Seçili Demetleri Hesaplama

Tanımlama gruplarını seçerek, Essbase hesaplamalarınızı etkin Smart View elektronik tablosuna odaklayabilir ve kapsamlarını blok depolamalı küpünüzdeki belirli veri dilimleriyle sınırlayabilirsiniz.

Demet seçimi boyutlardaki asimetrik kılavuz hesaplamalarını optimize ederek fazla hesaplamadan kaçınmanıza yardımcı olabilir.

Essbase hesaplama demetleri MDX sorgularında kullanılan demetlerden farklıdır. Hesaplama performansı ve küp boyutu çoğunlukla küpteki blok sayısı tarafından belirlenir (belirli bir blok boyutu varsa). Bu nedenle hesaplama demetleri sadece ayrıl üye birleşimleri için belirtilir. Ayrıca, hesaplama komut listesi oluşturma işlemini kolaylaştırmak için bir hesaplama demeti belirtimine tek bir ayrık boyuttan birden fazla üye eklenebilir. Örneğin, hesaplama demeti olarak ("New York", "Kaliforniya", "Fiili", "Kola") belirtirseniz aşağıdaki hücre kesişimlerini hesaplarsınız:

"New York"->"Actual"->"Cola"
"California"->"Actual"->"Cola"

Aşağıdaki simetrik kılavuzu ele alın. Her ürün için kılavuzda aynı pazarlar ve senaryo (Fiili) gösterildiğinden simetriktir.

Diyet Kola ürününün kılavuzunda Kola ürünündekinden daha az sayıda pazar olduğundan aşağıdaki kılavuz asimetriktir.

Birden fazla boyut bir FIX deyiminde veya bir Smart View kılavuzu bakış açısında olduğunda, hesaplama kapsamı öndeğeri FIX veya kılavuzdaki üyelerin çapraz ürününü (tüm olası birleşimler) hesaplamaktır. Diğer bir deyişle, ürün ve market birleşimlerinin kılavuzdan alındığı bakış açısı odaklı bir hesaplama şu satır-üye birleşimlerinin hepsini hesaplar:

Cola->"New York"
Cola->"Massachusetts"
Cola->"Florida"
Cola->"Connecticut"
Cola->"New Hampshire"
"Diet Cola"->"New York"
"Diet Cola"->"Massachusetts"
"Diet Cola"->"Florida"
"Diet Cola"->"Connecticut"
"Diet Cola"->"New Hampshire"

Bu hesaplama etkinliği ihtiyacınız duyduğunuzdan daha fazla olabilir. Sadece kılavuzda gösterilen birleşimleri hesaplamak isterseniz hesaplanacak demetleri belirtebilir ve hesaplamayı daha küçük bir dilimle sınırlayabilirsiniz. Demetlerin hesaplanması hesaplama süresini ve küp boyutunu da azaltabilir.

Cola->"New York"
Cola->"Massachusetts"
Cola->"Florida"
Cola->"Connecticut"
Cola->"New Hampshire"
"Diet Cola"->"New York"
"Diet Cola"->"Florida"

Hesaplama tanımlama grubu, iki veya daha fazla ayrık boyutta yer alan ve Essbase blok depolama hesaplamasında kullanılacak bir üye verisi dilimini göstermenin bir yoludur.

Geçerli hesaplama demetlerine örnekler:

• ("Diet Cola", "New York")
• ("Diet Cola", "Cola", Florida)
• (Cola, "New Hampshire")

MDX ifadeleri yazıyorsanız, MDX için geçerli olan şu demet kısıtlamalarına dikkat etmeniz gerekir:

• Bir MDX demetine her boyuttan sadece tek bir üye eklenebilir
• Bir MDX kümesindeki tüm demetlerde aynı boyutlar aynı sırada gösterilmelidir

Ancak, hesaplama komut listelerinde demetleri seçtiğinizde bu gereksinimler kolaylık sağlamak için esnetilir. Demet ifadelerini serbestçe yazabilirsiniz ve demetler şu demetin yaptığı gibi üye listelerini açıklayabilir: (@Children(East), Cola).

Demetleri seçmenin kolay bir yolu onları bir hesaplama listesine FIX deyiminin içerisinde bir liste olarak açıkça eklemektir.

FIX deyiminin formatını hatırlayın:

FIX (fixMbrs)
COMMANDS ;
ENDFIX

Aşağıdaki FIX deyiminde iki demet, komut bloğu başlamadan önce belirtilmiştir. Demetler, bir kümeyi (demet koleksiyonu) sınırlamak için küme parantezi { } içine alınır.

FIX({
  (@Children(East), Cola),
  ("New York", Florida, "Diet Cola")
  })
Sales (Sales = Sales + 10;);
ENDFIX

Demetler, hesaplama çalıştırma zamanında bir Smart View kılavuzu bakış açısında mevcut olan üyelere bağlı olarak bağlamsal olarak da seçilebilir. Bunu yapmak için hesaplama komut listenizde FIX deyimine @GRIDTUPLES fonksiyonunu bir bağımsız değişken olarak sağlarsınız.

FIX ({@GRIDTUPLES(Product, Market)})
   Sales (Sales = Sales + 10;);
ENDFIX

Hesaplama komut listesini aşağıdaki kılavuza göre Smart View'den yürütürseniz sadece ürün ve pazar birleşimleri hesaplanır. Örneğin, "Diyet Kola"->Massachusetts kılavuzda açıkça gösterilmediğinden hesaplanmaz. Kılavuzda Fiili gösterilmesine rağmen tüm senaryoların (bu örnek küpteki üçüncü ayrık boyut) hesaplandığına dikkat edin. Bunun nedeni, Senaryo boyutunun hesaplama komut listesindeki GRIDTUPLES deyiminin parçası olmamasıdır.

Açık demet listeleri veya @GRIDTUPLES fonksiyonu kullanılarak yapılan demet seçimi sadece FIX…ENDFIX hesaplama komutunun bağlamında geçerlidir. Demet seçimine olanak tanımak için FIX deyiminin sözdizimi genişletilir:

FIX ([{ tupleList | @GRIDTUPLES(dimensionList) },] fixMbrs)
COMMANDS ;
ENDFIX

• tupleList - virgülle ayrılmış demet kümesi.
• dimensionList - hesaplama bölgelerini tanımlamak için etkin Smart View kılavuzundaki üyeleri kullanılan en az iki ayrık boyut. (Hesaplama komut listelerinde, demetleri tanımlamak için sadece ayrık boyutları kullanabilirsiniz.)
• fixMbrs - bir üye veya üye listesi.

Smart View elektronik tablosu ve bir Essbase hesaplama komut dosyası FIX komutu kullanarak, seçili üye tanımlama gruplarını görünümün kılavuz noktasına göre hesaplayabilirsiniz. Alternatif olarak, hesaplama kapsamını tanımlamak için belirli bir Smart View kılavuzuna olan bağımlılığı kaldırarak FIX deyiminizde demet birleşimlerini açıkça yazabilirsiniz.

Seçili demetleri hesaplamak, hesaplama komut listelerinde ve Smart View kılavuzlarında asimetrik bölgelerle etkili şekilde çalışmanıza yardımcı olur.

Aşağıdaki örnekleri ele alın:

• Demet Seçimi Yok - Geçerli Smart View kılavuzu bakış açısına göre yöntem öndeğerinde hesaplar. Hesaplama belirli demetlerle sınırlı değildir.
• Adlandırılmış Ayrık Boyutları Seçme - Bir hesaplama komut listesinde adlandırılmış iki veya daha fazla ayrık boyuttaki demetleri hesaplar. Hesaplama, Smart View kılavuzunda mevcut olan demet boyutlarındaki üyelerle sınırlıdır.
• Bağlamsal Ayrık Boyutları Seçme - Çalıştırma zamanında seçilen ayrık boyutlardaki demetleri hesaplar. Hesaplama, Smart View kılavuzunda mevcut olan demet boyutlarındaki üyelerle sınırlıdır.

Örnekleri denemek için Essbase web arayüzünün Dosyalar alanındaki galeri klasörünün Teknik > Hesaplama bölümünden CalcTuple_Tuple.xlsx çalışma kitabı şablonunu indirin. Yönergeler için çalışma kitabındaki BENİOKU çalışma sayfasına bakın.

SET RUNTIMESUBVARS
{
ProductGridMembers = POV
<RTSV_HINT><svLaunch>
<description>All Product's members on the grid</description>
<type>member</type>
<dimension>Product</dimension><choice>multiple</choice>
</svLaunch></RTSV_HINT>;
MarketGridMembers = POV
<RTSV_HINT><svLaunch>
<description>All Market's members on the grid</description>
<type>member</type> <dimension>Market</dimension><choice>multiple</choice>
</svLaunch></RTSV_HINT>;
};
FIX (
&ProductGridMembers, &MarketGridMembers
)
Marketing(
   Marketing = Marketing +1;
);
ENDFIX

FIX (
{@GRIDTUPLES(Product, Market)}
)
Marketing(
   Marketing = Marketing + 1;
);
ENDFIX

SET RUNTIMESUBVARS
            {
            DimSelections = "Version", "Site", "Entity", "Product", "Market"
            <RTSV_HINT><svLaunch>
            <description>List two or more sparse dimensions used for forming calculation tuples:</description>
            <type>string</type>
            </svLaunch></RTSV_HINT>;
            };
            FIX (
            {@GRIDTUPLES(&DimSelections)}
            )
            Marketing(
            Marketing = Marketing + 1;
            );
            ENDFIX