Automatizar a Integração de Dados Diária

Este cenário explora o uso de um script de amostra para automatizar a integração de dados em uma base regular.

Crie um arquivo de lote (.bat) ou shell (.sh) que contenha um script semelhante ao seguinte para automatizar atividades relacionadas à integração de dados. O seguinte exemplo de script para Windows automatiza a integração diária de dados do aplicativo executando estas atividades:

  • Entre em um ambiente.

  • Exclua DailyPlanData se ele estiver presente.

  • Faça upload de DailyPlanData para o serviço.

  • Execute a regra de negócios Clear Plan Targets no tipo de plano Plan1.

  • Importe os dados usando o nome de job LoadDailyPlan.

  • Execute a regra de negócios Balance Sheet - Plan.

  • Execute a regra de negócios Allocate Plan Targets.

  • Exclua DailyTarget.zip se ele estiver presente.

  • Exporte os dados para DailyTarget.zip usando o nome de job ExportDailyTarget.

  • Faça download de DailyTarget.zip para o servidor e acrescenta o timestamp.

  • Saia do Planning.

Nota:

  • Se você adaptar esse script para seu uso, certifique-se de modificar os valores dos parâmetros SET url e SET user. Além disso, você pode modificar os valores dos parâmetros dataimportfilename, dataexportfilename, importdatajobname, exportdatajobname, br_clear, br_calculatebalancesheet e br_allocatetarget de acordo com seus requisitos.

  • Se você estiver usando a versão PDF deste documento: para evitar quebras de linha ou informações de rodapé que impedirão a utilização desse script, copie o script da Versão em HTML deste tópico.

Consulte Automação da Execução de Scripts para obter informações sobre como programar o script usando o Agendador de Tarefas do Windows.

@echo off

rem Sample Script to demonstrate daily data integration with 
rem Oracle Planning and Budgeting Cloud Services application.
rem This script uploads Plan data, clears target numbers,.
rem runs a business rule to calculate balance sheet data, and .
rem recalculates target numbers on the Vision demo application

rem Please input the below parameters
SET url=https://example.oraclecloud.com
SET user=serviceAdmin
SET dataimportfilename=DailyPlanData.csv
SET dataexportfilename=DailyTarget
SET importdatajobname=LoadDailyPlan
SET exportdatajobname=ExportDailyTarget
SET br_clear=Clear Plan Targets
SET br_calculatebalancesheet=Balance Sheet - Plan
SET br_allocatetarget=Allocate Plan Targets

SET password=%1

rem Executing EPM Automate commands

CD /D %~dp0
call epmautomate login %user% %password% %url%
IF %ERRORLEVEL% NEQ 0 goto :ERROR

for /f %%i in ('call epmautomate listfiles') do if %%i==%dataimportfilename% (call epmautomate deletefile %%i)
IF %ERRORLEVEL% NEQ 0 goto :ERROR

call epmautomate uploadfile %dataimportfilename%
IF %ERRORLEVEL% NEQ 0 goto :ERROR

call epmautomate runbusinessrule "%br_clear%"
IF %ERRORLEVEL% NEQ 0 goto :ERROR

call epmautomate importdata "%importdatajobname%"
IF %ERRORLEVEL% NEQ 0 goto :ERROR

call epmautomate runbusinessrule "%br_calculatebalancesheet%"
IF %ERRORLEVEL% NEQ 0 goto :ERROR

call epmautomate runbusinessrule "%br_allocatetarget%" "TargetVersion=Baseline"
IF %ERRORLEVEL% NEQ 0 goto :ERROR

for /f %%i in ('call epmautomate listfiles') do if %%i=="%dataexportfilename%.zip" (call epmautomate deletefile %%i)
IF %ERRORLEVEL% NEQ 0 goto :ERROR

call epmautomate exportdata %exportdatajobname% "%dataexportfilename%.zip"
IF %ERRORLEVEL% NEQ 0 goto :ERROR

call epmautomate downloadfile "%dataexportfilename%.zip"
IF %ERRORLEVEL% NEQ 0 goto :ERROR

rem Section to rename the file

Set Timestamp=%date:~4,2%_%date:~7,2%_%date:~10,4%_%time:~1,1%%time:~3,2%%
ren "%dataexportfilename%.zip" "%dataexportfilename%_%Timestamp%.zip"

call epmautomate logout
IF %ERRORLEVEL% NEQ 0 goto :ERROR

:EOF
echo Scheduled Task Completed successfully
exit /b %errorlevel%

:ERROR
echo Failed with error #%errorlevel%.
exit /b %errorlevel%