Calcular Participação no Produto e Valores de Participação no Mercado

Este exemplo de script de cálculo do Essbase calcula a participação no produto e os valores de participação no mercado, calculando cada membro como uma porcentagem do total e como uma porcentagem de seu pai.

Os valores de compartilhamento são calculados da seguinte forma:

  • Cada membro como uma porcentagem do total

  • Cada membro como uma porcentagem de seu pai

Suponha que você tenha adicionado quatro membros à dimensão Medidas:

  • Participação no mercado

  • Participação do produto

  • % de mercado

  • % do produto

Exemplo de script:

/* First consolidate the Sales values to ensure that they are accurate */

FIX(Sales)
   CALC DIM(Year, Market, Product);
ENDFIX

/* Calculate each market as a percentage of the total market for each product */

"Market Share" = Sales % Sales -> Market;

/* Calculate each product as a percentage of the total product for each market */

"Product Share" = Sales % Sales -> Product;

/* Calculate each market as a percentage of its parent for each product */

"Market %" = Sales % @PARENTVAL(Market, Sales);

/* Calculate each product as a percentage its parent for each market */

"Product %" = Sales % @PARENTVAL(Product, Sales);

O Essbase executa as seguintes ações:

  1. Corrige os valores de Vendas e consolida todos os valores de Vendas.

    O comando CALC DIM calcula as dimensões Ano, Mercado e Produto. A dimensão Medidas contém o membro Vendas e, portanto, não está consolidada. A dimensão Cenário é somente rótulo e, portanto, não precisa ser consolidada.

  2. Faz o ciclo do cubo e calcula a Participação no Mercado, obtendo o valor de Vendas de cada produto em cada mercado para cada mês e calculando esse valor de Vendas como uma porcentagem do total de Vendas em todos os mercados para cada produto (Vendas -> Mercado).

  3. Calcula a Participação no Produto, obtendo o valor de Vendas de cada produto em cada mercado para cada mês e calculando esse valor de Vendas como uma porcentagem do total de Vendas de todos os produtos em cada mercado (Vendas -> Produto).

  4. Calcula a % de Mercado obtendo o valor de Vendas de cada produto em cada mercado para cada mês e calculando esse valor de Vendas como uma porcentagem do valor de Vendas do pai do membro atual na dimensão de Mercado.

    A função @PARENTVAL obtém o valor de Vendas do pai na dimensão Mercado.

  5. Calcula a % do Produto obtendo o valor de Vendas de cada produto em cada mercado para cada mês e calculando esse valor de Vendas como uma porcentagem do valor de Vendas do pai do membro atual na dimensão Produto.

    @PARENTVAL obtém o valor de Vendas do pai na dimensão Produto.