External Organization ID

Code example:

import SCC_FILE_PARSER:UTIL:FieldCalculationAbstract;
import SCC_FILE_PARSER:MODEL:Results:ResultsField;
import SCC_FILE_PARSER:MODEL:Results:ResultsRecord;
import SCC_FILE_PARSER:MODEL:Results:ResultsCollection;
import SCC_FILE_PARSER:UTIL:Exception:FileParserException;

/**
  *  class ExtOrgId
  *
  *  @version 1.0
  *  @author Campus Solutions	
  *
  *  Module: Recruiting and Admissions / Common App.
  *  Description: 
  */
class ExtOrgId extends SCC_FILE_PARSER:UTIL:FieldCalculationAbstract
   /* public methods */
   method ExtOrgId();
   method calculateValue(&ResultsFieldIn As 
SCC_FILE_PARSER:MODEL:Results:ResultsField, 
&ResultsCollectionIn As SCC_FILE_PARSER:MODEL:Results:ResultsCollection) Returns any;
private
   method GetFileData();
   method GetFieldReferences();
   instance string &SchoolCeeb;
   instance string &ExtOrgIdOut;
   instance SCC_FILE_PARSER:MODEL:Results:ResultsField &ResultsField;
   instance SCC_FILE_PARSER:MODEL:Results:ResultsCollection &ResultsCollection;
   instance SCC_FILE_PARSER:MODEL:Results:ResultsField &SchoolCeebField;
end-class;
method ExtOrgId
   %Super = create SCC_FILE_PARSER:UTIL:FieldCalculationAbstract();
end-method;
method calculateValue
   /+ &ResultsFieldIn as SCC_FILE_PARSER:MODEL:Results:ResultsField, +/
   /+ &ResultsCollectionIn as SCC_FILE_PARSER:MODEL:Results:ResultsCollection +/
   /+ Returns Any +/
   /+ Extends/implements 
SCC_FILE_PARSER:UTIL:FieldCalculationAbstract.CalculateValue +/
   &ResultsCollection = &ResultsCollectionIn;
   &ResultsField = &ResultsFieldIn;
   %This.GetFileData();
   Return &ExtOrgIdOut;
end-method;
method GetFileData
   Local string &ExtOrg;
   If &SchoolCeebField = Null Then
      %This.GetFieldReferences();
   End-If;
   &SchoolCeeb = "";
   If &SchoolCeebField <> Null Then
      &SchoolCeeb = &SchoolCeebField.FieldValue;
      SQLExec("SELECT EXT_ORG_ID FROM PS_ORG_ADM_CUR_VW WHERE ATP_CD = :1", 
&SchoolCeeb, &ExtOrg);
      &ExtOrgIdOut = &ExtOrg;
   End-If;
end-method;
method GetFieldReferences
   Local integer &SegmentNbr;
   Local integer &RecordRow;
   Local SCC_FILE_PARSER:MODEL:Results:ResultsRecord &obj_SCC_STG_ACADHST;
   &SegmentNbr = &ResultsField.ResultsRecord.SegmentNbr;
   &RecordRow = &ResultsField.ResultsRecord.RecordRow;
   &obj_SCC_STG_ACADHST = &ResultsCollection.GetResultsRecord(&SegmentNbr, 
"SCC_STG_ACADHST", &RecordRow);
   If &obj_SCC_STG_ACADHST <> Null Then
      &SchoolCeebField = &obj_SCC_STG_ACADHST.GetResultsField("SAD_SCHOOL_CEEB");
   End-If;
end-method;