시나리오

Calculation Manager 구문:

[[getStartYear("ScenarioName")]]
[[getEndYear("ScenarioName")]]
[[getStartMonth("ScenarioName")]]
[[getEndMonth("ScenarioName")]]
[[PlanningFunctions.getModuleStartYear("ModuleName","ScenarioName")]]
[[PlanningFunctions.getModuleEndYear("ModuleName","ScenarioName")]] 
[[PlanningFunctions.getModuleStartPeriod("ModuleName","ScenarioName")]] 
[[PlanningFunctions.getModuleEndPeriod("ModuleName","ScenarioName")]] 
[[PlanningFunctions.isPlanStartYearSameAsCurrentFiscalYear("ModuleName")]]
  

시나리오 이름

ScenarioName은 입력된 시나리오 멤버 또는 Oracle Hyperion Calculation Manager 런타임 프롬프트 멤버 형식 변수일 수 있습니다. 멤버는 큰 따옴표로 묶어야 합니다. 예: [[getStartYear("Actual")]].

ScenarioName은 다음 형식의 대체 변수일 수도 있습니다.

• getSubVarValue("CubeName", "SubstitutionVariableName")는 CubeName을 통해 정의된 큐브 레벨의 지정된 대체 변수에 대한 대체 변수 값을 반환합니다.

• getSubVarValue("SubstitutionVariableName")는 모든 큐브의 애플리케이션 레벨에서 지정된 대체 변수에 대한 대체 변수 값을 반환합니다.

CubeName 및 SubstitutionVariableName은 큰따옴표로 묶어야 하며 & 또는 {}를 사용하지 마십시오. 아래 예 3 및 예 4를 참조하십시오.

모듈 이름

ModuleName은 Oracle Hyperion Planning 및 Strategic Workforce Planning의 현재 모듈에 대한 사전 정의된 이름이어야 합니다. ModuleName을 매개변수로 사용하는 이러한 표현식은 ScenarioName의 계획 및 예측 준비 구성 태스크 시간 대상 기간 정보를 사용합니다. 해당 시간 대상 기간은 계획 및 예측 시나리오에 대한 하나의 애플리케이션 내에서 모듈별로 다를 수 있습니다.

계획 및 예측 이외의 다른 시나리오도 이러한 표현식에서 참조될 수 있지만, 차원 편집기에서 SPR(Scenario Planning Range)에 대해 설정된 시간 기간만 반환합니다. 이 시간 기간은 해당 애플리케이션 내 모든 모듈에 대해 동일합니다. SPR(Scenario Planning Range)에 대한 자세한 내용은 시나리오 정보를 참조하십시오.

계획 시작 연도는 모듈에 대한 계획 시나리오와 관련된 다른 계획 및 예측 준비 구성 태스크입니다. 이 표현식은 해당 설정에 상대적인 값을 반환하므로 현재 회계 연도로 설정된 경우 정수 값 "1"을 반환하고 다음 회계 연도로 설정된 경우 "0"을 반환합니다. 이 표현식은 차원 멤버를 값으로 반환하지 않으므로 조건부 명령문 컨텍스트 내에서만 사용할 수 있습니다. 아래 예 5를 참조하십시오.

ModuleName에 적합한 값은 다음과 같으며 특정 비즈니스 프로세스에 적용할 수 있습니다.

예 1

다음은 {rtpScenario}가 멤버 유형의 실행 시간 프롬프트 변수이며 기본값은 actual인 구문입니다.

FIX({rtpScenario}, [[getStartYear({rtpScenario})]]:[[getEndYear({rtpScenario})]],
   [[getStartMonth({rtpScenario})]]:[[getEndMonth({rtpScenario})]])
      FIX ( Working, P_000, "111")
        "5800" = 5500;
      ENDFIX
ENDFIX  

위 구문은 다음 스크립트를 반환합니다.

FIX ("Actual", "FY10" : "FY18", "Jan" : "Dec") 
    FIX (Working, P_000, "111") 
      "5800" = 5500;
    ENDFIX 
ENDFIX

예 2

다음 구문의 경우

FIX({rtpScenario}, [[PlanningFunctions.getModuleStartYear("CAPITAL",{rtpScenario})]]:
[[PlanningFunctions.getModuleEndYear("CAPITAL",{rtpScenario})]] , "Jan" : "Dec")
  FIX(OEP_Working, P_000, "111")
    "5800" = 5500;
  ENDFIX
ENDFIX

다음 스크립트를 반환합니다. 여기서 자본 모듈 계획 및 예측 준비 구성 태스크는 계획 시나리오에 대해 FY18 및 FY22 각각의 시작 및 종료 연도를 설정합니다.

FIX("OEP_Plan", "FY18" : "FY22", "Jan" : "Dec")
  FIX(OEP_Working, P_000, "111")
    "5800" = 5500;
  ENDFIX
ENDFIX

예 3

다음 구문에서는 큐브 레벨의 대체 변수를 사용합니다. 이 예에서 Plan1은 큐브 이름이고 CurrentMonth는 대체 변수 이름입니다.

FIX ("OEP_Plan", [[getStartMonth(getSubVarValue("Plan1", "CurrentMonth"))]], "FY15", 
"BU Version_1", "No Currency", "No Entity", "No Grades") 
"Current" = 15; 
ENDFIX

이 구문은 다음 스크립트를 생성합니다.

FIX ("OEP_Plan", "Jan", "FY15", "BU Version_1", "No Currency", "No Entity", "No 
Grades") 
"Current" = 15; 
ENDFIX

예 4

다음 구문에서는 애플리케이션 레벨의 대체 변수를 사용합니다. 이 예에서 CurrentMonth는 대체 변수 이름입니다.

FIX ("OEP_Plan", [[getStartMonth(getSubVarValue("CurrentMonth"))]], "FY15", "BU 
Version_1", "No Currency", "No Entity", "No Grades") 
"Current" = 15; 
ENDFIX 

이 구문은 다음 스크립트를 생성합니다.

FIX ("OEP_Plan", "Jan", "FY15", "BU Version_1", "No Currency", "No Entity", "No 
Grades") 
"Current" = 15; 
ENDFIX

예 5

다음 구문의 경우

FIX("OEP_Plan","OEP_Working",FY20:FY24)
     "Bonus"
     (
     IF([[PlanningFunctions.isPlanStartYearSameAsCurrentFiscalYear ("Workspace")]] == 1)
              "Bonus" = "Salary" * 0.2;
     ELSEIF([[PlanningFunctions.isPlanStartYearSameAsCurrentFiscalYear ("Workforce")]] == 0)
              "Bonus" = "Salary" * 0.3;
     )
ENDFIX

다음 스크립트를 생성합니다. 여기서는 인력 모듈 계획 및 예측 준비 구성 태스크에 계획 시작 연도가 다음 회계 연도로 설정되어 있어 isPlanStartYearSameAsCurrentFiscalYear가 다음 회계 연도로 설정된 경우 정수 "0"을 반환하므로 첫번째 조건 테스트(IF)는 실패하여 실행되지 않고 두번째 조건 테스트(ELSEIF)는 통과하여 실행됩니다.

FIX("OEP_Plan","OEP_Working", FY20:FY24)
     "Bonus"
     (
     IF(0 == 1)
              "Bonus" = "Salary" * 0.2;
     ELSEIF(0 == 0)
              "Bonus" = "Salary" * 0.3;
     )
ENDFIX