OpenTextFile-Methode

Öffnet eine angegebene Datei und gibt ein TextStream-Objekt zurück, das zum Lesen von der Datei, zum Schreiben in die Datei oder zum Anhängen an die Datei verwendet werden kann.

Syntax

object.OpenTextFile(filename[, iomode[, create]])

Argumente:

Object: Erforderlich. "object" ist immer der Name eines FileSystemObject.
Filename: Erforderlich. Zeichenfolgenausdruck, der die zu öffnende Datei identifiziert.
Iomode: Optional. Kann eine von drei Konstanten sein: ForReading, ForWriting oder ForAppending.
Create: Optional. Boolescher Wert, der angibt, ob eine neue Datei erstellt werden kann, wenn der angegebene Dateiname nicht vorhanden ist. Der Wert ist "True", wenn eine neue Datei erstellt wird, "False", wenn sie nicht erstellt wird. Wird diese Option ausgelassen, wird keine neue Datei erstellt.
Format: Optional. Gibt das Format der geöffneten Datei an.

Hinweis:

Das Argument "format" ist inaktiv und wird beibehalten, um die VB-Skriptsyntax nachzuahmen. Es hat keine Auswirkung. Alle Dateien werden im Unicode-Format erstellt.

Einstellungen

Das Argument iomode kann eine der folgenden Einstellungen aufweisen:

Tabelle 11-34 Einstellungen für Argument "IOMode"

Konstante	Wert	Beschreibung
ForReading	1	Öffnen Sie eine Datei nur zum Lesen. Sie können nicht in diese Datei schreiben.
ForWriting	2	Öffnen Sie eine Datei zum Schreiben.
ForWriting	8	Öffnen Sie eine Datei, und fügen Sie Text am Ende der Datei hinzu.

Anmerkungen

Der folgende Code veranschaulicht die Verwendung der OpenTextFile-Methode.

Hinweis:

Wenn eine neue Datei erstellt wird, wird sie im Unicode-Format erstellt.
Wenn die Datei nicht vorhanden ist, löst der Code einen Fehler in ReadMode aus.

Beispiel 1:

Sub OpenFileForReading()
    Const ForReading = 1
    Dim fso, tso
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set tso = fso.OpenTextFile("C:\example1.txt", ForReading)    
    tso.Close               ' Close the file.

    Set tso = Nothing
    Set fso = Nothing
End Sub

Call OpenFileForReading
'If C:\example1.txt is not present then code will throw an error.

Beispiel 2:

Sub OpenFileForWriting()
    Const ForWriting = 2
    Dim fso, file
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set file = fso.OpenTextFile("C:\example2.txt", ForWriting, True)
    
    file.WriteLine("This is written to the file.")   ' Writes text to the file.
    file.Close               ' Close the file.

    Set file = Nothing
    Set fso = Nothing
End Sub

Call OpenFileForWriting
'Creates C:\example2.txt and writes a line "This is written to the file."

Beispiel 3:

Sub OpenFileForAppending()
    Const ForAppending = 8
    Dim fso, file
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set file = fso.OpenTextFile("C:\example2.txt", ForAppending, True)
    
    file.WriteLine("This line is appended.")   ' Appends text to the file.
    file.Close               ' Close the file.

    Set file = Nothing
    Set fso = Nothing
End Sub

Call OpenFileForAppending
'Creates C:\example2.txt and writes a line "This line is appended.". If file already exists it appends this line.

Beispiel 4:

Sub OpenFileWithCreateOption()
    Const ForWriting = 2
    Dim fso, file
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set file = fso.OpenTextFile("C:\example2.txt", ForWriting, True)   ' Creates the file if it doesn't exist.

    file.WriteLine("New File created and text written.")   ' Writes text to the file.
    file.Close               ' Close the file.
 
    Set file = Nothing
    Set fso = Nothing
End Sub

Call OpenFileWithCreateOption
'Overwrites C:\example2.txt and writes a line "New File created and text written.". If file does not exists then it creates it.