Referencias a los dominios de disponibilidad

En cuanto a los dominios de disponibilidad, advertimos sobre un patrón común, como se muestra aquí:

// Get all availability domains for the region
data "oci_identity_availability_domains" "ads" {
  compartment_id = "${var.tenancy_ocid}"
}
  
// Then either use it to get a single AD name based on the index:
resource "oci_core_instance" "nat" {
  availability_domain = "${lookup(data.oci_identity_availability_domains.ads.availability_domains[var.nat_instance_ad],"name")}"
  ...
}
  
// Or iterate through all the ADs:
resource "oci_core_subnet" "nat" {
  count = "${length(data.oci_identity_availability_domains.ads.availability_domains)}"
  availability_domain = "${lookup(data.oci_identity_availability_domains.ad.availability_domains[count.index], "name")}"
  ...
}

Por tanto, la recomendación es mostrar explícitamente los nombres de dominio de disponibilidad para las regiones de la configuración. Para ello, utilice una variable definida como se indica a continuación:

variable "ad_list" {
  type = list
}

A continuación, puede utilizar la variable como se muestra aquí:

// Index:
resource "oci_core_instance" "nat" {
  availability_domain = "${var.ad_list[var.nat_instance_ad_index]}"
  ...
}
  
// Or iterate through all the ADs:
resource "oci_core_subnet" "nat" {
  count = "${length(var.ad_list)}"
  availability_domain = "${var.ad_list[count.index]}"
  ...
}

A continuación, puede definir la variable ad_list directamente utilizando los nombres de dominio de disponibilidad para el inquilino y la región, como se muestra aquí:

variable "ad_list" {
  type = list
  default = ["kIdk:PHX-AD-1","kIdk:PHX-AD-2","kIdk:PHX-AD-3"]
}

La ventaja de utilizar este método es que le brinda control del uso de dominio de disponibilidad y evita que se produzcan cambios inesperados con el tiempo. Sin embargo, este enfoque es problemático cuando las configuraciones se comparten entre arrendamientos y regiones, porque los nombres de dominio de disponibilidad son específicos del arrendamiento y la región.

Una alternativa adecuada es definir el valor ad_list mediante el origen de datos oci_identity_availability_domains. Debe hacerlo en la configuración y, a continuación, transferirlos a los módulos. De esta forma, se centraliza la lista de AD de forma eficaz, lo que facilita el cambio a una lista explícita posteriormente, en caso necesario. Tenga en cuenta que los módulos en sí no deben utilizar el origen de datos oci_identity_availability_domains.

data "oci_identity_availability_domains" "ad" {
  compartment_id = "${var.tenancy_ocid}"
}
 
data "template_file" "ad_names" {
  count = "${length(data.oci_identity_availability_domains.ad.availability_domains)}"
  template = "${lookup(data.oci_identity_availability_domains.ad.availability_domains[count.index], "name")}"
}
  
module "ssm_network" {
  ad_list = "${data.template_file.ad_names.*.rendered}"
  ...
}