Escenarios

Exponga como expresiones el horizonte temporal Rango de planificación de escenario y la información de la tarea de configuración Preparación de planes y previsiones del módulo, lo cual le permite especificar lo siguiente:

Año de inicio: devuelve el año de inicio en formato de cadena para el escenario proporcionado.
Año de finalización: devuelve el año de finalización en formato de cadena para el escenario proporcionado.
Mes de inicio: devuelve el mes de inicio en formato de cadena para el escenario proporcionado.
Mes de finalización: devuelve el mes de finalización en formato de cadena para el escenario proporcionado.
Año de inicio del módulo: devuelve el año de inicio en formato de cadena para el escenario y el módulo proporcionados.
Año de finalización del módulo: devuelve el año de finalización en formato de cadena para el escenario y el módulo proporcionados.
Periodo de inicio del módulo: devuelve el periodo de inicio en formato de cadena para el escenario y el módulo proporcionados.
Periodo de finalización del módulo: devuelve el periodo de finalización en formato de cadena para el escenario y el módulo proporcionados.
Año de inicio del plan del módulo: devuelve un valor entero de "1" si es el Año fiscal actual y "0" si es el Siguiente año fiscal.

Nota:

Module Start Year, Module End Year, Module Start Period, Module End Period y Module Plan Start Year solo son válidos para las aplicaciones Planning Modules y Strategic Workforce Planning y requieren la sintaxis "PlanningFunctions".

Sintaxis de Calculation Manager:

[[getStartYear("ScenarioName")]]
[[getEndYear("ScenarioName")]]
[[getStartMonth("ScenarioName")]]
[[getEndMonth("ScenarioName")]]
[[PlanningFunctions.getModuleStartYear("ModuleName","ScenarioName")]]
[[PlanningFunctions.getModuleEndYear("ModuleName","ScenarioName")]] 
[[PlanningFunctions.getModuleStartPeriod("ModuleName","ScenarioName")]] 
[[PlanningFunctions.getModuleEndPeriod("ModuleName","ScenarioName")]] 
[[PlanningFunctions.isPlanStartYearSameAsCurrentFiscalYear("ModuleName")]]

Nombre de escenario

ScenarioName puede ser un miembro de escenario introducido o una variable de tipo miembro de petición de datos en tiempo de ejecución de Calculation Manager. El miembro debe estar entre comillas dobles. Por ejemplo, [[getStartYear("Actual")]].

ScenarioName también puede ser una variable de sustitución con los siguientes formatos:

getSubVarValue("CubeName", "SubstitutionVariableName") devuelve el valor de la variable de sustitución para una variable de sustitución dada en el nivel de cubo definido por CubeName
getSubVarValue("SubstitutionVariableName") devuelve el valor de la variable de sustitución para una variable de sustitución dada en el nivel de aplicación para todos los cubos

CubeName y SubstitutionVariableName deben encerrarse entre comillas dobles; no se debe utilizar & ni {}. Consulte los ejemplos 3 y 4 a continuación.

Nombre de módulo

ModuleName debe ser un nombre predefinido de un módulo actual en Planning y en Strategic Workforce Planning. Estas expresiones que utilizan ModuleName como parámetro usan la información del horizonte temporal de las tareas de configuración Preparación de planes y previsiones para ScenarioName, que puede tener diferentes horizontes temporales por módulo dentro de una aplicación para Escenarios de planes y previsiones.

En estas expresiones se puede hacer referencia a otros escenarios además de los planes y las previsiones, pero solo se devolverá el horizonte temporal definido para Rango de planificación de escenario en el editor de dimensiones, que será el mismo para todos los módulos dentro de la aplicación. Consulte Acerca de los escenarios para obtener más información sobre Rango de planificación de escenario.

Año de inicio del plan es otra tarea de configuración de Preparación de planes y previsiones que es específica del escenario del plan para los módulos. Esta expresión devuelve un valor relativo a su configuración de manera que devuelve el valor entero "1" si se define en Año fiscal actual, y "0" si se define en Siguiente año fiscal. Esta expresión solo está disponible en el contexto de una sentencia condicional, dado que no devuelve un miembro de dimensión como valor. Consulte el ejemplo 5 a continuación.

Los valores válidos de ModuleName son los siguientes y se aplican al proceso de negocio específico:

Tabla 10-4 Valores de ModuleName válidos

Proceso de negocio	Valor de `ModuleName` válido
Planning Modules	"Capital" "Financials" "Projects" "Workforce"
Strategic Workforce Planning	"Strategic Workforce" "Workforce"

Nota:

El valor ModuleName debe estar encerrado entre comillas dobles y no distingue entre mayúscula y minúscula.

Ejemplo 1

La siguiente sintaxis, donde {rtpScenario} es una variable de petición de datos en tiempo de ejecución de tipo miembro con un valor predeterminado actual:

FIX({rtpScenario}, [[getStartYear({rtpScenario})]]:[[getEndYear({rtpScenario})]],
   [[getStartMonth({rtpScenario})]]:[[getEndMonth({rtpScenario})]])
      FIX ( Working, P_000, "111")
        "5800" = 5500;
      ENDFIX
ENDFIX

devuelve el siguiente script:

FIX ("Actual", "FY10" : "FY18", "Jan" : "Dec") 
    FIX (Working, P_000, "111") 
      "5800" = 5500;
    ENDFIX 
ENDFIX

Ejemplo 2

Utilice la siguiente sintaxis:

FIX({rtpScenario}, [[PlanningFunctions.getModuleStartYear("CAPITAL",{rtpScenario})]]:
[[PlanningFunctions.getModuleEndYear("CAPITAL",{rtpScenario})]] , "Jan" : "Dec")
  FIX(OEP_Working, P_000, "111")
    "5800" = 5500;
  ENDFIX
ENDFIX

devuelve el siguiente script, donde la tarea de configuración Preparación de planes y previsiones del módulo Capital ha definido el año de inicio y de finalización en FY18 y FY22, respectivamente, para el escenario del plan:

FIX("OEP_Plan", "FY18" : "FY22", "Jan" : "Dec")
  FIX(OEP_Working, P_000, "111")
    "5800" = 5500;
  ENDFIX
ENDFIX

Ejemplo 3

En la siguiente sintaxis se utiliza una variable de sustitución en el nivel de cubo. En este ejemplo, Plan1 es el nombre del cubo CurrentMonth es el nombre de la variable de sustitución.

FIX ("OEP_Plan", [[getStartMonth(getSubVarValue("Plan1", "CurrentMonth"))]], "FY15", 
"BU Version_1", "No Currency", "No Entity", "No Grades") 
"Current" = 15; 
ENDFIX

Este genera el siguiente script:

FIX ("OEP_Plan", "Jan", "FY15", "BU Version_1", "No Currency", "No Entity", "No 
Grades") 
"Current" = 15; 
ENDFIX

Ejemplo 4

En la siguiente sintaxis se utiliza una variable de sustitución en el nivel de aplicación. En este ejemplo, CurrentMonth es el nombre de la variable de sustitución.

FIX ("OEP_Plan", [[getStartMonth(getSubVarValue("CurrentMonth"))]], "FY15", "BU 
Version_1", "No Currency", "No Entity", "No Grades") 
"Current" = 15; 
ENDFIX

Este genera el siguiente script:

FIX ("OEP_Plan", "Jan", "FY15", "BU Version_1", "No Currency", "No Entity", "No 
Grades") 
"Current" = 15; 
ENDFIX

Ejemplo 5

Utilice la siguiente sintaxis:

FIX("OEP_Plan","OEP_Working",FY20:FY24)
     "Bonus"
     (
     IF([[PlanningFunctions.isPlanStartYearSameAsCurrentFiscalYear ("Workspace")]] == 1)
              "Bonus" = "Salary" * 0.2;
     ELSEIF([[PlanningFunctions.isPlanStartYearSameAsCurrentFiscalYear ("Workforce")]] == 0)
              "Bonus" = "Salary" * 0.3;
     )
ENDFIX

genera el siguiente script, en el que la tarea de configuración Preparación de planes y previsiones del módulo Workforce tiene el Año de inicio del plan definido en Siguiente año fiscal de manera que la primera prueba condicional (IF) falla y no se ejecuta, mientras que la segunda prueba condicional (ELSEIF) aprueba y se ejecuta, ya que isPlanStartYearSameAsCurrentFiscalYear devuelve el entero "0" si se define en Siguiente año fiscal:

FIX("OEP_Plan","OEP_Working", FY20:FY24)
     "Bonus"
     (
     IF(0 == 1)
              "Bonus" = "Salary" * 0.2;
     ELSEIF(0 == 0)
              "Bonus" = "Salary" * 0.3;
     )
ENDFIX