Valittujen monikkojen laskenta

Valitsemalla monikkoja voit keskittyä Essbase-laskutoimituksiin aktiivisessaSmart View -ruudukossa ja rajata niiden laajuuden tiettyihin tietoviipaleisiin lohkotallennuskuutiossa.

Monikkovalinnalla voidaan optimoida asymmetrisia ruudukon laskutoimituksia dimensioissa ja estää ylilaskennan.

Essbasen laskentamonikot eroavat MDX-kyselyissä käytetyistä monikoista. Laskennan suorituskykyä ja kuution kokoa ohjataan pääasiassa kuution lohkojen lukumäärällä (tietyn lohkokoon mukaan). Tämän vuoksi laskentamonikkoja määritetään vain harvojen jäsenten yhdistelmille. Lisäksi laskennan komentosarjojen helpottamiseksi laskentamonikon määritykseen voidaan lisätä useita jäseniä, jotka ovat peräisin yhdestä harvasta dimensiosta. Jos esimerkiksi määrität laskentamonikoksi ("New York", "California", "Actual", "Cola"), lasket seuraavat solujen leikkauskohdat:

"New York"->"Actual"->"Cola"
"California"->"Actual"->"Cola"

Tarkastellaan seuraavaa symmetristä ruudukkoa. Se on symmetrinen, koska kaikilla tuotteilla on samat markkina-alueet ja sama skenaario (Actual).

Seuraava ruudukko on asymmetrinen, koska Diet Cola -tuotteella on ruudukossa vähemmän markkina-alueita kuin Cola-tuotteella.

Jos useampi kuin yksi dimensio on FIX-lauseessa tai Smart View -ruudukon näkökulmassa, laskennan oletuslaajuus on laskea FIX-lauseen tai ruudukon jäsenten ristitulo (kaikki mahdolliset yhdistelmät). Toisin sanoen näkökulmalähtöisessä laskennassa, jossa tuote- ja markkinayhdistelmät otetaan ruudukosta, lasketaan kaikki nämä rivi-jäsen-yhdistelmät:

Cola->"New York"
Cola->"Massachusetts"
Cola->"Florida"
Cola->"Connecticut"
Cola->"New Hampshire"
"Diet Cola"->"New York"
"Diet Cola"->"Massachusetts"
"Diet Cola"->"Florida"
"Diet Cola"->"Connecticut"
"Diet Cola"->"New Hampshire"

Laskutoimituksia saattaa olla enemmän kuin tarvitset. Jos haluat laskea vain ruudukossa näkyvät yhdistelmät, voit määrittää laskettavat monikot ja rajoittaa laskennan pienempään viipaleeseen. Monikkojen laskenta vähentää myös laskenta-aikaa ja pienentää kuution kokoa.

Cola->"New York"
Cola->"Massachusetts"
Cola->"Florida"
Cola->"Connecticut"
Cola->"New Hampshire"
"Diet Cola"->"New York"
"Diet Cola"->"Florida"

Monikkolaskenta on tapa esittää Essbase-lohkotallennuslaskennassa käytettävä, vähintään kahdesta harvasta dimensiosta peräisin olevien jäsenten tietosektori.

Esimerkkejä sallituista laskentamonikoista:

• ("Diet Cola", "New York")
• ("Diet Cola", "Cola", Florida)
• (Cola, "New Hampshire")

Jos kirjoitat MDX-lausekkeita, kannattaa ottaa huomioon nämä MDX:ää koskevat monikkorajoitukset:

• MDX-monikkoon voidaan liittää vain yksi jäsen kustakin dimensiosta
• MDX-joukon kaikissa monikoissa on oltava samat dimensiot samassa järjestyksessä

Kun valitset monikkoja laskentakomentosarjoissa, näistä vaatimuksista kuitenkin joustetaan. Voit kirjoittaa monikkolausekkeita vapaasti ja monikot saattavat kuvata jäsenlistoja, kuten seuraava monikko tekee: (@Children(East), Cola).

Helppo tapa valita monikkoja on lisätä ne erikseen laskentakomentosarjaan, FIX-lauseen sisällä olevana listana.

Muista, että FIX-lauseen muoto on seuraava:

FIX (fixMbrs)
COMMANDS ;
ENDFIX

Alla olevassa FIX-lauseessa määritetään kaksi monikkoa, ennen kuin komentolohko alkaa. Monikot ovat aaltosulkeiden { } välissä, ja niillä erotetaan joukko eli monikkojen kokoelma.

FIX({
  (@Children(East), Cola),
  ("New York", Florida, "Diet Cola")
  })
Sales (Sales = Sales + 10;);
ENDFIX

Monikot voidaan valita myös kontekstuaalisesti sen perusteella, mitä jäseniä Smart View -ruudukon näkökulmassa on laskenta-ajon aikana. Voit tehdä sen määrittämällä @GRIDTUPLES-funktion FIX-lauseen argumentiksi laskentakomentosarjaan.

FIX ({@GRIDTUPLES(Product, Market)})
   Sales (Sales = Sales + 10;);
ENDFIX

Jos suoritat tämän laskentakomentosarjan Smart View -ohjelmassa alla olevaa ruudukkoa käyttäen, lasketaan vain näkyvissä olevat tuotteiden ja markkina-alueiden yhdistelmät. Esimerkiksi yhdistelmää "Diet Cola"->Massachusetts ei lasketa, koska se ei näy ruudukossa. Huomaa, että kaikki skenaariot (kolmas harva dimensio tässä mallikuutiossa) lasketaan, vaikka ruudukossa näkyy vain Actual. Tämä johtuu siitä, että Scenario-dimensio ei ole osa GRIDTUPLES-lausetta laskentakomentosarjassa.

Monikkovalinta on käytettävissä vain FIX…ENDFIX-laskentakomennon kontekstissa riippumatta siitä, tehdäänkö se erillisiä monikkolistoja vai @GRIDTUPLES-funktiota käyttäen. FIX-lauseen syntaksi on laajennettu monikon valinnan käyttöönottoa varten:

FIX ([{ tupleList | @GRIDTUPLES(dimensionList) },] fixMbrs)
COMMANDS ;
ENDFIX

• tupleList - Pilkuilla erotettu monikkojen joukko.
• dimensionList - Laskenta-alueen määrityksessä käytetään vähintään kahta harvaa dimensiota, joiden jäsenet ovat peräisin Smart View -ruudukosta. (Laskentakomentosarjoissa voidaan käyttää vain harvoja dimensioita monikkojen määritykseen.)
• fixMbrs - Lista jäsenistä.

Käyttämällä Smart View -ruudukkoa ja Essbase-laskentakomentosarjan FIX-lausetta voit laskea valittuja jäsenten monikkoja ruudukon näkökulman perusteella. Voit myös kirjoittaa monikkoyhdistelmät erikseen FIX-lauseeseen sekä määrittää laskennan laajuuden poistamalla riippuvuuden tietystä Smart View -ruudukosta.

Valittujen monikkojen laskenta auttaa työskentelemään tehokkaasti asymmetrisia alueita käyttäen sekä laskentakomentosarjoissa että Smart View -ruudukoissa.

Tarkastellaan seuraavia esimerkkejä:

• Ei monikon valintaa - Laskenta suoritetaan oletustavalla, nykyisen Smart View -ruudukon näkökulman perusteella. Laskenta ei ole rajoitettu tiettyihin monikkoihin.
• Nimettyjen harvojen dimensioiden valinta - Laskee monikot vähintään kahdesta harvasta dimensiosta, jotka nimetty laskentakomentosarjassa. Laskenta on rajoitettu jäseniin, jotka ovat peräisin Smart View -ruudukossa olevista monikkodimensioista.
• Kontekstuaalisten harvojen dimensioiden valinta - Laskee monikot ajon aikana valituista harvoista dimensioista. Laskenta on rajoitettu jäseniin, jotka ovat peräisin Smart View -ruudukossa olevista monikkodimensioista.

Voit kokeilla esimerkkejä noutamalla CalcTuple_Tuple.xlsx-työkirjamallipohjan Essbasen web-käyttöliittymän Tiedostot-alueen Galleria-kansion valikkopolusta Tekninen > Lask. Ohjeita on työkirjan README-työarkissa.

SET RUNTIMESUBVARS
{
ProductGridMembers = POV
<RTSV_HINT><svLaunch>
<description>All Product's members on the grid</description>
<type>member</type>
<dimension>Product</dimension><choice>multiple</choice>
</svLaunch></RTSV_HINT>;
MarketGridMembers = POV
<RTSV_HINT><svLaunch>
<description>All Market's members on the grid</description>
<type>member</type> <dimension>Market</dimension><choice>multiple</choice>
</svLaunch></RTSV_HINT>;
};
FIX (
&ProductGridMembers, &MarketGridMembers
)
Marketing(
   Marketing = Marketing +1;
);
ENDFIX

FIX (
{@GRIDTUPLES(Product, Market)}
)
Marketing(
   Marketing = Marketing + 1;
);
ENDFIX

SET RUNTIMESUBVARS
            {
            DimSelections = "Version", "Site", "Entity", "Product", "Market"
            <RTSV_HINT><svLaunch>
            <description>List two or more sparse dimensions used for forming calculation tuples:</description>
            <type>string</type>
            </svLaunch></RTSV_HINT>;
            };
            FIX (
            {@GRIDTUPLES(&DimSelections)}
            )
            Marketing(
            Marketing = Marketing + 1;
            );
            ENDFIX