חישוב רשומות Tuple נבחרות

על-ידי בחירה ברשומת tuple, אתה יכול למקד את חישובי Essbase שלך ברשת מבט חכם הפעילה, ולהגביל את ההיקף שלהם לפרוסות ספציפיות של נתונים בקוביית האחסון בבלוקים שלך.

בחירה ברשומות Tuple מסייעת לך למטב חישובי רשת לא סימטרית בין ממדים, ובכך להימנע מחישוב-יתר.

רשומות tuple של Essbase שונות מרשומות tuple שבהן נעשה שימוש בשאילתות MDX. ביצועי החישוב וגודל הקובייה נקבעים בעיקר לפי מספר הבלוקים במסד הנתונים (אם נתון גודל בלוק ספציפי). מסיבה זו, מציינים רשומות tuple לחישוב לקומבינציות של איברי sparse בלבד. בנוסף לכך, להקלה על כתיבת תסריטי חישוב, ניתן לכלול ריבוי איברים מתוך ממד sparse אחד במפרט של רשומת tuple לחישוב. לדוגמה, אם תציין את רשומת ה-tuple לחישוב כך: ("ניו יורק", "קליפורניה", "בפועל", "קולה") תחשב את חיתוכי התאים הבאים:

"New York"->"Actual"->"Cola"
"California"->"Actual"->"Cola"

חשוב על הרשת הסימטרית הבאה: היא סימטרית כיוון שלכל מוצר מיוצגים ברשת אותם השווקים ואותו התרחיש (בפועל).

הרשת הבאה אינה סימטרית כיוון שלמוצר 'דיאט קולה' יש פחות שווקים ברשת מאשר למוצר 'קולה'.

כאשר יש יותר מממד אחד במשפט FIX או בנקודת מבט (POV) של רשת Smart View, ברירת המחדל של היקף החישוב הוא חישוב של המוצרים הצולבים (כל הקומבינציות האפשריות) של האיברים ב-FIX או ברשת. במילים אחרות, חישוב המונע באמצעות נקודת מבט שבו קומבינציות המוצר והשוק נלקחות מהרשת, מחשב את כל הקומבינציות הבאות של שורה-איבר:

Cola->"New York"
Cola->"Massachusetts"
Cola->"Florida"
Cola->"Connecticut"
Cola->"New Hampshire"
"Diet Cola"->"New York"
"Diet Cola"->"Massachusetts"
"Diet Cola"->"Florida"
"Diet Cola"->"Connecticut"
"Diet Cola"->"New Hampshire"

ייתכן שפעילות חישוב זו היא יותר ממה שאתה צריך. אם ברצונך לחשב רק את הקומבינציות המוצגות ברשת, תוכל לציין אילו רשומות tuple יש לחשב ובכך להגביל את החישוב לפרוסה קטנה יותר. חישוב רשומות tuple עשוי גם לצמצם את זמן החישוב ואת גודל הקובייה.

Cola->"New York"
Cola->"Massachusetts"
Cola->"Florida"
Cola->"Connecticut"
Cola->"New Hampshire"
"Diet Cola"->"New York"
"Diet Cola"->"Florida"

רשומת tuple לחישוב היא דרך להצגת פרוסת נתונים של איברים, מתוך שניים או יותר של ממדי sparse, כדי לעשות בה שימוש בחישוב אחסון בבלוקים של Essbase.

דוגמאות לרשומות Tuple תקפות לחישוב:

• ("דיאט קולה", "ניו יורק")
• ("דיאט קולה", "קולה", פלורידה)
• (קולה, "ניו המפשייר")

אם תכתוב ביטויי MDX תצטרך להיות מודע למגבלות הבאות של ה-tuple החלות על MDX:

• ניתן לכלול איבר אחד בלבד מכל ממד ברשומת MDX tuple
• בכל רשומות ה-tuple בסל MDX חייב להיות ייצוג לאותם הממדים ובאותו הסדר

עם זאת, כשבוחרים רשומות tuple בתסריטי חישוב, דרישות אלה מוסרות לצורך נוחות. תוכל לכתוב ביטויי tuple בחופשיות וביטויי ה-tuple יכולים לתאר רשימות איברים, כמו רשומת ה-tuple הבאה: (@Children(East), Cola).

דרך קלה לבחור רשומות tuple היא להוסיף אותן באופן מפורש בתסריט חישוב, כרשימה בתוך משפט ה-FIX.

זכור שהפורמט של משפט ה-FIX הוא כלהלן:

FIX (fixMbrs)
COMMANDS ;
ENDFIX

במשפט ה-FIX להלן, צוינו שתי רשומות tuple לפני שמתחיל בלוק הפקודה. רשומות ה-tuple מופיעות בין סוגריים מסולסלים { } שתוחמים סל שהוא אוסף של רשומות tuple.

FIX({
  (@Children(East), Cola),
  ("New York", Florida, "Diet Cola")
  })
Sales (Sales = Sales + 10;);
ENDFIX

דרך אחרת לבחור רשומות tuple היא על-פי הקשר, במבוסס על אילו איברים נמצאים בנקודת המבט של רשת Smart View בזמן ריצת החישוב. עושים זאת על-ידי הקצאת הפונקציה @GRIDTUPLES כארגומנט ל-FIX, בתסריט החישוב שלך.

FIX ({@GRIDTUPLES(Product, Market)})
   Sales (Sales = Sales + 10;);
ENDFIX

אם מריצים תסריט חישוב זה מ-Smart View כנגד הרשת למטה, אזי מחושבות רק הקומבינציות המוצגות של מוצרים ושווקים. לדוגמה, "Diet Cola"->Massachusetts לא מחושבת כיוון שהיא לא מוצגת באופן מפורשת ברשת. שים לב שכל התרחישים (ממד ה-sparse השלישי בקובייה זו לדוגמה) מחושבים, למרות שרק 'בפועל' מוצג ברשת. זאת משום שממד התרחיש אינו חלק מהמשפט GRIDTUPLES בתסריט החישוב.

בחירת רשומת tuple, אם היא מתבצעת באמצעות רשימות מפורשות של רשומות tuple או על-ידי שימוש בפונקציה @GRIDTUPLES, ישימה רק בהקשר של פקודת החישוב FIX…ENDFIX. התחביר של משפט ה-FIX מתרחב כדי לאפשר בחירת tuple:

FIX ([{ tupleList | @GRIDTUPLES(dimensionList) },] fixMbrs)
COMMANDS ;
ENDFIX

• tupleList - סל מופרד בפסיקים של רשומות tuple.
• dimensionList - לפחות שני ממדי sparse שהאיברים שלהם מהרשת הפעילה של Smart View משמשים להגדרת אזורי החישוב. (בתסריטי חישוב, תוכל להשתמש בממדי sparse בלבד כדי להגדיר רשומות tuple.)
• fixMbrs - איבר או רשימת איברים.

באמצעות רשת של Smart View ומשפט FIX של תסריט חישוב Essbase, תוכל לחשב איברים נבחרים שהן רשומות tuple על בסיס נקודת המבט (POV) של הרשת. לחלופין, תוכל להקליד באופן מפורש את קומבינציות tuple במשפט FIX שלך והסרת התלות ברשת Smart View מסוימת כדי להגדיר את היקף החישוב.

חישוב רשומות tuple נבחרות מסייע לך לעבוד ביעילות עם אזורים לא סימטריים בתסריטי החישוב וגם ברשתות Smart View.

חשוב על הדוגמאות הבאות:

• אין בחירת רשומת Tuple - מחשב בברירת המחדל של האופן, במבוסס על נקודת המבט (POV) של רשת Smart View. החישוב אינו מוגבל לאף רשומת tuple ספציפית.
• בחירה בממדי Sparse מזוהים - מחשב רשומות tuple מתוך שניים או יותר ממדי sparse מזוהים בתסריט חישוב. החישוב מוגבל לאיברים מממדי רשומת ה-tuple שנמצאים ברשת Smart View.
• בחירה בממדי Sparse הקשריים - מחשב רשומות tuple מתוך ממדי sparse שנבחרו בזמן ריצה. החישוב מוגבל לאיברים מממדי רשומת ה-tuple ברשת Smart View.

להתנסות בדוגמאות, הורד את תבנית חוברת העבודה CalcTuple_Tuple.xlsx מהקטע טכני> חישוב של התיקייה גלריה באזור קבצים של ממשק האינטרנט של Essbase. לקבלת הוראות עיין בגיליון העבודה README של חוברת העבודה.

SET RUNTIMESUBVARS
{
ProductGridMembers = POV
<RTSV_HINT><svLaunch>
<description>All Product's members on the grid</description>
<type>member</type>
<dimension>Product</dimension><choice>multiple</choice>
</svLaunch></RTSV_HINT>;
MarketGridMembers = POV
<RTSV_HINT><svLaunch>
<description>All Market's members on the grid</description>
<type>member</type> <dimension>Market</dimension><choice>multiple</choice>
</svLaunch></RTSV_HINT>;
};
FIX (
&ProductGridMembers, &MarketGridMembers
)
Marketing(
   Marketing = Marketing +1;
);
ENDFIX

FIX (
{@GRIDTUPLES(Product, Market)}
)
Marketing(
   Marketing = Marketing + 1;
);
ENDFIX

SET RUNTIMESUBVARS
            {
            DimSelections = "Version", "Site", "Entity", "Product", "Market"
            <RTSV_HINT><svLaunch>
            <description>List two or more sparse dimensions used for forming calculation tuples:</description>
            <type>string</type>
            </svLaunch></RTSV_HINT>;
            };
            FIX (
            {@GRIDTUPLES(&DimSelections)}
            )
            Marketing(
            Marketing = Marketing + 1;
            );
            ENDFIX