Integration von täglichen Daten automatisieren

In diesem Szenario wird die Verwendung eines Beispielskripts zur regelmäßigen Automatisierung der Datenintegration untersucht.

Um Integrationsaktivitäten zu automatisieren, erstellen Sie eine Batch- (.bat) oder Shell-Datei (.sh) mit einem ähnlichen Skript wie das folgende. Das folgende Beispielskript für Windows automatisiert die Integration von täglichen Anwendungsdaten, indem die folgenden Aktivitäten abgeschlossen werden:

  • Melden Sie sich bei einer Umgebung an.
  • Löschen Sie DailyPlanData, falls vorhanden.
  • Laden Sie DailyPlanData in den Service hoch.
  • Führen Sie die Geschäftsregel Clear Plan Targets (Planziele löschen) für den Plantyp Plan1 aus.
  • Importieren Sie Daten mit dem Jobnamen LoadDailyPlan.
  • Führen Sie die Geschäftsregel Balance Sheet - Plan (Bilanz - Plan) aus.
  • Führen Sie die Geschäftsregel Allocate Plan Targets (Planziele umlegen) aus.
  • Löschen Sie DailyTarget.zip, falls vorhanden.
  • Exportieren Sie Daten mit dem Jobnamen ExportDailyTarget in die Datei DailyTarget.zip.
  • Laden Sie DailyTarget.zip auf Ihren Server herunter, und hängen Sie den Zeitstempel an.
  • Melden Sie sich von der Umgebung ab.

Hinweis:

Wenn Sie dieses Skript an Ihre Zwecke anpassen möchten, müssen Sie die Werte für die Parameter SET url und SET user ändern. Zusätzlich können Sie die Werte für die Parameter dataimportfilename, dataexportfilename, importdatajobname, exportdatajobname, br_clear, br_calculatebalancesheet und br_allocatetarget an Ihre Bedürfnisse anpassen.

Informationen zum Planen von Skripten mit der Windows-Aufgabenplanung finden Sie unter Skriptausführung automatisieren.

@echo off

rem Sample Script to demonstrate daily data integration with 
rem Cloud EPM application.
rem This script uploads Plan data, clears target numbers,
rem runs a business rule to calculate balance sheet data, and 
rem recalculates target numbers on the Vision demo application

rem Please update these parameters
SET url=https://example.oraclecloud.com
SET user=serviceAdmin
SET dataimportfilename=DailyPlanData.csv
SET dataexportfilename=DailyTarget
SET importdatajobname=LoadDailyPlan
SET exportdatajobname=ExportDailyTarget
SET br_clear=Clear Plan Targets
SET br_calculatebalancesheet=Balance Sheet - Plan
SET br_allocatetarget=Allocate Plan Targets

SET password=%1

rem Executing EPM Automate commands

CD /D %~dp0
call epmautomate login %user% %password% %url%
IF %ERRORLEVEL% NEQ 0 goto :ERROR

for /f %%i in ('call epmautomate listfiles') do if %%i==%dataimportfilename% (call epmautomate deletefile %%i)
IF %ERRORLEVEL% NEQ 0 goto :ERROR

call epmautomate uploadfile %dataimportfilename%
IF %ERRORLEVEL% NEQ 0 goto :ERROR

call epmautomate runbusinessrule "%br_clear%"
IF %ERRORLEVEL% NEQ 0 goto :ERROR

call epmautomate importdata "%importdatajobname%"
IF %ERRORLEVEL% NEQ 0 goto :ERROR

call epmautomate runbusinessrule "%br_calculatebalancesheet%"
IF %ERRORLEVEL% NEQ 0 goto :ERROR

call epmautomate runbusinessrule "%br_allocatetarget%" "TargetVersion=Baseline"
IF %ERRORLEVEL% NEQ 0 goto :ERROR

for /f %%i in ('call epmautomate listfiles') do if %%i=="%dataexportfilename%.zip" (call epmautomate deletefile %%i)
IF %ERRORLEVEL% NEQ 0 goto :ERROR

call epmautomate exportdata %exportdatajobname% "%dataexportfilename%.zip"
IF %ERRORLEVEL% NEQ 0 goto :ERROR

call epmautomate downloadfile "%dataexportfilename%.zip"
IF %ERRORLEVEL% NEQ 0 goto :ERROR

rem Section to rename the file

Set Timestamp=%date:~4,2%_%date:~7,2%_%date:~10,4%_%time:~1,1%%time:~3,2%%
ren "%dataexportfilename%.zip" "%dataexportfilename%_%Timestamp%.zip"

call epmautomate logout
IF %ERRORLEVEL% NEQ 0 goto :ERROR

:EOF
echo Scheduled Task Completed successfully
exit /b %errorlevel%

:ERROR
echo Failed with error #%errorlevel%.
exit /b %errorlevel%