Criando o pacote employees_pkg
Esta seção mostra como criar o pacote employees_pkg, como seus subprogramas funcionam, como conceder o privilégio EXECUTE no pacote aos usuários que precisam dele e como esses usuários podem chamar um de seus subprogramas.
Para criar o pacote employees_pkg:
-
Conecte-se ao Banco de Dados como app_code do usuário.
Para obter instruções, consulte "Connecting to Oracle AI Database from SQL*Plus" ou "Connecting to Oracle AI Database from SQL Developer".
-
Crie estes sinônimos:
CREATE OR REPLACE SYNONYM employees FOR app_data.employees; CREATE OR REPLACE SYNONYM departments FOR app_data.departments; CREATE OR REPLACE SYNONYM jobs FOR app_data.jobs; CREATE OR REPLACE SYNONYM job_history FOR app_data.job_history;Você pode informar as instruções CREATE SYNONYM no SQL*Plus ou na Planilha do SQL Developer. Como alternativa, você pode criar os sinônimos com a ferramenta SQL Developer Create Synonym.
-
Crie a especificação do pacote.
-
Crie o corpo do pacotes.
Consulte também:
Criando a especificação de pacote para employees_pkg
Observação: Você deve estar conectado ao banco de dados como app_code do usuário.
Para criar a especificação de pacote para employees_pkg, a API para gerentes, use a seguinte instrução CREATE PACKAGE. Você pode informar a instrução no SQL*Plus ou na Planilha do SQL Developer. Como alternativa, você pode criar o pacote com a ferramenta SQL Developer Create Package.
CREATE OR REPLACE PACKAGE employees_pkg
AS
PROCEDURE get_employees_in_dept
( p_deptno IN employees.department_id%TYPE,
p_result_set IN OUT SYS_REFCURSOR );
PROCEDURE get_job_history
( p_employee_id IN employees.department_id%TYPE,
p_result_set IN OUT SYS_REFCURSOR );
PROCEDURE show_employee
( p_employee_id IN employees.employee_id%TYPE,
p_result_set IN OUT SYS_REFCURSOR );
PROCEDURE update_salary
( p_employee_id IN employees.employee_id%TYPE,
p_new_salary IN employees.salary%TYPE );
PROCEDURE change_job
( p_employee_id IN employees.employee_id%TYPE,
p_new_job IN employees.job_id%TYPE,
p_new_salary IN employees.salary%TYPE := NULL,
p_new_dept IN employees.department_id%TYPE := NULL );
END employees_pkg;
/Consulte também:
-
Oracle AI Database PL/SQL Language Reference para informações sobre a instrução CREATE PACKAGE
Criando o corpo do pacote para employees_pkg
Observação: Você deve estar conectado ao banco de dados como app_code do usuário.
Para criar o corpo do pacote para employees_pkg, a API para gerentes, use a seguinte instrução CREATE PACKAGE BODY. Você pode informar a instrução no SQL*Plus ou na Planilha do SQL Developer. Como alternativa, você pode criar o pacote com a ferramenta SQL Developer Create Body.
CREATE OR REPLACE PACKAGE BODY employees_pkg
AS
PROCEDURE get_employees_in_dept
( p_deptno IN employees.department_id%TYPE,
p_result_set IN OUT SYS_REFCURSOR )
IS
l_cursor SYS_REFCURSOR;
BEGIN
OPEN p_result_set FOR
SELECT e.employee_id,
e.first_name || ' ' || e.last_name name,
TO_CHAR( e.hire_date, 'Dy Mon ddth, yyyy' ) hire_date,
j.job_title,
m.first_name || ' ' || m.last_name manager,
d.department_name
FROM employees e INNER JOIN jobs j ON (e.job_id = j.job_id)
LEFT OUTER JOIN employees m ON (e.manager_id = m.employee_id)
INNER JOIN departments d ON (e.department_id = d.department_id)
WHERE e.department_id = p_deptno ;
END get_employees_in_dept;
PROCEDURE get_job_history
( p_employee_id IN employees.department_id%TYPE,
p_result_set IN OUT SYS_REFCURSOR )
IS
BEGIN
OPEN p_result_set FOR
SELECT e.First_name || ' ' || e.last_name name, j.job_title,
e.job_start_date start_date,
TO_DATE(NULL) end_date
FROM employees e INNER JOIN jobs j ON (e.job_id = j.job_id)
WHERE e.employee_id = p_employee_id
UNION ALL
SELECT e.First_name || ' ' || e.last_name name,
j.job_title,
jh.start_date,
jh.end_date
FROM employees e INNER JOIN job_history jh
ON (e.employee_id = jh.employee_id)
INNER JOIN jobs j ON (jh.job_id = j.job_id)
WHERE e.employee_id = p_employee_id
ORDER BY start_date DESC;
END get_job_history;
PROCEDURE show_employee
( p_employee_id IN employees.employee_id%TYPE,
p_result_set IN OUT sys_refcursor )
IS
BEGIN
OPEN p_result_set FOR
SELECT *
FROM (SELECT TO_CHAR(e.employee_id) employee_id,
e.first_name || ' ' || e.last_name name,
e.email_addr,
TO_CHAR(e.hire_date,'dd-mon-yyyy') hire_date,
e.country_code,
e.phone_number,
j.job_title,
TO_CHAR(e.job_start_date,'dd-mon-yyyy') job_start_date,
to_char(e.salary) salary,
m.first_name || ' ' || m.last_name manager,
d.department_name
FROM employees e INNER JOIN jobs j on (e.job_id = j.job_id)
RIGHT OUTER JOIN employees m ON (m.employee_id = e.manager_id)
INNER JOIN departments d ON (e.department_id = d.department_id)
WHERE e.employee_id = p_employee_id)
UNPIVOT (VALUE FOR ATTRIBUTE IN (employee_id, name, email_addr, hire_date,
country_code, phone_number, job_title, job_start_date, salary, manager,
department_name) );
END show_employee;
PROCEDURE update_salary
( p_employee_id IN employees.employee_id%type,
p_new_salary IN employees.salary%type )
IS
BEGIN
UPDATE employees
SET salary = p_new_salary
WHERE employee_id = p_employee_id;
END update_salary;
PROCEDURE change_job
( p_employee_id IN employees.employee_id%TYPE,
p_new_job IN employees.job_id%TYPE,
p_new_salary IN employees.salary%TYPE := NULL,
p_new_dept IN employees.department_id%TYPE := NULL )
IS
BEGIN
INSERT INTO job_history (employee_id, start_date, end_date, job_id,
department_id)
SELECT employee_id, job_start_date, TRUNC(SYSDATE), job_id, department_id
FROM employees
WHERE employee_id = p_employee_id;
UPDATE employees
SET job_id = p_new_job,
department_id = NVL( p_new_dept, department_id ),
salary = NVL( p_new_salary, salary ),
job_start_date = TRUNC(SYSDATE)
WHERE employee_id = p_employee_id;
END change_job;
END employees_pkg;
/Consulte também:
-
Oracle AI Database PL/SQL Language Reference para informações sobre a instrução CREATE PACKAGE BODY
Tutorial: Mostrando como os subprogramas employees_pkg funcionam
Usando o SQL*Plus, este tutorial mostra como os subprogramas do pacote employees_pkg funcionam. O tutorial também mostra como funcionam o acionador employees_aiufer e a constraint CHECK job_history_date_check.
Observação: Você deve estar conectado ao Oracle AI Database como usuário app_code do SQL*Plus.
Para usar o SQL*Plus a fim de mostrar como os subprogramas employees_pkg funcionam:
-
Use comandos de formatação para melhorar a legibilidade da saída. Por exemplo:
SET LINESIZE 80 SET RECSEP WRAPPED SET RECSEPCHAR "=" COLUMN NAME FORMAT A15 WORD_WRAPPED COLUMN HIRE_DATE FORMAT A20 WORD_WRAPPED COLUMN DEPARTMENT_NAME FORMAT A10 WORD_WRAPPED COLUMN JOB_TITLE FORMAT A29 WORD_WRAPPED COLUMN MANAGER FORMAT A11 WORD_WRAPPED -
Declare uma variável de bind para o valor do parâmetro de subprograma p_result_set:
VARIABLE c REFCURSOR -
Mostrar os funcionários no departamento 90:
EXEC employees_pkg.get_employees_in_dept( 90, :c ); PRINT cResultado:
EMPLOYEE_ID NAME HIRE_DATE JOB_TITLE ----------- --------------- -------------------- -------------------------- MANAGER DEPARTMENT ----------- ---------- 100 Steven King Tue Jun 17th, 2003 President Executive =========================================================================== 102 Lex De Haan Sat Jan 13th, 2001 Administration Vice President Steven King Executive =========================================================================== 101 Neena Kochhar Wed Sep 21st, 2005 Administration Vice President Steven King Executive =========================================================================== -
Exiba o histórico de cargos do funcionário 101:
EXEC employees_pkg.get_job_history( 101, :c ); PRINT cResultado:
NAME JOB_TITLE START_DAT END_DATE --------------- ----------------------------- --------- --------- Neena Kochhar Administration Vice President 16-MAR-05 Neena Kochhar Accounting Manager 28-OCT-01 15-MAR-05 Neena Kochhar Public Accountant 21-SEP-97 27-OCT-01 -
Mostrar informações gerais sobre o funcionário 101:
EXEC employees_pkg.show_employee( 101, :c ); PRINT cResultado:
ATTRIBUTE VALUE --------------- ---------------------------------------------- EMPLOYEE_ID 101 NAME Neena Kochhar EMAIL_ADDR NKOCHHAR HIRE_DATE 21-sep-2005 COUNTRY_CODE +1 PHONE_NUMBER 515.123.4568 JOB_TITLE Administration Vice President JOB_START_DATE 16-mar-05 SALARY 17000 MANAGER Steven King DEPARTMENT_NAME Executive 11 rows selected. -
Mostre as informações sobre o cargo Vice-Presidente de Administração:
SELECT * FROM jobs WHERE job_title = 'Administration Vice President';Resultado:
JOB_ID JOB_TITLE MIN_SALARY MAX_SALARY ---------- ----------------------------- ---------- ---------- AD_VP Administration Vice President 15000 30000 -
Tente dar ao funcionário 101 um novo salário fora da faixa salarial de seu cargo:
EXEC employees_pkg.update_salary( 101, 30001 );Resultado:
SQL> EXEC employees_pkg.update_salary( 101, 30001 ); BEGIN employees_pkg.update_salary( 101, 30001 ); END; * ERROR at line 1: ORA-20002: Salary modification invalid ORA-06512: at "APP_DATA.EMPLOYEES_AIUFER", line 13 ORA-04088: error during execution of trigger 'APP_DATA.EMPLOYEES_AIUFER' ORA-06512: at "APP_CODE.EMPLOYEES_PKG", line 77 ORA-06512: at line 1 -
Dê ao funcionário 101 um novo salário dentro do intervalo de seu cargo e mostre as informações gerais sobre ele novamente:
EXEC employees_pkg.update_salary( 101, 18000 ); EXEC employees_pkg.show_employee( 101, :c ); PRINT cResultado:
ATTRIBUTE VALUE --------------- ---------------------------------------------- EMPLOYEE_ID 101 NAME Neena Kochhar EMAIL_ADDR NKOCHHAR HIRE_DATE 21-sep-2005 COUNTRY_CODE +1 PHONE_NUMBER 515.123.4568 JOB_TITLE Administration Vice President JOB_START_DATE 16-mar-05 SALARY 18000 MANAGER Steven King DEPARTMENT_NAME Executive 11 rows selected. -
Altere o cargo do funcionário 101 para seu cargo atual com um salário mais baixo:
EXEC employees_pkg.change_job( 101, 'AD_VP', 17500, 90 );Resultado:
SQL> exec employees_pkg.change_job( 101, 'AD_VP', 17500, 90 ); BEGIN employees_pkg.change_job( 101, 'AD_VP', 17500, 80 ); END; * ERROR at line 1: ORA-02290: check constraint (APP_DATA.JOB_HISTORY_DATE_CHECK) violated ORA-06512: at "APP_CODE.EMPLOYEES_PKG", line 101 ORA-06512: at line 1 -
Mostrar informações sobre o funcionário. (Observe que o salário não foi alterado pela instrução na etapa anterior; é 18000, não 17500.)
exec employees_pkg.show_employee( 101, :c ); print cResultado:
ATTRIBUTE VALUE --------------- ---------------------------------------------- EMPLOYEE_ID 101 NAME Neena Kochhar EMAIL_ADDR NKOCHHAR HIRE_DATE 21-sep-2005 COUNTRY_CODE +1 PHONE_NUMBER 515.123.4568 JOB_TITLE Administration Vice President JOB_START_DATE 10-mar-2015 SALARY 18000 MANAGER Steven King DEPARTMENT_NAME Executive 11 rows selected.
Consulte também:
-
SQL*Plus User's Guide and Reference para obter informações sobre comandos do SQL*Plus
Concedendo o Privilégio EXECUTE a app_user e app_admin_user
Observação: Você deve estar conectado ao banco de dados como app_code do usuário.
Para conceder o privilégio EXECUTE no pacote employees_pkg para app_user (normalmente um gerente) e app_admin_user (um administrador de aplicativo), use as seguintes instruções GRANT (em qualquer uma das ordens). Você pode informar as instruções no SQL*Plus ou na Planilha do SQL Developer.
GRANT EXECUTE ON employees_pkg TO app_user;
GRANT EXECUTE ON employees_pkg TO app_admin_user;Consulte também:
-
Referência de Linguagem SQL do Oracle AI Database para informações sobre a instrução GRANT
Tutorial: Chamando get_job_history como app_user ou app_admin_user
Usando o SQL*Plus, este tutorial mostra como chamar o subprograma app_code.employees_pkg.get_job_history como o usuário app_user (normalmente um gerente) ou app_admin_user (um administrador de aplicativo).
Para chamar employees_pkg.get_job_history como app_user ou app_admin_user:
-
Conecte-se ao banco de dados como usuário app_user ou app_admin_user do SQL*Plus.
Para obter instruções, consulte "Estabelecendo Conexão com o Oracle AI Database no SQL*Plus".
-
Crie o seguinte sinônimo:
CREATE SYNONYM employees_pkg FOR app_code.employees_pkg; -
Exiba o histórico de cargos do funcionário 101:
EXEC employees_pkg.get_job_history( 101, :c ); PRINT cResultado:
NAME JOB_TITLE START_DAT END_DATE --------------- ----------------------------- --------- --------- Neena Kochhar Administration Vice President 16-MAR-05 15-MAY-12 Neena Kochhar Accounting Manager 28-OCT-01 15-MAR-05 Neena Kochhar Public Accountant 21-SEP-97 27-OCT-01