GetEntityDetails

Returns entity transaction details for the specified cell.

The information returned by GetEntityDetails corresponds to the data displayed by Entity Transaction Detail reports. For more information on the data returned, see the topics for Entity Transaction Detail reports in the Oracle Hyperion Financial Management, Fusion Edition User's Guide.

Tip:	To return header information for the cell’s entity transaction details, use GetEntityDetailsHeader.

Syntax

<HFMwData>.GetEntityDetails lEntityDetailsOptions, bstrScenario, bstrYear, bstrPeriod, bstrEntity, bstrParent, bstrView, bstrAccount, bstrICP, bstrCustom1, bstrCustom2, bstrCustom3, bstrCustom4, pvaravar2DRowColumnDetails

Argument	Description
lEntityDetailsOptions	Determines which entity transaction detail data is returned. Valid values are represented by the HFMConstants type library constants listed in Entity Transaction Detail Display Options. You can use the addition operator ( + ) with these constants to return multiple types of information. Input argument. Long subtype.
bstrScenario	The label of the cell’s Scenario dimension member. Input argument. String subtype.
bstrYear	The label of the cell’s Year dimension member. Input argument. String subtype.
bstrPeriod	The label of the cell’s Period dimension member. Input argument. String subtype.
bstrEntity	The label of the cell’s child Entity dimension member. Input argument. String subtype.
bstrParent	The label of the cell’s parent Entity dimension member. Input argument. String subtype.
bstrView	The label of the cell’s View dimension member. Input argument. String subtype.
bstrAccount	The label of the cell’s Account dimension member. Input argument. String subtype.
bstrICP	The label of the cell’s Intercompany Partner dimension member. Input argument. String subtype.
bstrCustom1	The label of the cell’s Custom 1 dimension member. Input argument. String subtype.
bstrCustom2	The label of the cell’s Custom 2 dimension member. Input argument. String subtype.
bstrCustom3	The label of the cell’s Custom 3 dimension member. Input argument. String subtype.
bstrCustom4	The label of the cell’s Custom 4 dimension member. Input argument. String subtype.
pvaravar2DRowColumnDetails	Returns a two-dimensional array that contains the entity transaction details. The first dimension represents the rows, the second dimension represents the columns. The second dimension is indexed by the HFMConstants type library constants listed in Entity Transaction Detail Information. Input/output argument.

Example

The following function takes the labels of a cell’s dimension members, and returns an HTML string that contains some header information returned by GetEntityDetailsHeader, as well as the Value dimension member, Entity dimension member, amount, debit, and credit entity transaction detail data.

Note:

Because some system-generated Value dimension member names contain greater-than and less-than characters, the example calls the VBScript Replace function to replace these characters with their corresponding HTML symbols.

Function GetHtmlEntDetails(sScen, sYear, sPer, sEnt, sPar, sView, _ 
   sAcct, sICP, sCust1, sCust2, sCust3, sCust4)
Dim cHFMData, vaHead, lOptions, vaRowCols, sRet
Set cHFMData = Server.CreateObject("Hyperion.HFMwData")
' cHFMSession is a previously set HFMwSession object
cHFMData.SetWebSession cHFMSession
cHFMData.GetEntityDetailsHeader sScen, sEnt, sPar, vaHead
sRet = "<p><b>Time: </b>" & vaHead(ENTITYDETAILS_HEADER_TIME) & "</p>"
sRet = sRet & "<p><b>Entity Currency: </b>" & _ 
   vaHead(ENTITYDETAILS_HEADER_ENTITY_CURRENCY) & "</p>"
sRet = sRet & "<p><b>Parent Currency: </b>" & _ 
   vaHead(ENTITYDETAILS_HEADER_PARENT_CURRENCY) & "</p>"
lOptions =  ENTITYDETAILS_CREDIT + ENTITYDETAILS_DEBIT + _ 
   ENTITYDETAILS_ENTITY + ENTITYDETAILS_LID + ENTITYDETAILS_BASE_RECORDS
cHFMData.GetEntityDetails lOptions, sScen, sYear, sPer, sEnt, sPar, _ 
   sView, sAcct, sICP, sCust1, sCust2, sCust3, sCust4, vaRowCols
sRet = sRet & "<table cellpadding=2>"
sRet = sRet & "<tr><td><b>Value</b></td><td><b>Amount</b></td>" & _ 
   "<td><b>Debit</b></td><td><b>Credit</b></td></tr>"
For i = lBound(vaRowCols) to uBound(vaRowCols)
   sVal = Replace(vaRowCols(i, ENTITYDETAILS_DIMENSION_VALUE), "<", "&lt;")
   sVal = Replace(sVal, ">", "&gt;")
   sRet = sRet + "<tr><td>" & sVal & "</td>"
   sRet = sRet & "<td>" & vaRowCols(i, ENTITYDETAILS_DIMENSION_AMOUNT) & _ 
      "</td>"
   sRet = sRet & "<td>" & vaRowCols(i, ENTITYDETAILS_DIMENSION_DEBIT) & _ 
      "</td>"
   sRet = sRet & "<td>" & vaRowCols(i, ENTITYDETAILS_DIMENSION_CREDIT) & _ 
      "</td></tr>"
Next
sRet = sRet + "</table>"
GetHtmlEntDetails = sRet
End Function