Calculer les valeurs de part de produit et de part de marché

Cet exemple de script de calcul Essbase calcule les valeurs de part de produit et de part de marché en calculant chaque membre en pourcentage du total et en pourcentage de son parent.

Les valeurs de partage sont calculées comme suit :

  • Chaque membre, sous forme de pourcentage du total

  • Chaque membre en pourcentage de son parent

Supposons que vous ayez ajouté quatre membres à la dimension Measures :

  • Part de marché

  • Partage de produit

  • % marché

  • % produit

Exemple de script:

/* First consolidate the Sales values to ensure that they are accurate */

FIX(Sales)
   CALC DIM(Year, Market, Product);
ENDFIX

/* Calculate each market as a percentage of the total market for each product */

"Market Share" = Sales % Sales -> Market;

/* Calculate each product as a percentage of the total product for each market */

"Product Share" = Sales % Sales -> Product;

/* Calculate each market as a percentage of its parent for each product */

"Market %" = Sales % @PARENTVAL(Market, Sales);

/* Calculate each product as a percentage its parent for each market */

"Product %" = Sales % @PARENTVAL(Product, Sales);

Essbase effectue les actions suivantes :

  1. Corrige les valeurs Sales et consolide toutes les valeurs Sales.

    La commande CALC DIM calcule les dimensions Année, Marché et Produit. La dimension Measures contient le membre Sales et n'est donc pas consolidée. La dimension Scénario est de type libellé uniquement et n'a donc pas besoin d'être consolidée.

  2. Parcourt le cube et calcule la part de marché en prenant la valeur des ventes pour chaque produit sur chaque marché pour chaque mois et en calculant cette valeur des ventes en pourcentage du total des ventes sur tous les marchés pour chaque produit (Ventes -> Marché).

  3. Calcule la part de produit en prenant la valeur des ventes pour chaque produit de chaque marché pour chaque mois et en calculant cette valeur des ventes en pourcentage du total des ventes de tous les produits de chaque marché (ventes -> produit).

  4. Calcule le pourcentage du marché en prenant la valeur des ventes pour chaque produit de chaque marché pour chaque mois et en calculant cette valeur des ventes en pourcentage de la valeur des ventes du parent du membre actuel dans la dimension Marché.

    La fonction @PARENTVAL obtient la valeur Sales du parent dans la dimension Market.

  5. Calcule le pourcentage de produit en prenant la valeur des ventes pour chaque produit de chaque marché pour chaque mois et en calculant cette valeur des ventes en pourcentage de la valeur des ventes du parent du membre actuel dans la dimension Produit.

    @PARENTVAL obtient la valeur Sales du parent dans la dimension Product.