Creazione del package employee_pkg
Questa sezione mostra come creare il pacchetto employee_pkg, come funzionano i relativi sottoprogrammi, come concedere il privilegio EXECUTE sul pacchetto agli utenti che lo richiedono e come tali utenti possono richiamare uno dei relativi sottoprogrammi.
Per creare il pacchetto employee_pkg:
-
Connettersi al database come utente app_code.
Per le istruzioni, vedere "Connessione a Oracle AI Database da SQL*Plus" o "Connessione a Oracle AI Database da SQL Developer".
-
Creare questi sinonimi:
CREATE OR REPLACE SYNONYM employees FOR app_data.employees; CREATE OR REPLACE SYNONYM departments FOR app_data.departments; CREATE OR REPLACE SYNONYM jobs FOR app_data.jobs; CREATE OR REPLACE SYNONYM job_history FOR app_data.job_history;È possibile immettere le istruzioni CREATE SYNONYM in SQL*Plus o nel foglio di lavoro di SQL Developer. In alternativa, è possibile creare i sinonimi con lo strumento SQL Developer Crea sinonimo.
-
Creare la specifica del package.
-
Creare il corpo del package.
Vedere anche:
Creazione della specifica package per employee_pkg
Nota: è necessario essere connessi al database come app_code utente.
Per creare la specifica PACKAGE per employee_pkg, l'API per i manager, utilizzare la seguente istruzione CREATE PACKAGE. È possibile immettere l'istruzione in SQL*Plus o nel foglio di lavoro di SQL Developer. In alternativa, è possibile creare il package con lo strumento SQL Developer Crea package.
CREATE OR REPLACE PACKAGE employees_pkg
AS
PROCEDURE get_employees_in_dept
( p_deptno IN employees.department_id%TYPE,
p_result_set IN OUT SYS_REFCURSOR );
PROCEDURE get_job_history
( p_employee_id IN employees.department_id%TYPE,
p_result_set IN OUT SYS_REFCURSOR );
PROCEDURE show_employee
( p_employee_id IN employees.employee_id%TYPE,
p_result_set IN OUT SYS_REFCURSOR );
PROCEDURE update_salary
( p_employee_id IN employees.employee_id%TYPE,
p_new_salary IN employees.salary%TYPE );
PROCEDURE change_job
( p_employee_id IN employees.employee_id%TYPE,
p_new_job IN employees.job_id%TYPE,
p_new_salary IN employees.salary%TYPE := NULL,
p_new_dept IN employees.department_id%TYPE := NULL );
END employees_pkg;
/Vedere anche:
-
Oracle AI Database PL/SQL Language Reference per informazioni sull'istruzione CREATE PACKAGE
Creazione del package body per employee_pkg
Nota: è necessario essere connessi al database come app_code utente.
Per creare il PACKAGE BODY per employee_pkg, l'API per i manager, utilizzare la seguente istruzione CREATE PACKAGE BODY. È possibile immettere l'istruzione in SQL*Plus o nel foglio di lavoro di SQL Developer. In alternativa, è possibile creare il pacchetto con lo strumento SQL Developer Crea corpo.
CREATE OR REPLACE PACKAGE BODY employees_pkg
AS
PROCEDURE get_employees_in_dept
( p_deptno IN employees.department_id%TYPE,
p_result_set IN OUT SYS_REFCURSOR )
IS
l_cursor SYS_REFCURSOR;
BEGIN
OPEN p_result_set FOR
SELECT e.employee_id,
e.first_name || ' ' || e.last_name name,
TO_CHAR( e.hire_date, 'Dy Mon ddth, yyyy' ) hire_date,
j.job_title,
m.first_name || ' ' || m.last_name manager,
d.department_name
FROM employees e INNER JOIN jobs j ON (e.job_id = j.job_id)
LEFT OUTER JOIN employees m ON (e.manager_id = m.employee_id)
INNER JOIN departments d ON (e.department_id = d.department_id)
WHERE e.department_id = p_deptno ;
END get_employees_in_dept;
PROCEDURE get_job_history
( p_employee_id IN employees.department_id%TYPE,
p_result_set IN OUT SYS_REFCURSOR )
IS
BEGIN
OPEN p_result_set FOR
SELECT e.First_name || ' ' || e.last_name name, j.job_title,
e.job_start_date start_date,
TO_DATE(NULL) end_date
FROM employees e INNER JOIN jobs j ON (e.job_id = j.job_id)
WHERE e.employee_id = p_employee_id
UNION ALL
SELECT e.First_name || ' ' || e.last_name name,
j.job_title,
jh.start_date,
jh.end_date
FROM employees e INNER JOIN job_history jh
ON (e.employee_id = jh.employee_id)
INNER JOIN jobs j ON (jh.job_id = j.job_id)
WHERE e.employee_id = p_employee_id
ORDER BY start_date DESC;
END get_job_history;
PROCEDURE show_employee
( p_employee_id IN employees.employee_id%TYPE,
p_result_set IN OUT sys_refcursor )
IS
BEGIN
OPEN p_result_set FOR
SELECT *
FROM (SELECT TO_CHAR(e.employee_id) employee_id,
e.first_name || ' ' || e.last_name name,
e.email_addr,
TO_CHAR(e.hire_date,'dd-mon-yyyy') hire_date,
e.country_code,
e.phone_number,
j.job_title,
TO_CHAR(e.job_start_date,'dd-mon-yyyy') job_start_date,
to_char(e.salary) salary,
m.first_name || ' ' || m.last_name manager,
d.department_name
FROM employees e INNER JOIN jobs j on (e.job_id = j.job_id)
RIGHT OUTER JOIN employees m ON (m.employee_id = e.manager_id)
INNER JOIN departments d ON (e.department_id = d.department_id)
WHERE e.employee_id = p_employee_id)
UNPIVOT (VALUE FOR ATTRIBUTE IN (employee_id, name, email_addr, hire_date,
country_code, phone_number, job_title, job_start_date, salary, manager,
department_name) );
END show_employee;
PROCEDURE update_salary
( p_employee_id IN employees.employee_id%type,
p_new_salary IN employees.salary%type )
IS
BEGIN
UPDATE employees
SET salary = p_new_salary
WHERE employee_id = p_employee_id;
END update_salary;
PROCEDURE change_job
( p_employee_id IN employees.employee_id%TYPE,
p_new_job IN employees.job_id%TYPE,
p_new_salary IN employees.salary%TYPE := NULL,
p_new_dept IN employees.department_id%TYPE := NULL )
IS
BEGIN
INSERT INTO job_history (employee_id, start_date, end_date, job_id,
department_id)
SELECT employee_id, job_start_date, TRUNC(SYSDATE), job_id, department_id
FROM employees
WHERE employee_id = p_employee_id;
UPDATE employees
SET job_id = p_new_job,
department_id = NVL( p_new_dept, department_id ),
salary = NVL( p_new_salary, salary ),
job_start_date = TRUNC(SYSDATE)
WHERE employee_id = p_employee_id;
END change_job;
END employees_pkg;
/Vedere anche:
-
Oracle AI Database PL/SQL Language Reference per informazioni sull'istruzione CREATE PACKAGE BODY
Esercitazione: Come funzionano i sottoprogrammi employee_pkg
Utilizzando SQL*Plus, questa esercitazione mostra il funzionamento dei sottoprogrammi del package impiegati_pkg. L'esercitazione mostra inoltre come funzionano il trigger employee_aiufer e il vincolo CHECK job_history_date_check.
Nota: è necessario essere connessi a Oracle AI Database come utente app_code da SQL*Plus.
Per utilizzare SQL*Plus per mostrare il funzionamento dei sottoprogrammi employee_pkg:
-
Utilizzare i comandi di formattazione per migliorare la leggibilità dell'output. Ad esempio:
SET LINESIZE 80 SET RECSEP WRAPPED SET RECSEPCHAR "=" COLUMN NAME FORMAT A15 WORD_WRAPPED COLUMN HIRE_DATE FORMAT A20 WORD_WRAPPED COLUMN DEPARTMENT_NAME FORMAT A10 WORD_WRAPPED COLUMN JOB_TITLE FORMAT A29 WORD_WRAPPED COLUMN MANAGER FORMAT A11 WORD_WRAPPED -
Dichiarare una bind variable per il valore del parametro del sottoprogramma p_result_set:
VARIABLE c REFCURSOR -
Mostra i dipendenti nel dipartimento 90:
EXEC employees_pkg.get_employees_in_dept( 90, :c ); PRINT cRisultato:
EMPLOYEE_ID NAME HIRE_DATE JOB_TITLE ----------- --------------- -------------------- -------------------------- MANAGER DEPARTMENT ----------- ---------- 100 Steven King Tue Jun 17th, 2003 President Executive =========================================================================== 102 Lex De Haan Sat Jan 13th, 2001 Administration Vice President Steven King Executive =========================================================================== 101 Neena Kochhar Wed Sep 21st, 2005 Administration Vice President Steven King Executive =========================================================================== -
Mostra la cronologia mansione del dipendente 101:
EXEC employees_pkg.get_job_history( 101, :c ); PRINT cRisultato:
NAME JOB_TITLE START_DAT END_DATE --------------- ----------------------------- --------- --------- Neena Kochhar Administration Vice President 16-MAR-05 Neena Kochhar Accounting Manager 28-OCT-01 15-MAR-05 Neena Kochhar Public Accountant 21-SEP-97 27-OCT-01 -
Mostra informazioni generali sul dipendente 101:
EXEC employees_pkg.show_employee( 101, :c ); PRINT cRisultato:
ATTRIBUTE VALUE --------------- ---------------------------------------------- EMPLOYEE_ID 101 NAME Neena Kochhar EMAIL_ADDR NKOCHHAR HIRE_DATE 21-sep-2005 COUNTRY_CODE +1 PHONE_NUMBER 515.123.4568 JOB_TITLE Administration Vice President JOB_START_DATE 16-mar-05 SALARY 17000 MANAGER Steven King DEPARTMENT_NAME Executive 11 rows selected. -
Mostra le informazioni sul lavoro Vicepresidente amministrazione:
SELECT * FROM jobs WHERE job_title = 'Administration Vice President';Risultato:
JOB_ID JOB_TITLE MIN_SALARY MAX_SALARY ---------- ----------------------------- ---------- ---------- AD_VP Administration Vice President 15000 30000 -
Provare a dare al dipendente 101 un nuovo stipendio al di fuori dell'intervallo per la propria mansione:
EXEC employees_pkg.update_salary( 101, 30001 );Risultato:
SQL> EXEC employees_pkg.update_salary( 101, 30001 ); BEGIN employees_pkg.update_salary( 101, 30001 ); END; * ERROR at line 1: ORA-20002: Salary modification invalid ORA-06512: at "APP_DATA.EMPLOYEES_AIUFER", line 13 ORA-04088: error during execution of trigger 'APP_DATA.EMPLOYEES_AIUFER' ORA-06512: at "APP_CODE.EMPLOYEES_PKG", line 77 ORA-06512: at line 1 -
Dare al dipendente 101 un nuovo stipendio all'interno dell'intervallo per la propria mansione e mostrare di nuovo informazioni generali su di loro:
EXEC employees_pkg.update_salary( 101, 18000 ); EXEC employees_pkg.show_employee( 101, :c ); PRINT cRisultato:
ATTRIBUTE VALUE --------------- ---------------------------------------------- EMPLOYEE_ID 101 NAME Neena Kochhar EMAIL_ADDR NKOCHHAR HIRE_DATE 21-sep-2005 COUNTRY_CODE +1 PHONE_NUMBER 515.123.4568 JOB_TITLE Administration Vice President JOB_START_DATE 16-mar-05 SALARY 18000 MANAGER Steven King DEPARTMENT_NAME Executive 11 rows selected. -
Modificare la mansione del dipendente 101 nella mansione corrente con uno stipendio inferiore:
EXEC employees_pkg.change_job( 101, 'AD_VP', 17500, 90 );Risultato:
SQL> exec employees_pkg.change_job( 101, 'AD_VP', 17500, 90 ); BEGIN employees_pkg.change_job( 101, 'AD_VP', 17500, 80 ); END; * ERROR at line 1: ORA-02290: check constraint (APP_DATA.JOB_HISTORY_DATE_CHECK) violated ORA-06512: at "APP_CODE.EMPLOYEES_PKG", line 101 ORA-06512: at line 1 -
Mostra informazioni sul dipendente. (Si noti che lo stipendio non è stato modificato dalla dichiarazione nel passo precedente; è 18000, non 17500.)
exec employees_pkg.show_employee( 101, :c ); print cRisultato:
ATTRIBUTE VALUE --------------- ---------------------------------------------- EMPLOYEE_ID 101 NAME Neena Kochhar EMAIL_ADDR NKOCHHAR HIRE_DATE 21-sep-2005 COUNTRY_CODE +1 PHONE_NUMBER 515.123.4568 JOB_TITLE Administration Vice President JOB_START_DATE 10-mar-2015 SALARY 18000 MANAGER Steven King DEPARTMENT_NAME Executive 11 rows selected.
Vedere anche:
-
SQL*Plus User's Guide and Reference per informazioni sui comandi di SQL*Plus
Concessione del privilegio EXECUTE a app_user e app_admin_user
Nota: è necessario essere connessi al database come app_code utente.
Per concedere il privilegio EXECUTE sul package employee_pkg a app_user (in genere un manager) e app_admin_user (un amministratore dell'applicazione), utilizzare le istruzioni GRANT riportate di seguito (in entrambi gli ordini). È possibile immettere le istruzioni in SQL*Plus o nel foglio di lavoro di SQL Developer.
GRANT EXECUTE ON employees_pkg TO app_user;
GRANT EXECUTE ON employees_pkg TO app_admin_user;Vedere anche:
-
Oracle AI Database SQL Language Reference per informazioni sull'istruzione GRANT
Esercitazione: richiamo di get_job_history come app_user o app_admin_user
Utilizzando SQL*Plus, questa esercitazione mostra come richiamare il sottoprogramma app_code.employees_pkg.get_job_history come utente app_user (in genere un manager) o app_admin_user (un amministratore dell'applicazione).
Per richiamare employee_pkg.get_job_history come app_user o app_admin_user:
-
Connettersi al database come utente app_user o app_admin_user da SQL*Plus.
Per le istruzioni, vedere "Connessione a Oracle AI Database da SQL*Plus".
-
Creare il seguente sinonimo:
CREATE SYNONYM employees_pkg FOR app_code.employees_pkg; -
Mostra la cronologia mansione del dipendente 101:
EXEC employees_pkg.get_job_history( 101, :c ); PRINT cRisultato:
NAME JOB_TITLE START_DAT END_DATE --------------- ----------------------------- --------- --------- Neena Kochhar Administration Vice President 16-MAR-05 15-MAY-12 Neena Kochhar Accounting Manager 28-OCT-01 15-MAR-05 Neena Kochhar Public Accountant 21-SEP-97 27-OCT-01