Instruction Exit

Syntaxe

Exit Do

Exit For

Exit Function

Exit Sub

Remarques

La syntaxe de l'instruction Exit se présente comme suit :

Exit Do

Permet de sortir d'une instruction Do...Loop. Cette instruction ne peut être utilisée que dans une instruction Do...Loop. Exit Do transfère le contrôle à l'instruction qui suit l'instruction Loop. Lorsqu'elle est utilisée dans des instructions Do...Loop imbriquées, l'instruction Exit Do transfère le contrôle à la boucle qui se trouve un niveau imbriqué au-dessus de celle où elle se trouve.

Exit For

Permet de sortir d'une boucle For. Cette instruction ne peut être utilisée que dans une boucle For...Next ou For Each...Next. Exit For transfère le contrôle à l'instruction qui suit l'instruction Next. Lorsqu'elle est utilisée dans des boucles For imbriquées, l'instruction Exit For transfère le contrôle à la boucle qui se trouve un niveau imbriqué au-dessus de celle où elle se trouve.

Exit Function

Permet de sortir immédiatement de la procédure Function dans laquelle elle apparaît. L'exécution se poursuit avec l'instruction qui suit celle qui a appelé la procédure Function.

Exit Sub

Permet de sortir immédiatement de la procédure Sub dans laquelle elle apparaît. L'exécution se poursuit avec l'instruction qui suit celle qui a appelé la procédure Sub.

Les exemples suivants illustrent l'utilisation de l'instruction Exit.

Exemple 1 :

Sub RandomLoop
   Dim I, MyNum
   
      For I = 1 To 1000   ' Loop 1000 times.
         MyNum = Int(Rnd * 100)   ' Generate random numbers.
         Select Case MyNum   ' Evaluate random number.
            Case 17 'Operations based on the requirement for this case
               Exit For   ' If 17, exit For...Next.            
            Case 54 'Operations based on the requirement for this case
               Exit Sub   ' If 54, exit Sub procedure.
            End Select
      Next
End Sub

Exemple 2 :

Function CalculateValue(x)
        If x < 0 Then
             CalculateValue = 0
             Exit Function
        End If
        CalculateValue = x * 4
End Function
'In this example, if x is negative, the function returns 0 and exits before executing any further calculations.

Exemple 3 :

Dim count 
count = 0 
Do While True 
        count = count + 1 
        If count > 10 Then 
                Exit Do ' Exits the loop after count exceeds ten.
        End If 
        ' Additional processing...
Loop 
'Here, once count exceeds 10, the loop will terminate.

Exemple 4 :

For i = 1 To 10
        If i = 5 Then
                Exit For ' Exits the loop when i equals 5.
        End If
        ' Code for other iterations...
Next
'In this case, when i reaches 5, the loop terminates early.