45.20 GET_DISPLAY_DATAファンクションのシグネチャ2

このファンクションは、1つの値参照ではなく、p_search_value_listで提供されるすべての値を参照します。

構文

APEX_PLUGIN_UTIL.GET_DISPLAY_DATA (
    p_sql_statement        IN VARCHAR2,
    p_min_columns          IN NUMBER,
    p_max_columns          IN NUMBER,
    p_component_name       IN VARCHAR2,
    p_display_column_no    IN BINARY_INTEGER DEFAULT 1,
    p_search_column_no     IN BINARY_INTEGER DEFAULT 2,
    p_search_value_list    IN apex_application_global.vc_arr2,
    p_display_extra        IN BOOLEAN        DEFAULT TRUE,
    p_escape_display_extra IN BOOLEAN        DEFAULT TRUE,
    p_auto_bind_items      IN BOOLEAN        DEFAULT TRUE,
    p_bind_list            IN t_bind_list    DEFAULT c_empty_bind_list,
    RETURN apex_application_global.vc_arr2;

パラメータ

パラメータ	説明
p_sql_statement	参照に使用されるSQL文。
p_min_columns	戻り列の最小数。
p_max_columns	戻り列の最大数。
p_component_name	エラーが戻される場合、エラー・メッセージが表示される際のページ・アイテムまたはレポート列の名前として、この値が使用されます。
p_display_column_no	SQL文から戻される列の数。p_min_columnsからp_max_columnsまでの範囲内である必要があります。
p_search_column_no	SQL文を制限するために使用する列の数。p_min_columnsからp_max_columnsまでの範囲内である必要があります。
p_search_value_list	参照する値の配列。
p_display_extra	TRUEを設定すると、値が見つからなかい場合に、かわりに検索値が結果に追加されます。
p_escape_display_extra	TRUEの場合、p_search_stringは、"追加表示"値として追加されているとエスケープされます。
p_auto_bind_items	APEXアイテム(ページおよびアプリケーション・アイテム)を自動的にバインドするかどうか。
p_bind_list	SQL問合せに使用する追加のバインド変数。

戻り値

戻り値	説明
apex_application_global.vc_arr2	pls_integerで索引付けされるVARCHAR2のリスト。p_search_value_listのエントリごとに、p_display_column_noで指定された列の最初のレコードの値が、p_search_value_listと同じ順序で結果の配列に含まれます。パラメータp_display_extraにTRUEが設定されていると、レコードが見つからない場合にp_search_stringの値が含まれます。そうでない場合は、値がスキップされます。

例

値7863、7911および7988を参照し、LOV問合せの対応する表示列の値で、HTMLリストを生成します。

function render_list (
    p_plugin              in apex_plugin.t_plugin,
    p_item                in apex_plugin.t_page_item,
    p_value               in varchar2,
    p_is_readonly         in boolean,
    p_is_printer_friendly in boolean )
    return apex_plugin.t_page_item_render_result
is
    l_search_list apex_application_global.vc_arr2;
    l_result_list apex_application_global.vc_arr2;
begin
    l_search_list(1) := '7863';
    l_search_list(2) := '7911';
    l_search_list(3) := '7988';
    --
    l_result_list :=
        apex_plugin_util.get_display_data (
            p_sql_statement     => p_item.lov_definition,
            p_min_columns       => 2,
            p_max_columns       => 2,
            p_component_name    => p_item.name,
            p_search_column_no  => 1,
            p_search_value_list => l_search_list );
    --
    sys.htp.p('<ul>');
    for i in 1 .. l_result_list.count
    loop
        sys.htp.p(
            '<li>'||
            sys.htf.escape_sc(l_result_list(i))||
            '</li>');
    end loop;
    sys.htp.p('</ul>');
end render_list;