Calcular cuota de producto y valores de cuota de mercado

Este ejemplo de script de cálculo de Essbase calcula los valores de cuota de mercado y cuota de producto calculando cada miembro como un porcentaje del total y como un porcentaje de su principal.

Los valores de las acciones se calculan de la siguiente manera:

  • Cada miembro como porcentaje del total

  • Cada miembro como porcentaje de su padre

Supongamos que ha agregado cuatro miembros a la dimensión Measures:

  • Cuota de mercado

  • Cuota de producto

  • % de mercado

  • Producto %

Script de ejemplo:

/* First consolidate the Sales values to ensure that they are accurate */

FIX(Sales)
   CALC DIM(Year, Market, Product);
ENDFIX

/* Calculate each market as a percentage of the total market for each product */

"Market Share" = Sales % Sales -> Market;

/* Calculate each product as a percentage of the total product for each market */

"Product Share" = Sales % Sales -> Product;

/* Calculate each market as a percentage of its parent for each product */

"Market %" = Sales % @PARENTVAL(Market, Sales);

/* Calculate each product as a percentage its parent for each market */

"Product %" = Sales % @PARENTVAL(Product, Sales);

Essbase realiza las siguientes acciones:

  1. Corrige los valores de Ventas y consolida todos los valores de Ventas.

    El comando CALC DIM calcula las dimensiones Year, Market y Product. La dimensión Measures contiene el miembro Sales y, por lo tanto, no está consolidada. La dimensión Scenario es solo una etiqueta y, por lo tanto, no es necesario consolidarla.

  2. Ciclos a través del cubo y calcula la cuota de mercado tomando el valor de ventas de cada producto en cada mercado para cada mes y calculando este valor de ventas como un porcentaje del total de ventas en todos los mercados para cada producto (Ventas -> Mercado).

  3. Calcula la cuota de producto tomando el valor de ventas de cada producto en cada mercado para cada mes y calculando este valor de ventas como un porcentaje del total de ventas de todos los productos en cada mercado (Ventas -> Producto).

  4. Calcula el % de mercado tomando el valor de ventas de cada producto en cada mercado para cada mes y calculando este valor de ventas como un porcentaje del valor de ventas del padre del miembro actual en la dimensión de mercado.

    La función @PARENTVAL obtiene el valor Sales del principal en la dimensión Market.

  5. Calcula el % de producto tomando el valor de ventas de cada producto en cada mercado para cada mes y calculando este valor de ventas como un porcentaje del valor de ventas del principal del miembro actual en la dimensión Producto.

    @PARENTVAL obtiene el valor Sales del principal en la dimensión Product.