Commonly Used PDL Calculated Mapping Application Class Objects

This section discusses how to derive:

Recruiting center.
Academic interests – description.

For additional commonly used calculated mapping application class objects, see Commonly Used Calculated Mapping Application Class Objects

Recruiting Center

import SCC_FILE_PARSER:MODEL:Results:ResultsField;
import SCC_FILE_PARSER:MODEL:Results:ResultsRecord;
import SCC_FILE_PARSER:UTIL:FieldCalculationAbstract;
import SCC_FILE_PARSER:MODEL:Results:ResultsCollection;
import SCC_FILE_PARSER:UTIL:Exception:FileParserException;

/**
  *  class Recruiting_Center
  *
  *  @version 1.0
  *  @author Campus Solutions	
  *
  *  Module: Campus Community / Common
  *  Description: 
  */


class Recruiting_Center extends SCC_FILE_PARSER:UTIL:FieldCalculationAbstract
   /* public methods */
   
   method Recruiting_Center();
   method  calculateValue(&ResultsFieldIn As SCC_FILE_PARSER:MODEL:Results:ResultsField, &ResultsCollectionIn As SCC_FILE_PARSER:MODEL:Results:ResultsCollection) Returns any;
   
private
   method GetFileData();
   method GetFieldReferences();
   
   instance string &adm_recr_ctrOut;
   instance string &RecruitingCenter;
   
   instance SCC_FILE_PARSER:MODEL:Results:ResultsField &ResultsField;
   instance SCC_FILE_PARSER:MODEL:Results:ResultsCollection &ResultsCollection;
   instance SCC_FILE_PARSER:MODEL:Results:ResultsField &InstitutionField;
   instance SCC_FILE_PARSER:MODEL:Results:ResultsField &CareerField;
   instance SCC_FILE_PARSER:MODEL:Results:ResultsField &ProgramField;
   instance SCC_FILE_PARSER:MODEL:Results:ResultsField &PlanField;
   
end-class;


/** 
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
     *
     * This method obtains the Recruiting Center based on incoming data.
     *
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
     */

method Recruiting_Center
   
   %Super = create SCC_FILE_PARSER:UTIL:FieldCalculationAbstract();
   
end-method;


/** 
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
     *
     * This method is the driver for deriving the Recruiting Center
     *
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
     */

method calculateValue
   /+ &ResultsFieldIn as SCC_FILE_PARSER:MODEL:Results:ResultsField, +/
   /+ &ResultsCollectionIn as SCC_FILE_PARSER:MODEL:Results:ResultsCollection +/
   /+ Returns Any +/
   /+ Extends/implements SCC_FILE_PARSER:UTIL:FieldCalculationAbstract.CalculateValue +/
   
   &ResultsCollection = &ResultsCollectionIn;
   &ResultsField = &ResultsFieldIn;
   
   %This.GetFileData();
   
   &RecruitingCenter = &adm_recr_ctrOut;
   
   Return &RecruitingCenter;
   
end-method;


/** 
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
     *
     * This method gets the Institution, Career, Program, and Plan from 
     * the incoming data. Based on what data was supplied, there is an 
     * iterative approach to obtaining the Recruiting Center 
     *
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
     */

method GetFileData
   Local string &Institution, &Career, &Program, &Plan, &adm_recr_ctr;
   
   %This.GetFieldReferences();
   
   &Institution = "";
   If &InstitutionField <> Null Then
      &Institution = &InstitutionField.FieldValue;
   End-If;
   
   &Career = "";
   If &CareerField <> Null Then
      &Career = &CareerField.FieldValue;
   End-If;
   
   &Program = "";
   If &ProgramField <> Null Then
      &Program = &ProgramField.FieldValue;
   End-If;
   
   &Plan = "";
   If &PlanField <> Null Then
      &Plan = &PlanField.FieldValue;
   End-If;
   
   &adm_recr_ctr = "";
   If All(&Institution, &Career, &Program, &Plan) Then
      SQLExec("SELECT ADM_RECR_CTR FROM PS_SAD_PDL_SETUP WHERE INSTITUTION = :1 AND ACAD_CAREER = :2 AND ACAD_PROG = :3 AND ACAD_PLAN = :4", &Institution, &Career, &Program, &Plan, &adm_recr_ctr);
   End-If;
   
   If &adm_recr_ctr = "" Then
      If All(&Institution, &Career, &Program) Then
         &Plan = " ";
         
         SQLExec("SELECT ADM_RECR_CTR FROM PS_SAD_PDL_SETUP WHERE INSTITUTION = :1 AND ACAD_CAREER = :2 AND ACAD_PROG = :3 AND ACAD_PLAN = :4", &Institution, &Career, &Program, &Plan, &adm_recr_ctr);
      End-If;
   End-If;
   
   If &adm_recr_ctr = "" Then
      If All(&Institution, &Career) Then
         &Program = " ";
         &Plan = " ";
         
         SQLExec("SELECT ADM_RECR_CTR FROM PS_SAD_PDL_SETUP WHERE INSTITUTION = :1 AND ACAD_CAREER = :2 AND ACAD_PROG = :3 AND ACAD_PLAN = :4", &Institution, &Career, &Program, &Plan, &adm_recr_ctr);
      End-If;
   End-If;
   
   &adm_recr_ctrOut = &adm_recr_ctr;
   
end-method;


/** 
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
     *
     * This method obtains the Institution, Academic Career, Program and
     * Plan - if available.
     *
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
     */

method GetFieldReferences
   
   Local integer &SegmentNbr;
   Local integer &RowNbr = 1;
   
   Local SCC_FILE_PARSER:MODEL:Results:ResultsRecord &obj_SAD_PRS_CAR_STG;
   Local SCC_FILE_PARSER:MODEL:Results:ResultsRecord &obj_SAD_PRS_PRG_STG;
   Local SCC_FILE_PARSER:MODEL:Results:ResultsRecord &obj_SAD_PRS_PLN_STG;
   
   &SegmentNbr = &ResultsField.ResultsRecord.SegmentNbr;
   
   &obj_SAD_PRS_CAR_STG = &ResultsCollection.GetResultsRecord(&SegmentNbr, "SAD_PRS_CAR_STG", &RowNbr);
   &obj_SAD_PRS_PRG_STG = &ResultsCollection.GetResultsRecord(&SegmentNbr, "SAD_PRS_PRG_STG", &RowNbr);
   &obj_SAD_PRS_PLN_STG = &ResultsCollection.GetResultsRecord(&SegmentNbr, "SAD_PRS_PLN_STG", &RowNbr);
   
   If &obj_SAD_PRS_CAR_STG <> Null Then
      &InstitutionField = &obj_SAD_PRS_CAR_STG.GetResultsField("INSTITUTION");
      
      &CareerField = &obj_SAD_PRS_CAR_STG.GetResultsField("ACAD_CAREER");
   End-If;
   
   If &obj_SAD_PRS_PRG_STG <> Null Then
      &ProgramField = &obj_SAD_PRS_PRG_STG.GetResultsField("ACAD_PROG");
   End-If;
   
   If &obj_SAD_PRS_PLN_STG <> Null Then
      &PlanField = &obj_SAD_PRS_PLN_STG.GetResultsField("ACAD_PLAN");
   End-If;
   
end-method;

Academic Interests – Description

import SCC_FILE_PARSER:UTIL:FieldCalculationAbstract;
import SCC_FILE_PARSER:MODEL:Results:ResultsField;
import SCC_FILE_PARSER:MODEL:Results:ResultsRecord;
import SCC_FILE_PARSER:MODEL:Results:ResultsCollection;
import SCC_FILE_PARSER:UTIL:Exception:FileParserException;

/**
  *  class FetchSubjectDescr
  *
  *  @version 1.0
  *  @author Campus Solutions	
  *
  *  Module: Recruiting and Admissions / Common App.
  *  Description: 
  */


class FetchSubjectDescr extends SCC_FILE_PARSER:UTIL:FieldCalculationAbstract
   /* public methods */
   
   method FetchSubjectDescr();
   method calculateValue(&ResultsFieldIn As SCC_FILE_PARSER:MODEL:Results:ResultsField, &ResultsCollectionIn As SCC_FILE_PARSER:MODEL:Results:ResultsCollection) Returns any;
   
private
   method GetFileData();
   method GetFieldReferences();
   
   instance string &SubjectArea;
   instance string &SubjectAreaDescrOut;
   
   instance SCC_FILE_PARSER:MODEL:Results:ResultsField &ResultsField;
   instance SCC_FILE_PARSER:MODEL:Results:ResultsCollection &ResultsCollection;
   instance SCC_FILE_PARSER:MODEL:Results:ResultsField &SubjectAreaField;
   
end-class;


/** 
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
     *
     * This method obtains the Subject Description based on incoming data.
     *
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
     */

method FetchSubjectDescr
   
   %Super = create SCC_FILE_PARSER:UTIL:FieldCalculationAbstract();
   
end-method;

/** 
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
     *
     * This method is the driver for deriving the Subject Description.
     *
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
     */

method calculateValue
   /+ &ResultsFieldIn as SCC_FILE_PARSER:MODEL:Results:ResultsField, +/
   /+ &ResultsCollectionIn as SCC_FILE_PARSER:MODEL:Results:ResultsCollection +/
   /+ Returns Any +/
   /+ Extends/implements SCC_FILE_PARSER:UTIL:FieldCalculationAbstract.CalculateValue +/
   
   
   &ResultsCollection = &ResultsCollectionIn;
   &ResultsField = &ResultsFieldIn;
   
   %This.GetFileData();
   
   Return &SubjectAreaDescrOut;
   
end-method;


/** 
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
     *
     * This method obtains the Subject Description based on incoming
     * Subject Area.
     *
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
     */

method GetFileData
   
   Local string &SubjectAreaDescr;
   
   If &SubjectAreaField = Null Then
      %This.GetFieldReferences();
   End-If;
   
   &SubjectArea = "";
   
   If &SubjectAreaField <> Null Then
      &SubjectArea = &SubjectAreaField.FieldValue;
      
      SQLExec("SELECT A.DESCR FROM PS_EXT_SUBJECT_TBL A WHERE A.EXT_SUBJECT_AREA =:1 AND A.EFF_STATUS = 'A' AND A.EFFDT = (SELECT MAX(A1.EFFDT) FROM PS_EXT_SUBJECT_TBL A1 WHERE A1.EXT_SUBJECT_AREA = A.EXT_SUBJECT_AREA AND A1.EFFDT <= %DateIn(:2))", &SubjectArea, %Date, &SubjectAreaDescr);
      
      If &SubjectAreaDescr = "" Then
         &SubjectAreaDescrOut = "NOT FOUND";
      Else
         &SubjectAreaDescrOut = &SubjectAreaDescr;
      End-If;
   End-If;
   
end-method;

/** 
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
     *
     * This method obtains the Subject Area from the incoming data.
     *
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
     */

method GetFieldReferences
   
   Local integer &SegmentNbr;
   Local integer &RecordRow;
   
   Local SCC_FILE_PARSER:MODEL:Results:ResultsRecord &obj_SCC_STG_ADMINT;
   
   &SegmentNbr = &ResultsField.ResultsRecord.SegmentNbr;
   &RecordRow = &ResultsField.ResultsRecord.RecordRow;
   
   &obj_SCC_STG_ADMINT = &ResultsCollection.GetResultsRecord(&SegmentNbr, "SCC_STG_ADMINT", &RecordRow);
   
   If &obj_SCC_STG_ADMINT <> Null Then
      &SubjectAreaField = &obj_SCC_STG_ADMINT.GetResultsField("EXT_SUBJECT_AREA");
   End-If;
   
end-method;