Invio del report attività via e-mail tramite uno script Groovy su lato server

Questo script può essere utilizzato per inviare tramite e-mail il report attività a un elenco di destinatari. È quindi possibile programmare l'esecuzione giornaliera dello script in modo da ottenere il report attività giornaliero. Lo script esegue le funzioni elencate di seguito.

  • Cifra la password dell'amministratore servizi che esegue lo script Groovy.
  • Accede all'ambiente Oracle Enterprise Performance Management Cloud utilizzando la password cifrata.
  • Invia tramite e-mail il report attività disponibile nell'ambiente a un elenco di destinatari, in genere amministratori servizi
  • Esegue la disconnessione dall'ambiente.

Se le password contengono caratteri speciali, fare riferimento alla sezione Gestione dei caratteri speciali. Assicurarsi inoltre di sostituire i valori dei parametri elencati di seguito a seconda degli ambienti.

Table 4-2 Parametri da modificare

Parametro Descrizione
user ID utente di un amministratore servizi per l'accesso all'ambiente.
password Password dell'amministratore servizi.
url URL dell'ambiente EPM Cloud da cui deve essere inviato tramite e-mail il report attività.
emailaddresses Elenco separato da punti e virgole contenente indirizzi e-mail a cui deve essere inviato il report attività.

Per informazioni dettagliate sull'utilizzo delle regole Groovy, fare riferimento alla sezione Utilizzo delle regole Groovy nel manuale Amministrazione di Planning.

/*RTPS: {user} {password} {url} {emailaddresses}*/
import java.text.SimpleDateFormat

String user = 'service_administrator'
String password = 'examplePWD'
String url = 'example_EPM_URL'
String emailaddresses = 'service_administrator@oracle.com'

EpmAutomate automate = getEpmAutomate()

def LogMessage(String message) {
    def date = new Date()
    def sdf = new SimpleDateFormat("MM/dd/yyyy HH:mm:ss")
    println('[' + sdf.format(date) + '][GROOVY] ' + message);
}

def LogOperationStatus(EpmAutomateStatus opstatus) {
    def returncode = opstatus.getStatus()
    LogMessage(opstatus.getOutput())
    LogMessage('return code: ' + returncode)
}

LogMessage('Starting mail activity report processing')

// encrypt
LogMessage("Operation: encrypt " + password + " oracleKey password.epw")
EpmAutomateStatus status = automate.execute('encrypt',password,"oracleKey","password.epw")
LogOperationStatus(status)

// login
LogMessage("Operation: login " + user + " password.epw " + url)
status = automate.execute('login',user,"password.epw",url)
LogOperationStatus(status)

// listfiles
LogMessage('Operation: listfiles')
status = automate.execute('listfiles')
LogOperationStatus(status)

String filelist = status.getItemsList()
String[] str = filelist.split(',');
String reportfile = ''

for( String svalues : str ) {
    String[] ftr = svalues.split('/')
    for( String fvalues : ftr ) {
        if (fvalues.startsWith('2') && fvalues.endsWith('html')) {
            reportfile = fvalues
        }
    }
}

def reportdir = reportfile.tokenize(".")[0]
String reportpath = 'apr/' + reportdir + '/' + reportfile

// sendMail
LogMessage('Operation: sendMail ' + emailaddresses + ' Daily Activity Report Body=Daily Activity Report Attachments=' + reportpath)
status = automate.execute('sendmail',emailaddresses,'Daily Activity Report','Body=Daily Activity Report',"Attachments=${reportpath}")
LogOperationStatus(status)

// logout
LogMessage('Operation: logout')
status = automate.execute('logout')
LogOperationStatus(status)