145 DBMS_SESSION

このパッケージは、PL/SQLからSQL ALTER SESSION文とSET ROLE文へのアクセスおよび他のセッション情報へのアクセスを提供します。DBMS_SESSIONを使用すると、作業環境とセキュリティ・レベルを設定できます。

この章のトピックは、次のとおりです:

• セキュリティ・モデル

• 操作上のノート

• データ構造

• DBMS_SESSIONサブプログラムの要約

145.1 DBMS_SESSIONのセキュリティ・モデル

このパッケージは、パッケージ所有者SYSではなく、コール・ユーザーの権限で実行されます。

145.2 DBMS_SESSIONの操作上のノート

close_cached_open_cursorsをオンまたはオフに変更しないでください。

145.3 DBMS_SESSIONのデータ構造

DBMS_SESSIONパッケージはTABLEタイプを定義します。

表タイプ

• INTEGER_ARRAY表タイプ

• LNAME_ARRAY表タイプ

145.3.1 DBMS_SERVICE INTEGER_ARRAY表タイプ

INTEGER_ARRAYは、BINARY_INTEGERの表タイプです。

構文

TYPE integer_array IS TABLE OF BINARY_INTEGER INDEX BY BINARY_INTEGER;

145.3.2 DBMS_SERVICE LNAME_ARRAY表タイプ

LNAME_ARRAYは、VARCHAR2の表タイプです。

構文

TYPE lname_array IS TABLE OF VARCHAR2(4000) INDEX BY BINARY_INTEGER;

145.4 DBMS_SESSIONサブプログラムの要約

この表は、DBMS_SESSIONサブプログラムをアルファベット順に示し、簡単に説明しています。

表145-1 DBMS_SESSIONパッケージのサブプログラム

サブプログラム	説明
CLEAR_ALL_CONTEXTプロシージャ	すべてのコンテキスト情報をクリアします。
CLEAR_CONTEXTプロシージャ	コンテキストをクリアします。
CLEAR_IDENTIFIERプロシージャ	識別子をクリアします。
CLOSE_DATABASE_LINKプロシージャ	データベース・リンクをクローズします。
FREE_UNUSED_USER_MEMORYプロシージャ	大量のメモリーが必要な操作を実行した後で未使用のメモリーを再要求できます。
GET_PACKAGE_MEMORY_UTILIZATIONプロシージャ	静的パッケージのメモリー使用量を示します。
IS_ROLE_ENABLEDファンクション	指定のロールがセッションで使用可能かどうかを判別します。
IS_SESSION_ALIVEファンクション	指定されたセッションがアクティブかどうかを判別します。
LIST_CONTEXTプロシージャ	現行のセッションについて、アクティブなネームスペースとコンテキストのリストを戻します。
MODIFY_PACKAGE_STATEプロシージャ	このプロシージャは、セッションでアクティブなすべてのPL/SQLプログラム・ユニットのセッション状態で、action_flagsパラメータで指定された様々なアクションを実行するために使用します。
SESSION_TRACE_DISABLEプロシージャ	コール元のセッションに対するセッション・レベルのSQLトレースを再設定します。
SESSION_TRACE_ENABLEプロシージャ	コール元のセッションに対するセッション・レベルのSQLトレースを使用可能にします。
RESET_PACKAGEプロシージャ	セッション内のすべてのパッケージのインスタンス化を解除します。
SET_CONTEXTプロシージャ	コンテキスト属性の値を設定または再設定します。
SET_EDITION_DEFERREDプロシージャ	指定したエディションへの切替えを要求します。
SET_IDENTIFIERプロシージャ	識別子を設定します。
SET_NLSプロシージャ	グローバリゼーション・サポート(NLS)を設定します。
SET_ROLEプロシージャ	ロールを設定します。
SET_SQL_TRACEプロシージャ	トレースをオンまたはオフにします。
SWITCH_CURRENT_CONSUMER_GROUPプロシージャ	ユーザーの現行のセッションでの、現行のリソース・コンシューマ・グループの変更を容易にします。
UNIQUE_SESSION_IDファンクション	データベースに現在接続しているすべてのセッションに対して一意の識別子を戻します。

145.4.1 CLEAR_ALL_CONTEXTプロシージャ

このプロシージャは、指定されたネームスペースのアプリケーション・コンテキスト情報をクリアします。

構文

DBMS_SESSION.CLEAR_ALL_CONTEXT
   namespace         VARCHAR2);

パラメータ

表145-2 CLEAR_ALL_CONTEXTプロシージャのパラメータ

パラメータ	説明
namespace	アプリケーション・コンテキスト情報をクリアするネームスペース。必須。

使用上のノート

• このプロシージャは、信頼されたパッケージで直接的または間接的に起動する必要があります。

• コンテキスト値の変更はただちに反映され、SYS_CONTEXTによるこの値への後続のコールは最新の値を戻します。

145.4.2 CLEAR_CONTEXTプロシージャ

このプロシージャは、指定されたネームスペースのアプリケーション・コンテキストをクリアします。

構文

DBMS_SESSION.CLEAR_CONTEXT
   namespace         VARCHAR2,
   client_identifier VARCHAR2
   attribute         VARCHAR2);

パラメータ

表145-3 CLEAR_CONTEXTプロシージャのパラメータ

パラメータ	説明
namespace	アプリケーション・コンテキストをクリアするネームスペース。必須。 セッション・ローカル・コンテキストの場合、namespaceの指定は必須です。Session Local Contextとして定義したnamespaceは、グローバルにアクセスされるコンテキストのみに関連付けられるため、client_identifierはオプションとなります。 グローバルにアクセスされるコンテキストの場合、namespaceの指定は必須です。NULLは、client_identifierに対する有効な値です(これは、識別子の設定がないセッションでは、SET_CONTEXTを使用して設定されたコンテキスト(namespace、attribute、value、username、nullなど)を参照できるためです)。
client_identifier	グローバル・コンテキストに適用され、その他のタイプのコンテキストではオプションです(最大64バイト)。
attribute	クリアするネームスペース内の特定の属性(オプション)。デフォルトはNULLです。attributeにNULLを指定すると、このネームスペースのnamespace、attribute、valueがセッションからクリアされます。attributeを指定しないと、namespace引数とclient_identifier引数に関するすべてのコンテキスト情報がクリアされます。

使用上のノート

• このプロシージャは、信頼されたパッケージで直接的または間接的に起動する必要があります。

• コンテキスト値の変更はただちに反映され、SYS_CONTEXTによるこの値への後続のコールは最新の値を戻します。

145.4.3 CLEAR_IDENTIFIERプロシージャ

このプロシージャは、セッションのset_client_idを削除します。

構文

DBMS_SESSION.CLEAR_IDENTIFIER;

使用上のノート

このプロシージャはパブリックで実行可能です。

145.4.4 CLOSE_DATABASE_LINKプロシージャ

このプロシージャは、オープンしているデータベース・リンクをクローズします。これは、SQL文ALTER SESSION CLOSE DATABASE LINK <name>と同じです。

構文

DBMS_SESSION.CLOSE_DATABASE_LINK (
   dblink VARCHAR2);

パラメータ

表145-4 CLOSE_DATABASE_LINKプロシージャのパラメータ

パラメータ	説明
dblink	クローズするデータベース・リンク名。

145.4.5 FREE_UNUSED_USER_MEMORYプロシージャ

このプロシージャは、大量のメモリー(100Kを超えるメモリー)が必要な操作の実行後、未使用のメモリーを再要求します。

大量のメモリーを使用する操作の例を次に示します。

• sort_area_size全部を使用し、sort_area_sizeが数百KBになる大規模なソート処理

• 大規模なPL/SQLパッケージ、プロシージャまたはファンクションのコンパイル処理

• PL/SQL索引表内にある数百KBのデータを格納する処理

v$sesstat固定ビューまたはv$statname固定ビューにある統計情報「セッションUGAメモリー」と「セッションPGAメモリー」を追跡調査して、ユーザー・メモリーを監視できます。これらの統計情報の監視では、このプロシージャが解放したメモリー量も表示されます。

ノート:

このプロシージャは、メモリーが非常に不足している場合のみ使用してください。頻繁には使用せず、慎重に使用してください。

構文

DBMS_SESSION.FREE_UNUSED_USER_MEMORY;

戻り値

このプロシージャの動作は、クライアントのかわりに稼働しているサーバーの構成によって決まります。

• 専用サーバー: 使用されていないPGAメモリーとセッション・メモリーをオペレーティング・システムに戻します。セッション・メモリーは、この構成内のPGAから割り当てられます。

• 共有サーバー: 使用されていないセッション・メモリーをshared_poolに戻します。セッション・メモリーは、この構成内のshared_poolから割り当てられます。

使用上のノート

このプロシージャを使用してメモリーを解放するためには、そのメモリーが使用中でないことが必要です。

ある操作でメモリーを割り当てた後は、同じタイプの操作でのみ、割り当てられたメモリーを再利用できます。たとえば、ソート用に割り当てられたメモリーは、ソート完了後にそのメモリーが使用されなくなると、別のソート処理でのみ再利用できます。ソートとコンパイルについては、操作の完了後にメモリーが使用されなくなると、ユーザーはこのプロシージャをコールして、この未使用メモリーを解放できます。

索引表にはメモリーが暗黙的に割り当てられ、その索引表の要素に割り当てられた値が格納されます。したがって、索引表内の要素が多いほど、RDBMSは多くのメモリーを索引表に割り当てます。索引表に要素がある間は、索引表に関連するメモリーは使用中になります。

索引表の有効範囲によって、メモリーの使用期間が決まります。グローバルに宣言された索引表は、パッケージまたはパッケージ本体で宣言された索引表です。これらの索引表には、セッション・メモリーからメモリーが割り当てられます。グローバルに宣言された索引表では、メモリーは、ユーザーのログイン中(ユーザーのセッションの間)は使用中のままとなり、Oracleから切断された後に解放されます。

ローカルで宣言された索引表は、ファンクション、プロシージャまたは無名ブロック内で宣言された索引表です。このような索引表には、PGAメモリーからメモリーが割り当てられます。ローカルに宣言された索引表については、索引表が宣言されたプロシージャ、ファンクションまたは無名ブロックをユーザーが実行しているかぎり、メモリーは使用中のままになります。プロシージャ、ファンクションまたは無名ブロックの実行が完了すると、そのメモリーはローカルに宣言された他の索引表で使用可能になります(すなわち、メモリーは使用中ではなくなります)。

初期化されていない空の索引表を既存の索引表に割り当てることは、索引表とその索引表に関連付けられたメモリーを明示的に再初期化するための1つの方法です。この操作を行うと、索引表に関連付けられているメモリーは使用中ではなくなり、このプロシージャをコールして解放できます。この方法は、グローバルに宣言した索引表がユーザー・セッションの期間中に大きくなる可能性があり、ユーザーが索引表の内容を必要としない場合は、特に役立ちます。

索引表の有効範囲に関連するメモリー・ルールは適用されたままです。しかし、この方法とプロシージャによって、ユーザーが介入して、索引表に関連付けられているメモリーを明示的に解放できます。

例

次のPL/SQLは、この方法とFREE_UNUSED_USER_MEMORYプロシージャの使用方法を示します。

CREATE PACKAGE foobar
   type number_idx_tbl is table of number indexed by binary_integer;

   store1_table  number_idx_tbl;     --  PL/SQL indexed table
   store2_table  number_idx_tbl;     --  PL/SQL indexed table
   store3_table  number_idx_tbl;     --  PL/SQL indexed table
   ...
END;            --  end of foobar

DECLARE
   ...
   empty_table   number_idx_tbl;     --  uninitialized ("empty") version
BEGIN
   FOR i in 1..1000000 loop
     store1_table(i) := i;           --  load data
   END LOOP;
   ...
   store1_table := empty_table;      --  "truncate" the indexed table
   ... 
   -
   dbms_session.free_unused_user_memory;  -- give memory back to system

   store1_table(1) := 100;           --  index tables still declared;
   store2_table(2) := 200;           --  but truncated.
   ...
END;

145.4.6 GET_PACKAGE_MEMORY_UTILIZATIONプロシージャ

このプロシージャは、静的パッケージのメモリー使用量を示します。

出力コレクションは、インスタンス化された各パッケージでのメモリー使用量を示します。各パッケージは、所有者名、パッケージ名、使用しているメモリー量および未使用の割り当てられたメモリー量によって示されます。メモリーの断片化のため、また一度使用された空きメモリー・チャンクはまずパッケージ・メモリー・ヒープが所有する空きリストに移動されるため、未使用のメモリー量はゼロより大きくなります。FREE_UNUSED_USER_MEMORYプロシージャが起動された場合のみ解放され、親ヒープに戻ります。

構文

DBMS_SESSION.GET_PACKAGE_MEMORY_UTILIZATION (
   owner_names     OUT NOCOPY LNAME_ARRAY,
   unit_names      OUT NOCOPY LNAME_ARRAY,
   unit_types      OUT NOCOPY INTEGER_ARRAY,
   used_amounts    OUT NOCOPY INTEGER_ARRAY,
   free_amounts    OUT NOCOPY INTEGER_ARRAY);

パラメータ

表145-5 GET_PACKAGE_MEMORY_UTILIZATIONファンクションのパラメータ

パラメータ	説明
owner_name	パッケージの所有者。
unit_name	パッケージの名前。
unit_types	ディクショナリ表obj$のtype#列の値。
used_amounts	バイト単位で指定した割当てメモリー量。
free_amounts	バイト単位で指定した使用可能なメモリー量。

145.4.7 IS_ROLE_ENABLEDファンクション

このファンクションは、指定のロールがこのセッションで使用可能かどうかを判別します。

構文

DBMS_SESSION.IS_ROLE_ENABLED (
   rolename    VARCHAR2) 
  RETURN BOOLEAN;

パラメータ

表145-6 IS_ROLE_ENABLEDファンクションのパラメータ

パラメータ	説明
rolename	ロール名。

戻り値

表145-7 IS_ROLE_ENABLEDファンクションの戻り値

戻り値	説明
is_role_enabled	ロールが使用可能かどうかによってTRUEまたはFALSE。

145.4.8 IS_SESSION_ALIVEファンクション

このファンクションは、指定されたセッションがアクティブかどうかを判別します。

構文

DBMS_SESSION.IS_SESSION_ALIVE (
   uniqueid VARCHAR2) 
  RETURN BOOLEAN;

パラメータ

表145-8 IS_SESSION_ALIVEファンクションのパラメータ

パラメータ	説明
uniqueid	セッションの一意のID。UNIQUE_SESSION_IDによって戻されるものと同じ。

戻り値

表145-9 IS_SESSION_ALIVEファンクションの戻り値

戻り値	説明
is_session_alive	セッションがアクティブかどうかによってTRUEまたはFALSE。

145.4.9 LIST_CONTEXTプロシージャ

このプロシージャは、現行のセッションに関するアクティブなネームスペースとコンテキストのリストを戻します。

構文

TYPE AppCtxRecTyp IS RECORD ( 
   namespace VARCHAR2(30), 
   attribute VARCHAR2(30),
   value     VARCHAR2(256)); 

TYPE AppCtxTabTyp IS TABLE OF AppCtxRecTyp INDEX BY BINARY_INTEGER; 

DBMS_SESSION.LIST_CONTEXT ( 
   list OUT AppCtxTabTyp, 
   size OUT NUMBER);

パラメータ

表145-10 LIST_CONTEXTプロシージャのパラメータ

パラメータ	説明
list	現行のセッション内のアプリケーション・コンテキスト設定リストを格納するバッファ。

戻り値

表145-11 LIST_CONTEXTプロシージャの戻り値

戻り値	説明
list	現行セッションの設定(ネームスペース、属性、値)リスト。
size	戻されたバッファ内のエントリ数を戻します。

使用上のノート

リスト内のコンテキスト情報は、<namespace> <attribute> <value>の順に表示されます。listは表タイプの変数なので、そのサイズは戻されるリストのサイズに合わせて動的に調整されます。

145.4.10 MODIFY_PACKAGE_STATEプロシージャ

このプロシージャは、セッションでアクティブなすべてのPL/SQLプログラム・ユニットのセッション状態で、action_flagsパラメータで指定された様々なアクションを実行するために使用します。このプロシージャは、PL/SQLコールで実行中の現行の起動が終了すると、有効になります。

このプロシージャでは、表145-13に示すDBMS_SESSION定数が使用されます。

構文

DBMS_SESSION.MODIFY_PACKAGE_STATE(
   action_flags IN PLS_INTEGER); 

パラメータ

表145-12 MODIFY_PACKAGE_STATEプロシージャのパラメータ

パラメータ

説明

action_flags

PL/SQLプログラム・ユニットで実行するアクションを判別するビット・フラグ。 DBMS_SESSION.FREE_ALL_RESOURCES(または1): セッションから、以前実行したPL/SQLプログラムに関連付けられたメモリーをすべて解放します。グローバルなパッケージの現行の値をクリアし、キャッシュされたカーソルをクローズします。その後の使用では、PL/SQLプログラム・ユニットが再インスタンス化され、グローバルなパッケージが再初期化されます。DBMS_SESSION.FREE_ALL_RESOURCESパラメータでMODIFY_PACKAGE_STATEを起動すると、DBMS_SESSION.RESET_PACKAGE()インタフェースと同一の機能が提供されます。 DBMS_SESSION.REINITIALIZE(または2): 実際にメモリーを解放して最初から再作成せずに、パッケージを再初期化します。パッケージ・メモリーは再利用されます。プログラム・セマンティクスとしては、DBMS_SESSION.REINITIALIZEフラグはDBMS_SESSION.FREE_ALL_RESOURCESフラグと同様、すべてのパッケージを再初期化します。 ただし、次の理由により、DBMS_SESSION.REINITIALIZEはDBMS_SESSION.FREE_ALL_RESOURCESオプションよりも高いパフォーマンスを提供します。 パッケージは、実際にメモリーを解放して始めから再作成せずに再初期化されます。パッケージ・メモリーは再利用されます。 意味的には、すべてのオープン・カーソルはクローズされます。ただし、カーソル・リソースは実際には解放されていません。これは、単にPL/SQLのカーソル・キャッシュに戻ります。このカーソル・キャッシュはフラッシュされません。したがって、PL/SQLで頻繁にアクセスされる静的SQLに対応するカーソルは、PL/SQLカーソル・キャッシュにキャッシュされたままになり、その後に使用するPL/SQL文では、新規カーソルのオープン、解析およびクローズに関わるアプリケーションへのオーバーヘッドがありません。 グローバルな状態でないPL/SQLモジュール(タイプやストアド・プロシージャなど)のセッション・メモリーは、解放されず、再作成されません。

使用上のノート

各フラグの相違点およびDBMS_SESSION.REINITIALIZEがDBMS_SESSION.FREE_ALL_RESOURCESよりも高いパフォーマンスを示す理由は、表145-14のパラメータの説明を参照してください。

表145-13 MODIFY_PACKAGE_STATEのAction_flags定数

定数	説明
FREE_ALL_RESOURCES	PLS_INTEGER:= 1
REINITIALIZE	PLS_INTEGER:= 2

• 再初期化とは、すべてのパッケージ変数を初期値に再設定するプロセス、およびパッケージ本体の初期化ブロック(存在する場合)を実行するプロセスのことです。次のパッケージを想定します。

    package P is
      n number;
      m number := P2.foo;
      d date := SYSDATE;
      cursor c is select * from emp;
      procedure bar;
    end P;
    /
    package body P is
      v   varchar2(20) := 'hello';
      procedure bar is
      begin
        ...
      end;
      procedure init_pkg is
      begin
        ....
      end;
    begin
      -- initialization block
      init_pkg;
      ...
      ...
    end P;
    /

パッケージPでは、再初期化で次の処理を行います。

• P.nをNULLに設定する。

• ファンクションP2.fooを起動し、P.mにP2.fooから戻された値を設定する。

• P.dにSYSDATE組込みの戻り値を設定する。

• カーソルP.cが事前にオープンしている場合は、これをクローズする。

• P.vを'hello'に設定する。

• パッケージ本体の初期化ブロックを実行する。

• パッケージの再初期化は、その後パッケージが実際に参照された場合のみ実行されます。さらに、パッケージは参照された順に再初期化されます。

• FREE_ALL_RESOURCESまたはREINITIALIZEを使用する場合は、パッケージ変数値のリセットによって、アプリケーションに影響を与えないようにしてください。

• DBMS_SESSION.REINITIALIZEは、実際にすべてのパッケージ状態を解放するとはかぎらず、場合によっては、FREE_ALL_RESOURCESフラグやRESET_PACKAGEプロシージャを使用した場合よりも、はるかに大量のセッション・メモリーがアプリケーションで使用されます。たとえばDBMS_SESSION.MODIFY_PACKAGE_STATE(DBMS_SESSION.REINITIALIZE)の実行後、アプリケーションが以前に参照されたパッケージの多くを参照しない場合、これらのパッケージのセッション・メモリーは、セッションの終了まで(またはDBMS_SESSION.RESET_PACKAGEがコールされるまで)保持されます。

• クライアント側のPL/SQLコードは、リモート・パッケージの変数または定数を参照できないため、定数の値を明示的に使用する必要があります。たとえば、DBMS_SESSION.MODIFY_PACKAGE_STATE(DBMS_SESSION.REINITIALIZE)は、定数DBMS_SESSION.REINITIALIZEを使用しているため、クライアント側ではコンパイルしません。

  かわりに、クライアント側ではDBMS_SESSION.MODIFY_PACKAGE_STATE(2)を使用します。これは、引数が明示的に指定されているためです。

例

ここでは、DBMS_SESSION.MODIFY_PACKAGE_STATEの使用例を示します。グローバルな状態(カーソルはc、変数値はcnt)のパッケージPを想定します。パッケージの最初の初期化では、パッケージ変数cntは0、カーソルcはCLOSEDです。次に、セッションで、cntの値が111に変更され、OPEN操作もカーソルで実行されます。print_statusをコールしてパッケージの状態を表示すると、cntが111で、カーソルがOPENであることを確認できます。次に、DBMS_SESSION.MODIFY_PACKAGE_STATEをコールします。print_statusを使用してパッケージPの状態を再度出力すると、cntが再度0になり、カーソルがCLOSEDされていることを確認できます。DBMS_SESSION.MODIFY_PACKAGE_STATEのコールが行われなかった場合は、2番目のprint_statusによって、111およびOPENが出力されます。

create or replace package P is
  cnt    number := 0;
  cursor c is select * from emp;
  procedure print_status;
end P;
/
show errors;

create or replace package body P is
  procedure print_status is
  begin
    dbms_output.put_line('P.cnt = ' || cnt);
    if c%ISOPEN then
      dbms_output.put_line('P.c is OPEN');
    else
      dbms_output.put_line('P.c is CLOSED');
    end if;
  end;
end P;
/
show errors;

SQL> set serveroutput on;
SQL> begin
  2   P.cnt := 111;
  3   open p.c;
  4   P.print_status;
  5  end;
  6  /
P.cnt = 111
P.c is OPEN

PL/SQL procedure successfully completed.

SQL> begin
  2   dbms_session.modify_package_state(dbms_session.reinitialize);
  3  end;
  4  /

PL/SQL procedure successfully completed.

SQL> set serveroutput on;
SQL>
SQL> begin
  2   P.print_status;
  3  end;
  4  /
P.cnt = 0
P.c is CLOSED

PL/SQL procedure successfully completed.

145.4.11 SESSION_TRACE_DISABLEプロシージャ

このプロシージャは、コール元のセッションに対するセッション・レベルのSQLトレースを再設定します。クライアントID、およびサービス、モジュール、アクションのトレースは影響を受けません。

構文

DBMS_SESSION.SESSION_TRACE_DISABLE;

145.4.12 SESSION _TRACE_ENABLEプロシージャ

このプロシージャは、コール元のセッションに対するセッション・レベルのSQLトレースを使用可能にします。このプロシージャを起動すると、セッションによって発行されたすべてのSQL文のSQLトレースが実行されます。

構文

DBMS_SESSION.SESSION_TRACE_ENABLE(
   waits     IN   BOOLEAN DEFAULT TRUE,
   binds     IN   BOOLEAN DEFAULT FALSE, 
   plan_stat IN   VARCHAR2 DEFAULT NULL);

パラメータ

表145-14 SESSION_TRACE_ENABLEプロシージャのパラメータ

パラメータ	説明
waits	待機情報をトレースするかどうかを指定します。
binds	バインド情報をトレースするかどうかを指定します。
plan_stat	行ソース統計をダンプする頻度。値は'NEVER'、'FIRST_EXECUTION'(NULLと同じ)または'ALL_EXECUTIONS'です。

145.4.13 RESET_PACKAGEプロシージャ

このプロシージャは、このセッションのすべてのパッケージのインスタンス化を解除します。これは、パッケージ状態を解放します。

ノート:

「SESSION _TRACE_ENABLEプロシージャ」を参照してください。Oracle9iで導入されているMODIFY_PACKAGE_STATEインタフェースでは、RESET_PACKAGEと同一の機能が提供されます。これは、このセッションのあらゆるPL/SQLパッケージの状態を再初期化するための、効率的で軽量なバリアントです。

実行状態をキャッシュするために使用するメモリーは、セッションで実行されたPL/SQLファンクション、プロシージャおよびパッケージに関連付けられています。

パッケージに関して、このメモリーのコレクションはパッケージ変数の現行の値を保持し、各PL/SQLプログラムによってオープンされたカーソルのキャッシュを制御します。RESET_PACKAGEへのコールは、以前実行した各PL/SQLプログラムに関連付けられていたメモリーをセッションから解放し、この結果、グローバルなパッケージの現行の値はクリアされ、キャッシュされたカーソルはクローズされます。

RESET_PACKAGEは、セッションで失敗したプログラムを確実に再起動するためにも使用できます。パッケージ変数を含んだプログラムが失敗すると、どの変数を初期化しなおす必要があるかを判別することは困難です。RESET_PACKAGEは、すべてのパッケージ変数が初期値に再設定されることを保証します。

構文

DBMS_SESSION.RESET_PACKAGE; 

使用上のノート

すべての実行PL/SQLが消費するメモリーは大量になるため、RESET_PACKAGEを使用して、データベース・アプリケーション内のある時点でセッション・メモリー・フットプリントを削減できます。ただし、パッケージ変数値の再設定がアプリケーションに影響を与えないことを確認してください。また、キャッシュしたメモリーとカーソルのないプログラムを後で実行すると、解放されたメモリーとカーソルを再作成する必要があるため、実行速度が遅くなることに留意してください。

RESET_PACKAGEは、メモリー、カーソルおよびパッケージ変数をコール直後に解放しません。

ノート:

RESET_PACKAGEは、起動したPL/SQLコールの実行が完了した後でのみ、メモリー、カーソルおよびパッケージ変数を解放します。

たとえば、PL/SQLプロシージャP1がPL/SQLプロシージャP2をコールし、P2がRESET_PACKAGEをコールしたとします。プロシージャP1の実行が完了するまで(PL/SQLコールが終了するまで)、RESET_PACKAGEの処理は行われません。

例

SQL*Plusスクリプトは、多数のPL/SQLプログラム・ユニットを伴った大きいプログラムを実行します。これらのプログラム・ユニットでは、グローバル変数を使用する場合もしない場合もあります。ただし、実行後はグローバル変数は必要ありません。

EXCECUTE large_plsql_program1; 
 

キャッシュされたPL/SQLセッション・メモリーを解放するには:

EXECUTE DBMS_SESSION.RESET_PACKAGE; 
 

別の大きいプログラムを実行するには:

EXECUTE large_plsql_program2;

145.4.14 SET_CONTEXTプロシージャ

このプロシージャは、4つのタイプのコンテキスト(セッション・ローカル、グローバルな初期化、外部的な初期化およびグローバルなアクセス)を設定します。

次の5つのパラメータのうち最初の3つのみが必須となっており、後の2つはオプションでグローバルにアクセスされるコンテキストのみで使用されます。パラメータ情報の詳細は、パラメータ表および「使用上のノート」に示されています。

構文

DBMS_SESSION.SET_CONTEXT (
   namespace VARCHAR2,
   attribute VARCHAR2,
   value     VARCHAR2,
   username  VARCHAR2,
   client_id VARCHAR2 );

パラメータ

表145-15 SET_CONTEXTプロシージャのパラメータ

パラメータ	説明
namespace	設定するアプリケーション・コンテキストのネームスペース(30バイトに制限)。
attribute	設定するアプリケーション・コンテキストの属性(30バイトに制限)。
value	設定するアプリケーション・コンテキストの値(4KBに制限)。
username	アプリケーション・コンテキストのデータベース・ユーザー名属性。 デフォルト: NULL
client_id	アプリケーション・コンテキストのアプリケーション固有のclient_id属性(最大64バイト)。 デフォルト: NULL

使用上のノート

• 最初の3つのパラメータは、すべてのコンテキスト・タイプに対して必須です。

• usernameパラメータは、有効なSQL識別子である必要があります。

• client_idパラメータは、最大64バイトの文字列である必要があります。これは大/小文字を区別し、set_identifierに対して提供される引数と一致させる必要があります。

• ネームスペース・パラメータがグローバル・コンテキストのネームスペースである場合、usernameパラメータはセッションの現行のデータベース・ユーザー名と一致し、client_idパラメータはセッションの現行のclient_idと一致します。これらのパラメータが設定されていない場合はNULLとみなされるため、どのユーザーもコンテキスト値を表示することができます。

• このプロシージャは、信頼されたパッケージで直接的または間接的に起動する必要があります。

• SET_CONTEXTのコール元は、CREATE CONTEXT文を介してコンテキスト・ネームスペースに関連付けられたプロシージャのコール・スタックに存在する必要があります。コール・スタックのチェックは、DBMSの境界を越えません。

• ネームスペースに設定できる属性の数に制限はありません。属性は、ユーザーによってリセットされないかぎり、ユーザーのセッション時に値を保持します。

• パラメータの値がネームスペースで設定されている場合、SET_CONTEXTがこの値を上書きします。

• コンテキスト値の変更はただちに反映され、SYS_CONTEXTによるこの値への後続のコールは最新の値を戻します。

参照:

次の詳細は、『Oracle Databaseセキュリティ・ガイド』を参照してください。

• ユーザー名およびクライアントIDの設定に関する項

• クライアントのセッションIDを使用するグローバル・アプリケーション・コンテキストの作成の例に関する項

145.4.15 SET_EDITION_DEFERREDプロシージャ

このプロシージャは、指定したエディションへの切替えを要求します。切替えは、現行のクライアント・コールの終了時に有効になります。

構文

DBMS_SESSION.SET_EDITION_DEFERRED (
   edition    IN    VARCHAR2);

パラメータ

表145-16 SET_EDITION_DEFERREDプロシージャのパラメータ

パラメータ	説明
edition	切替え先となるエディション名。文字列の内容はSQL識別子として処理され、実際のエディション名に特殊文字または小文字が含まれている場合は、残りの文字列を二重引用符で囲む必要があります(二重引用符を使用しない場合、内容は大文字に設定されます)。コール元には、指定したエディションに対するUSE権限が必要です。

145.4.16 SET_IDENTIFIERプロシージャ

このプロシージャは、セッションのクライアントIDを設定します。

構文

DBMS_SESSION.SET_IDENTIFIER (
   client_id VARCHAR2);

パラメータ

表145-17 SET_IDENTIFIERプロシージャのパラメータ

パラメータ	説明
client_id	現行のデータベース・セッションのアプリケーション固有の識別子で、大/小文字の区別があります。 このパラメータの最大バイト数は、64バイトです。入力が64バイトを超えると、追加のバイトは切り捨てられます。

使用上のノート

• SET_IDENTIFIERは、セッションのクライアントIDを指定された値に設定します。この値を使用すれば、v$session.client_identifierによってv$session内のセッションを識別できます。また、sys_context('USERENV','CLIENT_IDENTIFIER')によってセッションを識別するためにも使用できます。

• このプロシージャはPUBLICで実行可能です。

145.4.17 SET_NLSプロシージャ

このプロシージャは、グローバリゼーション・サポート(NLS)を設定します。これは、SQL文ALTER SESSION SET <nls_parameter> = <value>と同じです。

構文

DBMS_SESSION.SET_NLS (
   param VARCHAR2, 
   value VARCHAR2);

パラメータ

表145-18 SET_NLSプロシージャのパラメータ

パラメータ	説明
param	グローバリゼーション・サポートのパラメータ。このパラメータ名は、'NLS'で開始する必要があります。
value	パラメータ値。 パラメータがテキスト・リテラルの場合は、埋込みの一重引用符が必要です。例としては、set_nls ('nls_date_format','''DD-MON-YY''')があげられます。

145.4.18 SET_ROLEプロシージャ

このプロシージャは、ロールを使用可能または使用禁止にします。これは、SET ROLE SQL文と同等です。

構文

DBMS_SESSION.SET_ROLE (
   role_cmd VARCHAR2);

パラメータ

表145-19 SET_ROLEプロシージャのパラメータ

パラメータ	説明
role_cmd	テキストが"set role"に追加され、SQLとして実行されます。

使用上のノート

このプロシージャは、既存のトランザクション内からコールされない場合、新しいトランザクションを作成することに注意してください。

145.4.19 SET_SQL_TRACEプロシージャ

このプロシージャは、トレースをオンまたはオフにします。これは、SQL文ALTER SESSION SET SQL_TRACE ...と同じです。

構文

DBMS_SESSION.SET_SQL_TRACE (
   sql_trace boolean);

パラメータ

表145-20 SET_SQL_TRACEプロシージャのパラメータ

パラメータ	説明
sql_trace	TRUEはトレースをオンにし、FALSEはトレースをオフにします。

145.4.20 SWITCH_CURRENT_CONSUMER_GROUPプロシージャ

このプロシージャは、ユーザーの現行のセッションでの現行のリソース・コンシューマ・グループを変更します。

ある特定のグループに対して切替え権限がある場合は、コンシューマ・グループを切り替えることができます。コール元が別のプロシージャの場合、ユーザーは、そのプロシージャの所有者が切替え権限を持っているコンシューマ・グループに切り替えることができます。

構文

DBMS_SESSION.switch_current_consumer_group (
   new_consumer_group     IN  VARCHAR2, 
   old_consumer_group     OUT VARCHAR2, 
   initial_group_on_error IN  BOOLEAN); 

パラメータ

表145-21 SWITCH_CURRENT_CONSUMER_GROUPプロシージャのパラメータ

パラメータ	説明
new_consumer_group	切り替える先のコンシューマ・グループの名前。
old_consumer_group	切り替える元のコンシューマ・グループの名前。
initial_group_on_error	TRUEの場合は、エラー発生時にコール元の現行のコンシューマ・グループが初期コンシューマ・グループとして設定されます。

戻り値

このプロシージャは、old_consumer_groupパラメータにある、ユーザーの古いコンシューマ・グループを出力します。

ノート:

old_consumer_groupで戻された値を使用して、古いコンシューマ・グループに後で切り替えることができます。

例外

表145-22 SWITCH_CURRENT_CONSUMER_GROUPプロシージャの例外

例外	説明
29368	コンシューマ・グループが存在しません。
1031	権限が不十分です。
29396	OTHER_GROUPSコンシューマ・グループに切り替えることができません。

使用上のノート

プロシージャの所有者には、ユーザーを古いコンシューマ・グループに再切替えするために、ユーザーの古いグループ(old_consumer_group)に対する権限が必要です。このプロシージャには1つの例外があり、ユーザーを初期コンシューマ・グループにいつでも切り替えることができます(権限チェックはスキップ)。

initial_group_on_errorをTRUEに設定すると、SWITCH_CURRENT_CONSUMER_GROUPプロシージャは、new_consumer_groupが指定したグループに現行のセッションを設定できない場合、そのセッションをデフォルト・グループに設定します。現行のコンシューマ・グループが初期コンシューマ・グループに変更されていても、new_consumer_groupへのセッションの移動に関連するエラーは発生します。

例

CREATE OR REPLACE PROCEDURE high_priority_task is 
   old_group varchar2(30); 
   prev_group varchar2(30); 
   curr_user varchar2(30);  
BEGIN 
  -- switch invoker to privileged consumer group. If we fail to do so, an 
  -- error is thrown, but the consumer group does not change 
  -- because 'initial_group_on_error' is set to FALSE 
 
  dbms_session.switch_current_consumer_group('tkrogrp1', old_group, FALSE); 
  -- set up exception handler (in the event of an error, we do not want to 
  -- return to caller while leaving the session still in the privileged 
  -- group) 
 
  BEGIN 
    -- perform some operations while under privileged group 
 
  EXCEPTION 
    WHEN OTHERS THEN 
     -- It is possible that the procedure owner does not have privileges 
     -- on old_group. 'initial_group_on_error' is set to TRUE to make sure 
     -- that the user is moved out of the privileged group in such a 
     -- situation 
 
     dbms_session.switch_current_consumer_group(old_group,prev_group,TRUE); 
     RAISE; 
    END; 
 
  -- we've succeeded. Now switch to old_group, or if cannot do so, switch 
  -- to caller's initial consumer group 
 
  dbms_session.switch_current_consumer_group(old_group,prev_group,TRUE); 
END high_priority_task; 
/  

145.4.21 UNIQUE_SESSION_IDファンクション

このファンクションは、データベースに現在接続しているすべてのセッションに対して一意の識別子を戻します。同じセッション中にこのファンクションを複数回コールしても、常に同じ結果が戻されます。

構文

DBMS_SESSION.UNIQUE_SESSION_ID 
  RETURN VARCHAR2;

プラグマ

pragma restrict_references(unique_session_id,WNDS,RNDS,WNPS);

戻り値

表145-23 UNIQUE_SESSION_IDファンクションの戻り値

戻り値	説明
unique_session_id	最大24バイトまで戻します。