Υπολογισμός επιλεγμένων πλειάδων

Με την επιλογή πλειάδων, μπορείτε να εστιάσετε τους υπολογισμούς σας Essbase στον ενεργό πλέγμα Smart View, περιορίζοντας την εμβέλειά τους σε συγκεκριμένες ενότητες δεδομένων στον κύβο αποθήκευσης μπλοκ.

Η επιλογή πλειάδων σάς βοηθά να βελτιστοποιήσετε ασύμμετρους υπολογισμούς πλέγματος μεταξύ διαστάσεων, αποφεύγοντας τον διπλό υπολογισμό.

Οι πλειάδες υπολογισμού Essbase διαφέρουν από τις πλειάδες που χρησιμοποιούνται σε ερωτήματα MDX. Η απόδοση υπολογισμών και το μέγεθος κύβων επηρεάζονται κυρίως από τον αριθμό των μπλοκ στον κύβο (δεδομένου ενός συγκεκριμένου μεγέθους μπλοκ). Για τον λόγο αυτό, οι πλειάδες υπολογισμού προσδιορίζονται μόνο για συνδυασμούς αραιών μελών. Επιπλέον, για πιο εύκολη δημιουργία δεσμών υπολογισμού, κατά τον προσδιορισμό μιας πλειάδας υπολογισμού μπορούν να συμπεριληφθούν πολλαπλά μέλη από μία αραιή διάσταση. Για παράδειγμα, εάν προσδιορίσετε ως πλειάδα υπολογισμού το ("New York", "California", "Actual", "Cola"), τότε θα υπολογίσετε τις εξής διασταυρώσεις κελιών:

"New York"->"Actual"->"Cola"
"California"->"Actual"->"Cola"

Εξετάστε το ακόλουθο συμμετρικό πλέγμα. Είναι συμμετρικό επειδή για κάθε προϊόν στο πλέγμα αναπαριστώνται οι ίδιες αγορές και το ίδιο σενάριο (Actual).

Το ακόλουθο πλέγμα είναι ασύμμετρο, επειδή το προϊόν Diet Cola έχει λιγότερες αγορές στο πλέγμα από το προϊόν Cola.

Το προεπιλεγμένο εύρος υπολογισμού, όταν υπάρχουν περισσότερες από μία διαστάσεις σε μια πρόταση FIX ή σε μια άποψη προβολής (POV) του πλέγματος Smart View , είναι ο υπολογισμός του γινόμενου (όλων των πιθανών συνδυασμών) των μελών στην πρόταση FIX ή στο πλέγμα. Με άλλα λόγια, ένας υπολογισμός βάσει POV όπου οι συνδυασμοί προϊόντων και αγορών λαμβάνονται από το πλέγμα υπολογίζει όλους αυτούς τους συνδυασμούς σειρών-μελών:

Cola->"New York"
Cola->"Massachusetts"
Cola->"Florida"
Cola->"Connecticut"
Cola->"New Hampshire"
"Diet Cola"->"New York"
"Diet Cola"->"Massachusetts"
"Diet Cola"->"Florida"
"Diet Cola"->"Connecticut"
"Diet Cola"->"New Hampshire"

Αυτή η δραστηριότητα υπολογισμών ίσως είναι πιο εκτενής από ό,τι χρειάζεστε. Εάν θέλετε να υπολογίσετε μόνο τους συνδυασμούς που εμφανίζονται στο πλέγμα, μπορείτε να προσδιορίσετε ποιες πλειάδες θέλετε να υπολογιστούν και να περιορίσετε τον υπολογισμό σε ένα μικρότερο τμήμα. Ο υπολογισμός πλειάδων μπορεί επίσης να μειώσει τον χρόνο υπολογισμού και το μέγεθος κύβων.

Cola->"New York"
Cola->"Massachusetts"
Cola->"Florida"
Cola->"Connecticut"
Cola->"New Hampshire"
"Diet Cola"->"New York"
"Diet Cola"->"Florida"

Μια πλειάδα υπολογισμού είναι μια μέθοδος για την αναπαράσταση ενός τμήματος δεδομένων μελών, από δύο ή περισσότερες αραιές διαστάσεις, που θα χρησιμοποιηθεί σε έναν υπολογισμό χώρου αποθήκευσης μπλοκ Essbase.

Παραδείγματα έγκυρων πλειάδων υπολογισμού:

• ("Diet Cola", "New York")
• ("Diet Cola", "Cola", Florida)
• (Cola, "New Hampshire")

Εάν συντάσσετε εκφράσεις MDX, μπορεί να γνωρίζετε αυτούς τους περιορισμούς πλειάδων που ισχύουν για MDX:

• Σε μια πλειάδα MDX μπορεί να συμπεριληφθεί μόνο ένα μέλος από κάθε διάσταση
• Σε όλες τις πλειάδες σε ένα σύνολο MDX πρέπει να αναπαριστώνται οι ίδιες διαστάσεις, με την ίδια σειρά

Ωστόσο, όταν επιλέγετε πλειάδες σε δέσμες ενεργειών υπολογισμού, αυτές οι απαιτήσεις είναι πιο ελαστικές, για λόγους ευκολίας. Μπορείτε ελεύθερα να συντάσσετε εκφράσεις πλειάδας και οι πλειάδες μπορούν να περιγράφουν λίστες μελών, όπως στην ακόλουθη πλειάδα: (@Children(East), Cola).

Ένας εύκολος τρόπος για να επιλέξετε πλειάδες είναι να τις εισαγάγετε ρητά σε μια δέσμη ενεργειών υπολογισμού, ως λίστα εντός της πρότασης FIX.

Θυμηθείτε ότι η μορφή μιας πρότασης FIX είναι ως εξής:

FIX (fixMbrs)
COMMANDS ;
ENDFIX

Στην παρακάτω πρόταση FIX, καθορίζονται δύο πλειάδες πριν ξεκινήσει το μπλοκ εντολής. Οι πλειάδες περικλείονται σε άγκιστρα { } που οριοθετούν ένα σύνολο, δηλαδή μια συλλογή πλειάδων.

FIX({
  (@Children(East), Cola),
  ("New York", Florida, "Diet Cola")
  })
Sales (Sales = Sales + 10;);
ENDFIX

Ένας άλλος τρόπος να επιλέξετε πλειάδες είναι συγκειμενικά, βάσει οποιωνδήποτε μελών υπάρχουν σε μια POV πλέγματος Smart View κατά την ώρα εκτέλεσης του υπολογισμού. Αυτό το κάνετε παρέχοντας τη συνάρτηση @GRIDTUPLES ως όρισμα στο FIX, στη δέσμη ενεργειών υπολογισμού σας.

FIX ({@GRIDTUPLES(Product, Market)})
   Sales (Sales = Sales + 10;);
ENDFIX

Εάν εκτελέσετε αυτήν τη δέσμη ενεργειών υπολογισμού από το Smart View έναντι του παρακάτω πλέγματος, τότε υπολογίζονται μόνο οι εμφανιζόμενοι συνδυασμοί προϊόντων και αγορών. Για παράδειγμα, δεν υπολογίζεται το "Diet Cola"->Massachusetts, καθώς δεν εμφανίζεται ρητά στο πλέγμα. Λάβετε υπόψη ότι υπολογίζονται όλα τα σενάρια (η τρίτη αραιή διάσταση σε αυτό το δείγμα κύβου), αν και μόνο το "Actual" εμφανίζεται στο πλέγμα. Αυτό συμβαίνει επειδή η διάσταση "Scenario" δεν είναι μέρος της πρότασης GRIDTUPLES στη δέσμη ενεργειών υπολογισμού.

Η επιλογή πλειάδων, είτε πραγματοποιείται με τη χρήση ρητών λιστών πλειάδων είτε με τη χρήση της συνάρτησης @GRIDTUPLES, εφαρμόζεται μόνο στο πλαίσιο της εντολής υπολογισμού FIX…ENDFIX. Η σύνταξη της πρότασης FIX επεκτείνεται επιτρέποντας την επιλογή πλειάδων:

FIX ([{ tupleList | @GRIDTUPLES(dimensionList) },] fixMbrs)
COMMANDS ;
ENDFIX

• tupleList - σύνολο πλειάδων διαχωρισμένων με κόμμα.
• dimensionList - τουλάχιστον δύο αραιές διαστάσεις, τα μέλη των οποίων από το ενεργό πλέγμα Smart View χρησιμοποιούνται για τον ορισμό των περιοχών υπολογισμού. (Στις δέσμες ενεργειών υπολογισμού, μπορείτε να χρησιμοποιήσετε μόνο αραιές διαστάσεις για τον ορισμό πλειάδων.)
• fixMbrs - ένα μέλος ή μια λίστα μελών.

Χρησιμοποιώντας ένα πλέγμα Smart View και μια πρόταση FIX δέσμης ενεργειών υπολογισμού Essbase, μπορείτε να υπολογίσετε επιλεγμένες πλειάδες μελών βάσει της άποψης προβολής (POV) του πλέγματος. Εναλλακτικά, μπορείτε να πληκτρολογήσετε ρητούς συνδυασμούς πλειάδων στην πρόταση FIX, καταργώντας την εξάρτηση σε ένα συγκεκριμένο πλέγμα Smart View για τον ορισμό του εύρους υπολογισμού.

Ο υπολογισμός επιλεγμένων πλειάδων σάς βοηθά να εργαστείτε αποδοτικά με ασύμμετρες περιοχές σε δέσμες ενεργειών υπολογισμού και πλέγματα Smart View .

Εξετάστε τα παρακάτω παραδείγματα:

• Καμία επιλογή πλειάδας - Υπολογίζει με τον προεπιλεγμένο τρόπο, βάσει της τρέχουσας άποψης προβολής (POV) του πλέγματος Smart View. Ο υπολογισμός δεν περιορίζεται σε συγκεκριμένες πλειάδες.
• Επιλογή προσδιορισμένων αραιών διαστάσεων - Υπολογίζει πλειάδες από δύο ή περισσότερες αραιές διαστάσεις που έχουν προσδιοριστεί σε μια δέσμη ενεργειών υπολογισμού. Ο υπολογισμός περιορίζεται σε μέλη από τις διαστάσεις πλειάδας που υφίστανται στο πλέγμα Smart View .
• Επιλογή συγκειμενικών αραιών διαστάσεων - Υπολογίζει πλειάδες από αραιές διαστάσεις που επιλέγονται κατά τον χρόνο εκτέλεσης. Ο υπολογισμός περιορίζεται σε μέλη από τις διαστάσεις πλειάδας που υφίστανται στο πλέγμα Smart View .

Για να δοκιμάσετε τα παραδείγματα, πραγματοποιήστε λήψη του προτύπου βιβλίου εργασίας CalcTuple_Tuple.xlsx από την ενότητα "Τεχνικά > Υπολογισμός" του φακέλου "Συλλογή" στην περιοχή "Αρχεία" του περιβάλλοντος εργασίας web του Essbase. Για οδηγίες ανατρέξτε στο φύλλο εργασίας README στο βιβλίο εργασίας.

SET RUNTIMESUBVARS
{
ProductGridMembers = POV
<RTSV_HINT><svLaunch>
<description>All Product's members on the grid</description>
<type>member</type>
<dimension>Product</dimension><choice>multiple</choice>
</svLaunch></RTSV_HINT>;
MarketGridMembers = POV
<RTSV_HINT><svLaunch>
<description>All Market's members on the grid</description>
<type>member</type> <dimension>Market</dimension><choice>multiple</choice>
</svLaunch></RTSV_HINT>;
};
FIX (
&ProductGridMembers, &MarketGridMembers
)
Marketing(
   Marketing = Marketing +1;
);
ENDFIX

FIX (
{@GRIDTUPLES(Product, Market)}
)
Marketing(
   Marketing = Marketing + 1;
);
ENDFIX

SET RUNTIMESUBVARS
            {
            DimSelections = "Version", "Site", "Entity", "Product", "Market"
            <RTSV_HINT><svLaunch>
            <description>List two or more sparse dimensions used for forming calculation tuples:</description>
            <type>string</type>
            </svLaunch></RTSV_HINT>;
            };
            FIX (
            {@GRIDTUPLES(&DimSelections)}
            )
            Marketing(
            Marketing = Marketing + 1;
            );
            ENDFIX