Créer le package employees_pkg
Cette section explique comment créer le package employees_pkg, comment ses sous-programmes fonctionnent, comment accorder le privilège d'exécution sur le package aux utilisateurs qui en ont besoin et comment ces utilisateurs peuvent appeler l'un de ses sous-programmes.
Etapes de création du package employees_pkg :
-
Connectez-vous à Oracle Database en tant qu'utilisateur app_code.
Pour obtenir des instructions, reportez-vous à Connexion à Oracle Database à partir de SQL*Plus ou à Connexion à Oracle Database à partir de SQL Developer.
-
Créez les synonymes suivants :
CREATE OR REPLACE SYNONYM employees FOR app_data.employees; CREATE OR REPLACE SYNONYM departments FOR app_data.departments; CREATE OR REPLACE SYNONYM jobs FOR app_data.jobs; CREATE OR REPLACE SYNONYM job_history FOR app_data.job_history;Vous pouvez entrer les instructions CREATE SYNONYM dans SQL*Plus ou dans la feuille de calcul de SQL Developer. Vous pouvez également créer les synonymes à l'aide de l'outil SQL Developer Create Synonym.
-
Créez la spécification de package.
-
Créez le corps du lot.
Voir aussi :
Création de la spécification de package pour employees_pkg
Remarque : vous devez être connecté à Oracle Database en tant qu'utilisateur app_code.
Pour créer la spécification de PACKAGE employees_pkg, l'API pour les responsables, utilisez l'instruction CREATE PACKAGE suivante. Vous pouvez entrer l'instruction dans SQL*Plus ou dans la feuille de calcul de SQL Developer. Vous pouvez également créer le package à l'aide de l'outil SQL Developer Create Package.
CREATE OR REPLACE PACKAGE employees_pkg
AS
PROCEDURE get_employees_in_dept
( p_deptno IN employees.department_id%TYPE,
p_result_set IN OUT SYS_REFCURSOR );
PROCEDURE get_job_history
( p_employee_id IN employees.department_id%TYPE,
p_result_set IN OUT SYS_REFCURSOR );
PROCEDURE show_employee
( p_employee_id IN employees.employee_id%TYPE,
p_result_set IN OUT SYS_REFCURSOR );
PROCEDURE update_salary
( p_employee_id IN employees.employee_id%TYPE,
p_new_salary IN employees.salary%TYPE );
PROCEDURE change_job
( p_employee_id IN employees.employee_id%TYPE,
p_new_job IN employees.job_id%TYPE,
p_new_salary IN employees.salary%TYPE := NULL,
p_new_dept IN employees.department_id%TYPE := NULL );
END employees_pkg;
/Voir aussi :
-
Oracle Database PL/SQL Language Reference, pour plus d'informations sur l'instruction CREATE PACKAGE
Créer le corps du package pour employees_pkg
Remarque : vous devez être connecté à Oracle Database en tant qu'utilisateur app_code.
Pour créer le corps du PACKAGE employees_pkg, l'API des responsables, utilisez l'instruction CREATE PACKAGE BODY suivante. Vous pouvez entrer l'instruction dans SQL*Plus ou dans la feuille de calcul de SQL Developer. Vous pouvez également créer le package à l'aide de l'outil SQL Developer Create Body.
CREATE OR REPLACE PACKAGE BODY employees_pkg
AS
PROCEDURE get_employees_in_dept
( p_deptno IN employees.department_id%TYPE,
p_result_set IN OUT SYS_REFCURSOR )
IS
l_cursor SYS_REFCURSOR;
BEGIN
OPEN p_result_set FOR
SELECT e.employee_id,
e.first_name || ' ' || e.last_name name,
TO_CHAR( e.hire_date, 'Dy Mon ddth, yyyy' ) hire_date,
j.job_title,
m.first_name || ' ' || m.last_name manager,
d.department_name
FROM employees e INNER JOIN jobs j ON (e.job_id = j.job_id)
LEFT OUTER JOIN employees m ON (e.manager_id = m.employee_id)
INNER JOIN departments d ON (e.department_id = d.department_id)
WHERE e.department_id = p_deptno ;
END get_employees_in_dept;
PROCEDURE get_job_history
( p_employee_id IN employees.department_id%TYPE,
p_result_set IN OUT SYS_REFCURSOR )
IS
BEGIN
OPEN p_result_set FOR
SELECT e.First_name || ' ' || e.last_name name, j.job_title,
e.job_start_date start_date,
TO_DATE(NULL) end_date
FROM employees e INNER JOIN jobs j ON (e.job_id = j.job_id)
WHERE e.employee_id = p_employee_id
UNION ALL
SELECT e.First_name || ' ' || e.last_name name,
j.job_title,
jh.start_date,
jh.end_date
FROM employees e INNER JOIN job_history jh
ON (e.employee_id = jh.employee_id)
INNER JOIN jobs j ON (jh.job_id = j.job_id)
WHERE e.employee_id = p_employee_id
ORDER BY start_date DESC;
END get_job_history;
PROCEDURE show_employee
( p_employee_id IN employees.employee_id%TYPE,
p_result_set IN OUT sys_refcursor )
IS
BEGIN
OPEN p_result_set FOR
SELECT *
FROM (SELECT TO_CHAR(e.employee_id) employee_id,
e.first_name || ' ' || e.last_name name,
e.email_addr,
TO_CHAR(e.hire_date,'dd-mon-yyyy') hire_date,
e.country_code,
e.phone_number,
j.job_title,
TO_CHAR(e.job_start_date,'dd-mon-yyyy') job_start_date,
to_char(e.salary) salary,
m.first_name || ' ' || m.last_name manager,
d.department_name
FROM employees e INNER JOIN jobs j on (e.job_id = j.job_id)
RIGHT OUTER JOIN employees m ON (m.employee_id = e.manager_id)
INNER JOIN departments d ON (e.department_id = d.department_id)
WHERE e.employee_id = p_employee_id)
UNPIVOT (VALUE FOR ATTRIBUTE IN (employee_id, name, email_addr, hire_date,
country_code, phone_number, job_title, job_start_date, salary, manager,
department_name) );
END show_employee;
PROCEDURE update_salary
( p_employee_id IN employees.employee_id%type,
p_new_salary IN employees.salary%type )
IS
BEGIN
UPDATE employees
SET salary = p_new_salary
WHERE employee_id = p_employee_id;
END update_salary;
PROCEDURE change_job
( p_employee_id IN employees.employee_id%TYPE,
p_new_job IN employees.job_id%TYPE,
p_new_salary IN employees.salary%TYPE := NULL,
p_new_dept IN employees.department_id%TYPE := NULL )
IS
BEGIN
INSERT INTO job_history (employee_id, start_date, end_date, job_id,
department_id)
SELECT employee_id, job_start_date, TRUNC(SYSDATE), job_id, department_id
FROM employees
WHERE employee_id = p_employee_id;
UPDATE employees
SET job_id = p_new_job,
department_id = NVL( p_new_dept, department_id ),
salary = NVL( p_new_salary, salary ),
job_start_date = TRUNC(SYSDATE)
WHERE employee_id = p_employee_id;
END change_job;
END employees_pkg;
/Voir aussi :
-
Oracle Database PL/SQL Language Reference, pour plus d'informations sur l'instruction CREATE PACKAGE BODY
Tutoriel : Affichage du fonctionnement des sous-programmes employees_pkg
A l'aide de SQL*Plus, ce tutoriel montre comment fonctionnent les sous-programmes du package employees_pkg. Le tutoriel montre également comment fonctionnent le déclencheur employees_aiufer et la contrainte CHECK job_history_date_check.
Remarque : vous devez être connecté à Oracle Database en tant qu'utilisateur app_code à partir de SQL*Plus.
Pour utiliser SQL*Plus afin d'afficher le fonctionnement des sous-programmes employees_pkg, procédez comme suit :
-
Utilisez les commandes de formatage pour améliorer la lisibilité de la sortie. Exemple :
SET LINESIZE 80 SET RECSEP WRAPPED SET RECSEPCHAR "=" COLUMN NAME FORMAT A15 WORD_WRAPPED COLUMN HIRE_DATE FORMAT A20 WORD_WRAPPED COLUMN DEPARTMENT_NAME FORMAT A10 WORD_WRAPPED COLUMN JOB_TITLE FORMAT A29 WORD_WRAPPED COLUMN MANAGER FORMAT A11 WORD_WRAPPED -
Déclarez une variable attachée pour la valeur du paramètre de sous-programme p_result_set :
VARIABLE c REFCURSOR -
Afficher les employés du service 90 :
EXEC employees_pkg.get_employees_in_dept( 90, :c ); PRINT cRésultats :
EMPLOYEE_ID NAME HIRE_DATE JOB_TITLE ----------- --------------- -------------------- -------------------------- MANAGER DEPARTMENT ----------- ---------- 100 Steven King Tue Jun 17th, 2003 President Executive =========================================================================== 102 Lex De Haan Sat Jan 13th, 2001 Administration Vice President Steven King Executive =========================================================================== 101 Neena Kochhar Wed Sep 21st, 2005 Administration Vice President Steven King Executive =========================================================================== -
Afficher l'historique de l'emploi de l'employé 101 :
EXEC employees_pkg.get_job_history( 101, :c ); PRINT cRésultats :
NAME JOB_TITLE START_DAT END_DATE --------------- ----------------------------- --------- --------- Neena Kochhar Administration Vice President 16-MAR-05 Neena Kochhar Accounting Manager 28-OCT-01 15-MAR-05 Neena Kochhar Public Accountant 21-SEP-97 27-OCT-01 -
Afficher des informations générales sur l'employé 101 :
EXEC employees_pkg.show_employee( 101, :c ); PRINT cRésultats :
ATTRIBUTE VALUE --------------- ---------------------------------------------- EMPLOYEE_ID 101 NAME Neena Kochhar EMAIL_ADDR NKOCHHAR HIRE_DATE 21-sep-2005 COUNTRY_CODE +1 PHONE_NUMBER 515.123.4568 JOB_TITLE Administration Vice President JOB_START_DATE 16-mar-05 SALARY 17000 MANAGER Steven King DEPARTMENT_NAME Executive 11 rows selected. -
Affichez les informations relatives au poste de vice-président de l'administration :
SELECT * FROM jobs WHERE job_title = 'Administration Vice President';Résultats :
JOB_ID JOB_TITLE MIN_SALARY MAX_SALARY ---------- ----------------------------- ---------- ---------- AD_VP Administration Vice President 15000 30000 -
Essayez de donner à l'employé 101 un nouveau salaire en dehors de la fourchette pour son emploi :
EXEC employees_pkg.update_salary( 101, 30001 );Résultats :
SQL> EXEC employees_pkg.update_salary( 101, 30001 ); BEGIN employees_pkg.update_salary( 101, 30001 ); END; * ERROR at line 1: ORA-20002: Salary modification invalid ORA-06512: at "APP_DATA.EMPLOYEES_AIUFER", line 13 ORA-04088: error during execution of trigger 'APP_DATA.EMPLOYEES_AIUFER' ORA-06512: at "APP_CODE.EMPLOYEES_PKG", line 77 ORA-06512: at line 1 -
Donnez à l'employé 101 un nouveau salaire dans la fourchette pour son emploi et affichez à nouveau des informations générales sur elle :
EXEC employees_pkg.update_salary( 101, 18000 ); EXEC employees_pkg.show_employee( 101, :c ); PRINT cRésultats :
ATTRIBUTE VALUE --------------- ---------------------------------------------- EMPLOYEE_ID 101 NAME Neena Kochhar EMAIL_ADDR NKOCHHAR HIRE_DATE 21-sep-2005 COUNTRY_CODE +1 PHONE_NUMBER 515.123.4568 JOB_TITLE Administration Vice President JOB_START_DATE 16-mar-05 SALARY 18000 MANAGER Steven King DEPARTMENT_NAME Executive 11 rows selected. -
Remplacez l'emploi de l'employé 101 par son emploi actuel avec un salaire inférieur :
EXEC employees_pkg.change_job( 101, 'AD_VP', 17500, 90 );Résultats :
SQL> exec employees_pkg.change_job( 101, 'AD_VP', 17500, 90 ); BEGIN employees_pkg.change_job( 101, 'AD_VP', 17500, 80 ); END; * ERROR at line 1: ORA-02290: check constraint (APP_DATA.JOB_HISTORY_DATE_CHECK) violated ORA-06512: at "APP_CODE.EMPLOYEES_PKG", line 101 ORA-06512: at line 1 -
Afficher les informations sur le salarié. (Notez que le salaire n'a pas été modifié par le relevé de l'étape précédente ; il s'agit de 18000, et non de 17500.)
exec employees_pkg.show_employee( 101, :c ); print cRésultats :
ATTRIBUTE VALUE --------------- ---------------------------------------------- EMPLOYEE_ID 101 NAME Neena Kochhar EMAIL_ADDR NKOCHHAR HIRE_DATE 21-sep-2005 COUNTRY_CODE +1 PHONE_NUMBER 515.123.4568 JOB_TITLE Administration Vice President JOB_START_DATE 10-mar-2015 SALARY 18000 MANAGER Steven King DEPARTMENT_NAME Executive 11 rows selected.
Voir aussi :
-
Guide de l'utilisateur et référence SQL*Plus, pour plus d'informations sur les commandes SQL*Plus
Accorder le privilège Execute à app_user et app_admin_user
Remarque : vous devez être connecté à Oracle Database en tant qu'utilisateur app_code.
Pour accorder le privilège d'exécution sur le package employees_pkg à app_user (généralement un manager) et app_admin_user (un administrateur d'application), utilisez les instructions GRANT suivantes (dans l'un ou l'autre ordre). Vous pouvez entrer les instructions dans SQL*Plus ou dans la feuille de calcul de SQL Developer.
GRANT EXECUTE ON employees_pkg TO app_user;
GRANT EXECUTE ON employees_pkg TO app_admin_user;Voir aussi :
-
Manuel Oracle Database SQL Language Reference, pour plus d'informations sur l'instruction GRANT
Tutoriel : Appel de get_job_history en tant qu'app_user ou app_admin_user
A l'aide de SQL*Plus, ce tutoriel montre comment appeler le sous-programme app_code.employees_pkg.get_job_history en tant qu'utilisateur app_user (généralement un gestionnaire) ou app_admin_user (un administrateur d'application).
Etapes permettant d'appeler employees_pkg.get_job_history en tant qu'app_user ou app_admin_user :
-
Connectez-vous à Oracle Database en tant qu'utilisateur app_user ou app_admin_user depuis SQL*Plus.
Pour obtenir des instructions, reportez-vous à Connexion à Oracle Database à partir de SQL*Plus.
-
Créez le synonyme suivant :
CREATE SYNONYM employees_pkg FOR app_code.employees_pkg; -
Afficher l'historique de l'emploi de l'employé 101 :
EXEC employees_pkg.get_job_history( 101, :c ); PRINT cRésultats :
NAME JOB_TITLE START_DAT END_DATE --------------- ----------------------------- --------- --------- Neena Kochhar Administration Vice President 16-MAR-05 15-MAY-12 Neena Kochhar Accounting Manager 28-OCT-01 15-MAR-05 Neena Kochhar Public Accountant 21-SEP-97 27-OCT-01