Calcola quota prodotto e valori quota di mercato

Questo esempio di script di calcolo Essbase calcola i valori della quota di prodotto e della quota di mercato calcolando ogni membro come percentuale del totale e come percentuale del relativo padre.

I valori di condivisione vengono calcolati come indicato di seguito.

  • ogni membro come percentuale del totale

  • Ogni membro come percentuale del relativo padre

Si supponga di aver aggiunto quattro membri alla dimensione Misure.

  • Quota di mercato

  • Quota prodotto

  • % mercato

  • % prodotto

Script di esempio:

/* First consolidate the Sales values to ensure that they are accurate */

FIX(Sales)
   CALC DIM(Year, Market, Product);
ENDFIX

/* Calculate each market as a percentage of the total market for each product */

"Market Share" = Sales % Sales -> Market;

/* Calculate each product as a percentage of the total product for each market */

"Product Share" = Sales % Sales -> Product;

/* Calculate each market as a percentage of its parent for each product */

"Market %" = Sales % @PARENTVAL(Market, Sales);

/* Calculate each product as a percentage its parent for each market */

"Product %" = Sales % @PARENTVAL(Product, Sales);

Essbase esegue le azioni riportate di seguito.

  1. Corregge i valori delle vendite e consolida tutti i valori delle vendite.

    Il comando CALC DIM calcola le dimensioni Anno, Mercato e Prodotto. La dimensione Misure contiene il membro Vendite e pertanto non è consolidata. La dimensione Scenario è solo etichetta e pertanto non deve essere consolidata.

  2. Esegue il ciclo del cubo e calcola la quota di mercato prendendo il valore di vendita per ogni prodotto in ciascun mercato per ogni mese e calcolando questo valore di vendita come percentuale delle vendite totali in tutti i mercati per ogni prodotto (vendite -> mercato).

  3. Calcola la quota prodotto prendendo il valore di vendita per ogni prodotto in ciascun mercato per ogni mese e calcolando questo valore di vendita come percentuale delle vendite totali di tutti i prodotti in ciascun mercato (Vendite -> Prodotto).

  4. Calcola la percentuale di mercato prendendo il valore delle vendite per ogni prodotto in ciascun mercato per ogni mese e calcolando questo valore delle vendite come percentuale del valore delle vendite del padre del membro corrente nella dimensione Mercato.

    La funzione @PARENTVAL ottiene il valore Vendite del padre nella dimensione Mercato.

  5. Calcola la percentuale di prodotto prendendo il valore di vendita per ogni prodotto in ciascun mercato per ogni mese e calcolando questo valore di vendita come percentuale del valore di vendita del padre del membro corrente nella dimensione Prodotto.

    @PARENTVAL ottiene il valore Vendite del padre nella dimensione Prodotto.