X DevAPI User Guide

11.1 Session Objects and Functions

Session

The syntax for this object shown in EBNF is:

Session
    ::= '.getSchema(' StringLiteral ')'
        | '.getSchemas()'
        | '.createSchema(' StringLiteral ')'
        | '.dropSchema(' StringLiteral ')'
        | '.getDefaultSchema()'
        | '.startTransaction()'
        | '.commit()'
        | '.rollback()'
        | '.setSavepoint()'                    
        | '.setSavepoint(' StringLiteral ')'
        | '.releaseSavePoint(' StringLiteral ')'
        | '.rollbackTo(' StringLiteral ')'
        | '.close()'
        | SqlExecute                

Figure 11.1 Session

Content shows the syntax in EBNF form as described in the preceding text.

SqlExecute

The syntax for this function shown in EBNF is:

SqlExecute
    ::= '.sql(' SqlStatementStr ')'
        ( '.bind(' Literal (',' Literal)* ')')*
        ( '.execute()' )?

Figure 11.2 SqlExecute

Content shows the syntax in EBNF form as described in the preceding text.

SQLPlaceholderValues

The syntax for this function shown in EBNF is:

SQLPlaceholderValues
  ::= '{' SQLPlaceholderName ':' ( SQLLiteral ) '}'

Figure 11.3 SQLPlaceholderValues

Content shows the syntax in EBNF form as described in the preceding text.

SQLPlaceholderName

The syntax for this function shown in EBNF is:

SQLPlaceholderName
  ::= '?'

Figure 11.4 SQLPlaceholderName

Content shows the syntax in EBNF form as described in the preceding text.

SQLLiteral

The syntax for this function shown in EBNF is:

SQLLiteral
  ::= '"' StringLiteral '"' | Number | Document

Figure 11.5 SQLLiteral

Content shows the syntax in EBNF form as described in the preceding text.