GET_PRINT_CONFIGプロシージャ

このファンクションは、データ・エクスポートのスタイルを設定するための印刷構成を準備します。

色は16進(hex)表記、RGBカラー・コードまたはHTMLカラー名を使用して指定されます。
位置合せのオプションは、「左」、「中央」、「右」です
フォント・ファミリのオプションは、「Helvetica」、「Times」、「Courier」です
フォントの太さのオプションは、「標準」、「太字」です

構文

FUNCTION GET_PRINT_CONFIG(
    p_units                       IN t_unit         DEFAULT c_unit_inches,
    p_paper_size                  IN t_size         DEFAULT c_size_letter,
    p_width_units                 IN t_width_unit   DEFAULT c_width_unit_percentage,
    p_width                       IN NUMBER         DEFAULT 11,
    p_height                      IN NUMBER         DEFAULT 8.5,
    p_orientation                 IN t_orientation  DEFAULT c_orientation_landscape,
    --
    p_page_header                 IN VARCHAR2       DEFAULT NULL,
    p_page_header_font_color      IN t_color        DEFAULT '#000000',
    p_page_header_font_family     IN t_font_family  DEFAULT c_font_family_helvetica,
    p_page_header_font_weight     IN t_font_weight  DEFAULT c_font_weight_normal,
    p_page_header_font_size       IN NUMBER         DEFAULT 12,
    p_page_header_alignment       IN t_alignment    DEFAULT c_align_center,
    --
    p_page_footer                 IN VARCHAR2       DEFAULT NULL,
    p_page_footer_font_color      IN t_color        DEFAULT '#000000',
    p_page_footer_font_family     IN t_font_family  DEFAULT c_font_family_helvetica,
    p_page_footer_font_weight     IN t_font_weight  DEFAULT c_font_weight_normal,
    p_page_footer_font_size       IN NUMBER         DEFAULT 12,
    p_page_footer_alignment       IN t_alignment    DEFAULT c_align_center,
    --
    p_header_bg_color             IN t_color        DEFAULT '#EEEEEE',
    p_header_font_color           IN t_color        DEFAULT '#000000',
    p_header_font_family          IN t_font_family  DEFAULT c_font_family_helvetica,
    p_header_font_weight          IN t_font_weight  DEFAULT c_font_weight_bold,
    p_header_font_size            IN NUMBER         DEFAULT 10,
    --
    p_body_bg_color               IN t_color        DEFAULT '#FFFFFF',
    p_body_font_color             IN t_color        DEFAULT '#000000',
    p_body_font_family            IN t_font_family  DEFAULT c_font_family_helvetica,
    p_body_font_weight            IN t_font_weight  DEFAULT c_font_weight_normal,
    p_body_font_size              IN NUMBER         DEFAULT 10,
    --
    p_border_width                IN NUMBER         DEFAULT .5,
    p_border_color                IN t_color        DEFAULT '#666666' ) return t_print_config;

パラメータ

パラメータ	説明
`p_units`	ページの幅と高さの指定に使用する単位を選択します。有効な値は、インチ、ミリメートル、センチメートル、ポイントです
`p_paper_size`	PDFのみ。レポート・ページのサイズを選択します。独自のページの幅と高さを入力するには、「カスタム」を選択します。使用可能なオプションは、「レター」、「リーガル」、「タブロイド」、「A4」、「A3」、「カスタム」です
`p_width_units`	PDFのみ。列幅の指定に使用する単位を選択します。有効な値は、パーセント、ポイント、ピクセルです
`p_width`	PDFのみ。ページの幅。
`p_height`	PDFのみ。ページの高さ。
`p_orientation`	ページの向き。PDFのみ。使用可能なオプションは、「垂直」(縦)、「水平」(横)です
`p_page_header`	ドキュメントのヘッダー・セクションに表示するテキスト。
`p_page_header_font_color`	ページ・ヘッダーのフォント色。
`p_page_header_font_family`	ページ・ヘッダーのフォント・ファミリ。
`p_page_header_font_weight`	ページ・ヘッダーのフォントの太さ。
`p_page_header_font_size`	ページ・ヘッダーのフォント・サイズ。
`p_page_header_alignment`	ページ・ヘッダー・テキストの位置合せ。
`p_page_footer`	ドキュメントのフッター・セクションに表示するテキスト。
`p_page_footer_font_color`	ページ・フッターのフォント色。
`p_page_footer_font_family`	ページ・フッターのフォント・ファミリ。
`p_page_footer_font_weight`	ページ・フッターのフォントの太さ。
`p_page_footer_font_size`	ページ・フッターのフォント・サイズ。
`p_page_footer_alignment`	ページ・フッター・テキストの位置合せ。
`p_header_bg_color`	表ヘッダーの背景色。
`p_header_font_color`	表ヘッダーのフォント色。
`p_header_font_family`	表ヘッダーのフォント・ファミリ。
`p_header_font_weight`	表ヘッダーのフォントの太さ。
`p_header_font_size`	表ヘッダーのフォント・サイズ。
`p_body_bg_color`	表本体の背景色。
`p_body_font_color`	表本体のフォント色。
`p_body_font_family`	表本体のフォント・ファミリ。
`p_body_font_weight`	表本体のフォントの太さ。
`p_body_font_size`	表本体のフォント・サイズ。
`p_border_width`	枠線の幅。
`p_border_color`	枠線の色。

戻り値

データ・エクスポートのスタイルを設定するための印刷構成。

例

DECLARE
    l_context         apex_exec.t_context; 
    l_print_config    apex_data_export.t_print_config;
    l_export          apex_data_export.t_export;
BEGIN
    l_context := apex_exec.open_query_context(
        p_location    => apex_exec.c_location_local_db,
        p_sql_query   => 'select * from emp' );

    l_print_config := apex_data_export.get_print_config(
        p_orientation     => apex_data_export.c_orientation_portrait,
        p_border_width    => 2 );

    l_export := apex_data_export.export (
        p_context         => l_context,
        p_print_config    => l_print_config,
        p_format          => apex_data_export.c_format_pdf );

    apex_exec.close( l_context );

    apex_data_export.download( p_export => l_export );

EXCEPTION
    when others THEN
        apex_exec.close( l_context );
        raise;
END;