サンプル15-B: 計算済行と欠落した関係

このEssbaseレポート・スクリプトは、情報を要約します。レポートに必要な関係がデータベース・アウトラインに存在しない場合に、計算済行(または列)を使用することが最適な解決策になることがよくあります。

このサンプル・レポートは、キューブ・アウトラインに含まれないNorth/Southのグループ化の情報について簡単に要約します。

           Budget Payroll

                      Jan      Feb      Mar 
                     ====     ====     ==== 
Northern Cities
================
New_York            1,940    1,930    1,930 
Boston              1,610    1,610    1,610 
Chicago             1,630    1,630    1,630 
San_Francisco       1,815    1,815    1,815 
Seattle             1,415    1,409    1,409 

Southern Cities
================
Denver              1,499    1,499    1,499 
Los_Angeles         1,757    1,787    1,787 
Dallas              1,002    1,002    1,002 
Phoenix               900      900      900 
Houston               834      834      834 

Total Northern      8,410    8,394    8,394 
Total Southern      5,992    6,022    6,022

次のスクリプトを使用して、サンプル15-Bを作成します。

// Declare Calculated Rows to Sum Southern and Northern Cities
{ CALCULATE ROW "Total Southern" OFF

// initially, set operation to OFF
  CALCULATE ROW "Total Northern" OFF  }

<PAGE(Product,Scenario,Accounts)
{ RENAME "" } Product             // all products, so blank out
                                  // the Product Label
Budget
Payroll
     <COLUMN(Year)
     Jan  Feb  Mar

<ROW(Market)                      // Northern Cities

{ SETROWOP "Total Northern" +     // Accumulate for Northern

SKIP 3
IMMHEADING                                              // Put out heading now so text
                                  // will go after it
Text 0 "Northern Cities" UCHARACTERS
}

New_York Boston  Chicago San_Francisco Seattle

//Southern Cities

{ SETROWOP "Total Southern" +   } // Accumulate for Southern
{ SETROWOP "Total Northern" OFF } // Stop Accumulation for Northern

{ SKIP Text 0 "Southern Cities" UCHARACTERS }

Denver  Los_Angeles Dallas  Phoenix Houston

{ SKIP
PRINTROW "Total Northern"         // output calculated rows
PRINTROW "Total Southern"
}
    !