Obliczenia z użyciem wybranych krotek

Wybierając krotki, można skoncentrować swoje obliczenia Essbase w aktywnej tabeli Smart View, ograniczając ich zakres do określonych wycinków danych w kostce stanowiącej wolumin blokowy.

Poprzez wybór krotek można zoptymalizować asymetryczne obliczenia w tabeli obejmujące różne wymiary, unikając w ten sposób nadmiernych wyników.

Krotki używane w obliczeniach w Essbase różnią się od krotek używanych w zapytaniach MDX. Wydajność obliczeń i rozmiar kostki zależą głównie od liczby bloków w kostce (zakładając określony rozmiar bloku). Z tego powodu krotki dla obliczeń są określane tylko dla kombinacji elementów rzadkich. Ponadto, w celu ułatwienia tworzenia skryptów obliczeń, w specyfikacji krotki dla obliczeń można zawrzeć wiele elementów z jednego wymiaru rzadkiego. Na przykład, jeśli jako krotka dla obliczeń zostanie użyta krotka ("New York", "California", "Actual", "Cola"), to można obliczyć następujące części wspólne komórek:

"New York"->"Actual"->"Cola"
"California"->"Actual"->"Cola"

Rozważmy pokazaną poniżej tabelę symetryczną. Jest ona symetryczna, ponieważ w tabeli są dla każdego produktu zawarte te same rynki i ten sam scenariusz (Actual).

Poniższa tabela jest asymetryczna, ponieważ produkt Diet Cola ma w tabeli mniej rynków niż produkt Cola.

Domyślnym zakresem obliczeń, gdy w instrukcji FIX lub w punkcie widzenia (POV) tabeli Smart View występuje więcej niż jeden wymiar, jest obliczanie iloczynu wektorowego (wszystkich możliwych kombinacji) elementów z instrukcji FIX lub tabeli. Inaczej mówiąc, obliczenie sterowane punktem widzenia, w którym kombinacje produktów i rynków pochodzą z tabeli, oblicza wszystkie następujące kombinacje "wiersz-element":

Cola->"New York"
Cola->"Massachusetts"
Cola->"Florida"
Cola->"Connecticut"
Cola->"New Hampshire"
"Diet Cola"->"New York"
"Diet Cola"->"Massachusetts"
"Diet Cola"->"Florida"
"Diet Cola"->"Connecticut"
"Diet Cola"->"New Hampshire"

To może być działanie przekraczające oczekiwane. Chcąc obliczyć tylko kombinacje pokazane w tabeli, można określić, które krotki mają być używane w obliczeniu, oraz ograniczyć obliczenie do mniejszego wycinka. Obliczenia z użyciem krotek mogą się także przyczynić do skrócenia czasu obliczania oraz zmniejszenia rozmiaru kostki.

Cola->"New York"
Cola->"Massachusetts"
Cola->"Florida"
Cola->"Connecticut"
Cola->"New Hampshire"
"Diet Cola"->"New York"
"Diet Cola"->"Florida"

Krotka obliczeniowa to sposób reprezentowania wycinka danych z elementów z dwóch lub większej liczby wymiarów rzadkich, który ma być używany w obliczeniach Essbase w woluminie blokowym.

Przykłady poprawnych krotek obliczeniowych

• ("Diet Cola", "New York")
• ("Diet Cola", "Cola", Florida)
• (Cola, "New Hampshire")

Pisząc wyrażenia MDX, należy pamiętać o następujących ograniczeniach dla krotek:

• W krotce MDX może zostać zawarty tylko jeden element z każdego z wymiarów
• Wszystkie krotki w zbiorze MDX muszą reprezentować te same wymiary, w tej samej kolejności

Jeśli jednak krotki są wybierane w skryptach obliczeń, wymagania te ulegają złagodzeniu. Można swobodnie pisać wyrażenia oparte na krotkach, przy czym krotki mogą opisywać listy elementów, jak ma to miejsce w następującej krotce: (@Children(East), Cola).

Łatwym sposobem wyboru krotek jest wstawienie ich jawnie w skrypcie obliczeń, w postaci listy w obrębie instrukcji FIX.

Format instrukcji FIX ma następującą postać:

FIX (fixMbrs)
COMMANDS ;
ENDFIX

W poniższej instrukcji FIX są podane, przed blokiem poleceń, dwie krotki. Krotki są ujęte w nawiasy klamrowe { } ograniczające zbiór, będący kolekcją krotek.

FIX({
  (@Children(East), Cola),
  ("New York", Florida, "Diet Cola")
  })
Sales (Sales = Sales + 10;);
ENDFIX

Innym sposobem wyboru krotek jest wybór kontekstowy, oparty na elementach występujących w punkcie widzenia (POV) tabeli Smart View w chwili tworzenia obliczenia. Wyboru tego dokonuje się, używając — w skrypcie obliczeń — funkcji @GRIDTUPLES jako argumentu instrukcji FIX.

FIX ({@GRIDTUPLES(Product, Market)})
   Sales (Sales = Sales + 10;);
ENDFIX

Jeśli ten skrypt obliczeń zostanie uruchomiony z aplikacji Smart View w odniesieniu do podanej poniżej tabeli, to będą obliczane tylko wyświetlane kombinacje produktów i rynków. Na przykład kombinacja "Diet Cola"->Massachusetts nie zostanie obliczona, ponieważ nie jest pokazywana w tabeli. Należy pamiętać, że obliczane są wszystkie scenariusze (trzeci wymiar rzadki w tej przykładowej kostce), mimo że w tabeli jest pokazywany tylko scenariusz "Actual". Wynika to z tego, że wymiar "Scenariusz" (Scenario) nie jest częścią instrukcji GRIDTUPLES w skrypcie obliczeń.

Wybór krotek — bez względu na to, czy jest dokonywany za pomocą jawnej listy krotek czy przy użyciu funkcji @GRIDTUPLES — ma zastosowanie tylko w kontekście obliczeniowego polecenia FIX…ENDFIX. Składnia instrukcji FIX została rozszerzona, tak aby był możliwy wybór krotek:

FIX ([{ tupleList | @GRIDTUPLES(dimensionList) },] fixMbrs)
COMMANDS ;
ENDFIX

• tupleList — lista krotek rozdzielonych przecinkiem.
• dimensionList — przynajmniej dwa wymiary rzadkie, których elementy z aktywnej tabeli Smart View są używane do definiowania obszarów obliczeń. (W skryptach obliczeń można do definiowania krotek używać tylko wymiarów rzadkich.)
• fixMbrs — element lub lista elementów.

Używając tabeli Smart View i instrukcji FIX w skrypcie obliczeń Essbase, można obliczać wybrane krotki elementów zgodnie z punktem widzenia (POV) tabeli. Alternatywnie można — w celu zdefiniowania zakresu obliczeń — wpisać kombinacje krotek bezpośrednio w instrukcji FIX, usuwając w ten sposób zależność od tabeli Smart View.

Obliczając wybrane krotki, można skutecznie pracować z asymetrycznymi obszarami zarówno w skryptach obliczeń, jak i w tabelach Smart View.

Rozważmy następujące przykłady:

• Bez wyboru krotek — Obliczenia są wykonywane w sposób domyślny, na podstawie bieżącego punktu widzenia (POV) tabeli Smart View. Obliczenia nie są ograniczone do żadnych określonych krotek.
• Wybór nazwanych wymiarów rzadkich — Są obliczane krotki z dwóch lub większej liczby wymiarów rzadkich, nazwanych w skrypcie obliczeń. Obliczenia są ograniczane do elementów z wymiarów krotek, występujących w tabeli Smart View.
• Wybór kontekstowych wymiarów rzadkich — Są obliczane krotki z wymiarów rzadkich, wybranych w trybie wykonawczym. Obliczenia są ograniczane do elementów z wymiarów krotek, występujących w tabeli Smart View.

Aby wypróbować te przykłady, należy pobrać szablon skoroszytu CalcTuple_Tuple.xlsx z sekcji Techniczne > Obliczenia folderu galerii, który znajduje się w obszarze Pliki w internetowym interfejsie Essbase. Odpowiednie instrukcje są zawarte w arkuszu README skoroszytu.

SET RUNTIMESUBVARS
{
ProductGridMembers = POV
<RTSV_HINT><svLaunch>
<description>All Product's members on the grid</description>
<type>member</type>
<dimension>Product</dimension><choice>multiple</choice>
</svLaunch></RTSV_HINT>;
MarketGridMembers = POV
<RTSV_HINT><svLaunch>
<description>All Market's members on the grid</description>
<type>member</type> <dimension>Market</dimension><choice>multiple</choice>
</svLaunch></RTSV_HINT>;
};
FIX (
&ProductGridMembers, &MarketGridMembers
)
Marketing(
   Marketing = Marketing +1;
);
ENDFIX

FIX (
{@GRIDTUPLES(Product, Market)}
)
Marketing(
   Marketing = Marketing + 1;
);
ENDFIX

SET RUNTIMESUBVARS
            {
            DimSelections = "Version", "Site", "Entity", "Product", "Market"
            <RTSV_HINT><svLaunch>
            <description>List two or more sparse dimensions used for forming calculation tuples:</description>
            <type>string</type>
            </svLaunch></RTSV_HINT>;
            };
            FIX (
            {@GRIDTUPLES(&DimSelections)}
            )
            Marketing(
            Marketing = Marketing + 1;
            );
            ENDFIX