Referenciando Domínios de Disponibilidade

Em relação aos domínios de disponibilidade, temos cuidado com um padrão comum, conforme mostrado aqui:

// Get all availability domains for the region
data "oci_identity_availability_domains" "ads" {
  compartment_id = "${var.tenancy_ocid}"
}
  
// Then either use it to get a single AD name based on the index:
resource "oci_core_instance" "nat" {
  availability_domain = "${lookup(data.oci_identity_availability_domains.ads.availability_domains[var.nat_instance_ad],"name")}"
  ...
}
  
// Or iterate through all the ADs:
resource "oci_core_subnet" "nat" {
  count = "${length(data.oci_identity_availability_domains.ads.availability_domains)}"
  availability_domain = "${lookup(data.oci_identity_availability_domains.ad.availability_domains[count.index], "name")}"
  ...
}

A recomendação é listar explicitamente os nomes de domínio de disponibilidade para as regiões da sua configuração. Para isso, use uma variável definida da seguinte forma:

variable "ad_list" {
  type = list
}

Você poderá usar a variável conforme mostrado aqui:

// Index:
resource "oci_core_instance" "nat" {
  availability_domain = "${var.ad_list[var.nat_instance_ad_index]}"
  ...
}
  
// Or iterate through all the ADs:
resource "oci_core_subnet" "nat" {
  count = "${length(var.ad_list)}"
  availability_domain = "${var.ad_list[count.index]}"
  ...
}

Em seguida, você poderá definir a variável ad_list diretamente usando os nomes de domínios de disponibilidade para a sua tenant e a sua região, conforme mostrado aqui:

variable "ad_list" {
  type = list
  default = ["kIdk:PHX-AD-1","kIdk:PHX-AD-2","kIdk:PHX-AD-3"]
}

A vantagem de usar esse método é que ele oferece controle sobre o uso do domínio de disponibilidade e impede alterações inesperadas ao longo do tempo. No entanto, essa abordagem é problemática quando as configurações são compartilhadas entre tenancies e regiões, porque os nomes de domínios de disponibilidade são específicos para a tenancy e para a região.

Uma alternativa conveniente é definir o valor ad_list usando a origem de dados oci_identity_availability_domains. Você deve fazer isso na configuração e, em seguida, especificar esses valores para os módulos. Essa opção centraliza de forma eficiente a lista de ADs, facilitando posteriormente a alternância para uma lista explícita, se necessário: observe que os próprios módulos não devem usar a origem de dados oci_identity_availability_domains.

data "oci_identity_availability_domains" "ad" {
  compartment_id = "${var.tenancy_ocid}"
}
 
data "template_file" "ad_names" {
  count = "${length(data.oci_identity_availability_domains.ad.availability_domains)}"
  template = "${lookup(data.oci_identity_availability_domains.ad.availability_domains[count.index], "name")}"
}
  
module "ssm_network" {
  ad_list = "${data.template_file.ad_names.*.rendered}"
  ...
}