Example of Implementing Zoom Using the CUSTOM Library (User, System Administrator, and Flexfields Help)


	Previous	Next		Contents	Index	Navigation	Glossary	Library

Example of Implementing Zoom Using the CUSTOM Library

Here is an example of a simple customization you can do with the Zoom feature (in the CUSTOM library).

Note: This Zoom demo/example is based on the training class form DEMXXEOR used in the class "Develop Extensions to Oracle Applications" (available through Oracle Education Services). The form files can be found on the Release 10SC Production 13 (and later) Development Kit CD-ROM, installable using the Oracle Installer file WINDOWS.PRD that you find under the ALPHAINS directory. The product name to install is "Training Class Forms (Develop Extensions to Oracle Applications)". See the Readme.txt file included for setting up the corresponding tables and views in your database.

The DEMXXEOR form is a very simple form for entering orders. In this example, we add two parameters (ORDER_ID and CUSTOMER_NAME) to the form that can be accepted from Zoom upon form startup. The form then fires an automatic query based on the parameters if one of the parameters has a value.

For the Zoom itself, we make Zoom available from the first block of the same form. The user can have a value in one or both of the Order Number and Customer Name fields. When the user clicks on the Zoom button, Zoom opens another session of the same form and automatically queries up any existing orders fitting the criteria.

Once you understand how this Zoom works and is implemented, you should be able to take the same approach with other forms (not necessarily zooming to another session of the same form).

Modify the Form

Using the Oracle Forms Designer, modify the Demo Orders form (DEMXXEOR.fmb) so it is able to receive parameter(s) from the Zoom code.

Note: The DEMXXEOR form shipped on the Release 10SC Production 15 (and later) Development Kit CD-ROM already has these modifications.

1. Create parameter ORDER_ID (Char, size 255, no default value).

2. Create parameter CUSTOMER_NAME (Char, size 255, no default value).

In theory, the parameter should match both the field the value comes from and the field it goes to, but it depends on the purpose of the parameter. In this case, having Char instead of number allows wildcards for the automatic query, as does having the parameter longer than the actual field (standard query length for most items is 255, and these parameters will only be used for queries).

3. Modify the default WHERE clause of the target block (ORDERS) to use parameter values as query criteria if they are not null:

	WHERE (:parameter.order_id is null or
		dem_orders_v.order_id like :parameter.order_id)
	AND (:parameter.customer_name is null or
		dem_orders_v.customer_name like :parameter.customer_name)

4. In the WHEN-NEW-FORM-INSTANCE trigger, add to the end of the existing code:

	/* fire automatic query if a parameter has a value from Zoom */
	if (:parameter.order_id is not null) or
	   (:parameter.customer_name is not null) then
	  GO_BLOCK('ORDERS');
	  do_key('EXECUTE_QUERY');

	/* clear the parameters after the query so they don't remain
		criteria for future queries */
	  :parameter.order_id := null;
	  :parameter.customer_name := null;
	end if;

5. Compile and generate the form, and put the .fmx file in the appropriate directory (assumes you have a custom application set up from the class).

6. Register the form, define a function for it (DEM_DEMXXEOR), and put the form function on a menu so you can access it. Verify that the form works properly from the Navigator before you modify the CUSTOM library.

Modify the CUSTOM Library

1. Open CUSTOM.PLL in the Oracle Forms Designer.

2. Attach the FNDSQF library (without hardcoded path name). Not necessary for Release Production 15 or later.

3. Modify the text of the CUSTOM package body as follows (the CUSTOM library comes with extensive comments that explain each section. You modify the actual code sections):

------------------------------------------------------------
PACKAGE BODY custom IS
  --
  -- Customize this package to provide specific responses to
  -- events within Oracle Applications forms.
  --
  -- Do not change the specification of the CUSTOM package 
  -- in any way.
  --
  ------------------------------------------------------------
  function zoom_available return BOOLEAN is
  --
  -- This function allows you to specify if zooms exist for the
  -- current context. If zooms are available for this block, then 
  -- return TRUE; else return FALSE. 
  --
  -- This routine is called on a per-block basis within every
  -- Applications form. Therefore, any code that will enable 
  -- Zoom must test the current 
  -- form and block from which the call is being made. 
  --
  -- By default this routine must return FALSE.
 
        form_name  varchar2(30) := name_in('system.current_form');
        block_name varchar2(30) := name_in('system.cursor_block'); 
  begin
        if (form_name = 'DEMXXEOR' and block_name = 'ORDERS') then
          return TRUE;
        else
          return FALSE;
        end if;
  
  end zoom_available;
  ---------------------------------------------------------------
  function style(event_name varchar2) return integer is
  --
  --  This Zoom example does not do anything to the STYLE function

  begin  
    return custom.standard;
  end style;
  ---------------------------------------------------------------
  procedure event(event_name varchar2) is
  --
  -- This procedure allows you to execute your code at specific
  -- events. 'ZOOM' or product-specific events will be passed
  -- in event_name. See the Applications Technical Reference
  -- manuals for a list of events that are available through 
  -- this interface.
 
        form_name  varchar2(30) := name_in('system.current_form');
        block_name varchar2(30) := name_in('system.cursor_block'); 
        param_to_pass1 varchar2(255);
        param_to_pass2 varchar2(255);

  BEGIN

        if (event_name = 'ZOOM') then

          if (form_name = 'DEMXXEOR' and block_name = 'ORDERS')
            then
            param_to_pass1 := name_in('ORDERS.order_id');
            param_to_pass2 := name_in('ORDERS.customer_name');

		/* use fnd_function.execute instead of open_form */
            FND_FUNCTION.EXECUTE(FUNCTION_NAME=>'DEM_DEMXXEOR', 
                                 OPEN_FLAG=>'Y', 
                                 SESSION_FLAG=>'Y', 
                                 OTHER_PARAMS=>
                                'ORDER_ID="'||param_to_pass1||
                                '" CUSTOMER_NAME="'||
                                param_to_pass2||'"');
		/* all the extra single and double quotes account for
		   any spaces that might be in the passed values */

          end if;

        else
          null;
        end if;
 
  end event;

END custom;
------------------------------------------------------------------

4. Compile All and save your changes. Exit the Designer.

5. Use the Forms Generate program to generate a new .plx file for the CUSTOM library.

6. Verify that your file generated successfully. If you leave out the pathname for the output file, the file will be generated in c:\orawin\bin (or platform equivalent). Move it to c:\apps10\au10\.

7. Make sure that the function you call in your Zoom (DEM_DEMXXEOR) is somewhere on the menu in your responsibility. It does not need to be accessible from the menu in the Navigator (do this by adding it to the menu but leaving the prompt blank). Otherwise, the Zoom button will be enabled but the user will get a message saying that function is not available.

8. Try it out from the Oracle Applications Navigator.

Example of Implementing Zoom Using the CUSTOM Library

Modify the Form

Modify the CUSTOM Library

See Also