DBMS_EXT_TABLE_CACHE-Package

Das Package DBMS_EXT_TABLE_CACHE stellt Routinen bereit, mit denen das Caching von Daten, auf die häufig zugegriffen wird, aus externen Tabellen und aus Tabellen konfiguriert und verwaltet wird, die über gemountete Kataloge in Autonomous AI Database bereitgestellt werden.

Zusammenfassung der DBMS_EXT_TABLE_CACHE-Unterprogramme

In dieser Tabelle werden die Unterprogramme zusammengefasst, die im Package DBMS_EXT_TABLE_CACHE enthalten sind.

Unterprogramm Beschreibung
Prozedur ADD_BY_LIKE Fügt eine oder mehrere Dateien, die den angegebenen Filtern entsprechen, in den Lake Cache ein.
Prozedur ADD_FILE Fügt eine Datei zum Lake Cache hinzu.
Prozedur ADD_LATEST_FILES Füllt eine oder mehrere Dateien basierend auf dem vom Argument SINCE angegebenen Zeitintervall und dem aktuellen Zeitstempel auf.
Prozedur ADD_TABLE Fügt Dateien aus der angegebenen Quelltabelle in den Lake Cache ein. Die Quelltabelle kann entweder eine externe Tabelle oder eine Tabelle sein, die über einen gemounteten Katalog bereitgestellt wird.
CLEAR-Verfahren Löscht einen Lake Cache.
CREATE_CACHE - Prozedur Erstellt einen Lake Cache.
Prozedur deaktivieren Deaktiviert einen Lake-Cache.
DROP_BY_LIKE - Prozedur Dateien basierend auf den angegebenen Filtern aus dem Lake Cache löschen.
DROP_CACHE Löscht einen Lake Cache.
DROP_FILE-Prozedur Entfernt die angegebene Quelldatei aus dem Lake Cache.
Prozedur aktivieren Aktiviert einen zuvor deaktivierten Lake Cache.
Funktion GET_AVAILABLE_QUOTA Gibt die verbleibende verfügbare Cache-Quota für ein Schema oder einen bestimmten externen Tabellencache zurück.
Funktion GET_GLOBAL_CACHE_QUOTA Gibt die aufgelöste globale Cache-Quota zurück.
GET_USER_PROPERTY (Funktion) Ruft die Caching-Voreinstellung für einen Lake Cache ab.
Prozedur REFRESH_TABLE Löscht gecachte Daten für nicht mehr vorhandene Dateien und lädt die neu oder neu geänderten Dateien.
Prozedur RETIRE_FILES Löscht eine oder mehrere Dateien aus dem Cache, die älter als das angegebene Intervall sind.
SET_USER_PROPERTY-Prozedur Gibt die Caching-Voreinstellung für den Lake Cache an.
Prozedur VALIDATE Validiert einen Lake Cache.

Prozedur ADD_BY_LIKE

Die Prozedur DBMS_EXT_TABLE_CACHE.ADD_BY_LIKE lädt mindestens eine angegebene Quelldatei in den Lake-Cache.

Syntax

DBMS_EXT_TABLE_CACHE.ADD_BY_LIKE (
      owner        IN VARCHAR2,
      table_name   IN VARCHAR2,
      path_filters IN CLOB,
      esc_char     IN VARCHAR2 DEFAULT NULL,
      force        IN BOOLEAN  DEFAULT FALSE);

Parameter

Parameter Beschreibung
owner Legt den Schemanamen fest.
table_name Gibt den Namen der Quelltabelle an. Die Quelltabelle kann entweder eine externe Tabelle oder eine Tabelle sein, die über einen gemounteten Katalog bereitgestellt wird.
path_filters PATH_FILTERS ist ein JSON_ARRAY von Pfadfiltern, mit denen nach angegebenen Mustern in Datei-URLs gesucht wird.
esc_char

Gibt das Escapezeichen an, das in den Pfadfiltern verwendet werden soll. Wenn das Escape-Zeichen im Muster vor "%" oder "_" steht, wird das Sonderzeichen wörtlich interpretiert und nicht als besonderes Musterabgleichszeichen.

Dieser Parameter ist optional, und der Standardwert für diesen Parameter ist NULL.

force

Erzwingt, dass die angegebenen vorhandenen Dateien im Cache überschrieben werden, auch wenn die Dateien nicht geändert wurden.

Dieser Parameter ist optional, und der Standardwert für den Parameter force lautet FALSE.

Beispiel

BEGIN
  DBMS_EXT_TABLE_CACHE.ADD_BY_LIKE (
    owner        => 'SALES',
    table_name   =>'STORE_SALES',
    path_filters => '["https://swiftobjectstorage.us-ashburn-1.oraclecloud.com/v1/your_namespace/your_bucket/salesdata1.parquet",
                      "https://swiftobjectstorage.us-ashburn-1.oraclecloud.com/v1/your_namespace/your_bucket/salesdata2.parquet"]'
);
END;
/

Diese Prozedur unterstützt auch Tabellen, die über gemountete Kataloge bereitgestellt werden.

Hinweis zur Verwendung

  • Standardmäßig überspringt die Prozedur DBMS_EXT_TABLE_CACHE.ADD_BY_LIKE das Laden der Dateien, wenn:

    • Die Dateien wurden zuvor gecacht und sind noch im Cache verfügbar.

    • Die Dateien wurden seit dem letzten Zwischenspeicher nicht mehr geändert.

    Sie können jedoch den Parameter force verwenden, um die Dateien im Cache zu überschreiben, auch wenn die Dateien nicht geändert wurden.

Prozedur ADD_FILE

Die Prozedur DBMS_EXT_TABLE_CACHE.ADD_FILE lädt die angegebene Datei in den Lake-Cache.

Syntax

DBMS_EXT_TABLE_CACHE.ADD_FILE (
      owner        IN VARCHAR2,
      table_name   IN VARCHAR2,
      file_url     IN VARCHAR2,
      force        IN BOOLEAN DEFAULT FALSE);

Parameter

Parameter Beschreibung
owner Legt den Schemanamen fest.
table_name Gibt den Namen der Quelltabelle an. Die Quelltabelle kann entweder eine externe Tabelle oder eine Tabelle sein, die über einen gemounteten Katalog bereitgestellt wird.
file_url Gibt die Datei-URL an.
force

Erzwingt, dass die angegebenen vorhandenen Dateien im Cache überschrieben werden, auch wenn die Dateien nicht geändert wurden.

Dieser Parameter ist optional, und der Standardwert für den Parameter force lautet FALSE.

Beispiel

BEGIN
  DBMS_EXT_TABLE_CACHE.ADD_FILE (
    owner        => 'SALES',
    table_name   => 'STORE_SALES',
    file_url     => 'https://swiftobjectstorage.us-ashburn-1.oraclecloud.com/v1/your_namespace/your_bucket/salesdata.parquet'
);
END;
/

Diese Prozedur unterstützt auch Tabellen, die über gemountete Kataloge bereitgestellt werden.

Hinweise zur Verwendung

  • Die Prozedur DBMS_EXT_TABLE_CACHE.ADD_FILE überspringt das Laden der Datei in den Cache, wenn die angegebene Datei im Cache vorhanden ist und seit dem letzten Zwischenspeichern der Datei nicht mehr geändert wurde.

  • Mit dem Parameter force können Sie die Datei im Cache überschreiben, selbst wenn die Datei nicht geändert wurde.

Prozedur ADD_LATEST_FILES

Die DBMS_EXT_TABLE_CACHE.ADD_LATEST_FILES füllt mindestens eine Datei in den Lake-Cache auf. Die Dateien werden basierend auf dem vom Argument SINCE festgelegten Zeitintervall und dem aktuellen Zeitstempel aufgefüllt.

Syntax

DBMS_EXT_TABLE_CACHE.ADD_LATEST_FILES (
      owner        IN  VARCHAR2,
      table_name   IN  VARCHAR2,
      since        IN  INTERVAL DAY TO SECOND,
      max_files    IN  NUMBER,
      force        IN  BOOLEAN DEFAULT FALSE);

Parameter

Parameter Beschreibung
owner Legt den Schemanamen fest.
table_name Gibt den Namen der Quelltabelle an. Die Quelltabelle kann entweder eine externe Tabelle oder eine Tabelle sein, die über einen gemounteten Katalog bereitgestellt wird.
since Der Parameter since akzeptiert einen INTERVAL DAY TO SECOND-Wert und wird zur Berechnung des Zeitintervalls zwischen dem Wert since und dem aktuellen Zeitstempel verwendet. Das resultierende Zeitintervall wird dann verwendet, um die Dateien basierend auf ihrer letzten Änderungszeit aufzufüllen.
max_files Gibt die maximale Anzahl von Dateien an, die in den Lake Cache geladen werden sollen.
force

Erzwingt, dass die angegebenen vorhandenen Dateien im Cache überschrieben werden, auch wenn die Dateien nicht geändert wurden.

Dieser Parameter ist optional, und der Standardwert für diesen Parameter ist FALSE.

Beispiel

BEGIN
  DBMS_EXT_TABLE_CACHE.ADD_LATEST_FILES (
    owner        => 'SALES',
    table_name   => 'STORE_SALES',
    since        => INTERVAL '7' DAY,
    max_files    => 5,
    force        => TRUE);
END;
/

Diese Prozedur unterstützt auch Tabellen, die über gemountete Kataloge bereitgestellt werden.

Hinweis zur Verwendung

  • Standardmäßig überspringt die Prozedur DBMS_EXT_TABLE_CACHE.ADD_LATEST_FILES das Auffüllen der Dateien, wenn:

    • Die angegebenen Dateien wurden zuvor gecacht und sind noch im Cache verfügbar.

    • Die angegebenen Dateien wurden seit dem letzten Zwischenspeichern nicht mehr geändert.

    Sie können jedoch den Parameter force verwenden, um die Dateien im Cache zu überschreiben, auch wenn die Dateien nicht geändert wurden.

Prozedur ADD_TABLE

Die Prozedur DBMS_EXT_TABLE_CACHE.ADD_TABLE lädt eine gesamte Tabelle oder einen bestimmten Prozentsatz der Quelltabelle in den Cache. Die Quelltabelle kann entweder eine externe Tabelle oder eine Tabelle sein, die über einen gemounteten Katalog bereitgestellt wird.

Syntax

DBMS_EXT_TABLE_CACHE.ADD_TABLE (
      owner         IN VARCHAR2,
      table_name    IN VARCHAR2,
      percent_files IN NUMBER DEFAULT NULL,
      force         IN BOOLEAN DEFAULT FALSE);

Parameter

Parameter Beschreibung
owner Legt den Schemanamen fest.
table_name Gibt den Namen der Quelltabelle an. Die Quelltabelle kann entweder eine externe Tabelle oder eine Tabelle sein, die über einen gemounteten Katalog bereitgestellt wird.
percent_files

Gibt den Prozentsatz der Tabellendaten an, die gecacht werden sollen. Beispiel: 1 auf 100.

Standardmäßig werden alle Dateien geladen.

force

Erzwingt, dass die angegebenen Dateien im Cache überschrieben werden, auch wenn die Dateien nicht geändert wurden.

Dieser Parameter ist optional, und der Standardwert für force ist FALSE.

Beispiel

BEGIN
  DBMS_EXT_TABLE_CACHE.ADD_TABLE (
    owner         => 'SALES',
    table_name    => 'STORE_SALES',
    percent_files => 50);
END;
/

Diese Prozedur unterstützt auch Tabellen, die über gemountete Kataloge bereitgestellt werden.

Hinweise zur Verwendung

  • Die DBMS_EXT_TABLE_CACHE.ADD_TABLE versucht, die gesamte Tabelle oder einen bestimmten Prozentsatz des Dateiinhalts im Cache zu cachen.

  • Die Parameter percent_files und force schließen sich gegenseitig aus.

  • Standardmäßig überspringt die Prozedur DBMS_EXT_TABLE_CACHE.ADD_TABLE das Laden der Dateien, wenn:

    • Die angegebenen Dateien wurden zuvor gecacht und sind noch im Cache verfügbar.

    • Die angegebenen Dateien wurden seit dem letzten Zwischenspeichern nicht mehr geändert.

    Sie können jedoch den Parameter force verwenden, um die Dateien im Cache zu überschreiben, auch wenn die Dateien nicht geändert wurden.

CLEAR-Verfahren

Die Prozedur DBMS_EXT_TABLE_CACHE.CLEAR entfernt alle Dateien aus einem Lake-Cache, während der Cache beibehalten wird.

Syntax

DBMS_EXT_TABLE_CACHE.CLEAR (
      owner         IN VARCHAR2,
      table_name    IN VARCHAR2);

Parameter

Parameter Beschreibung
owner Legt den Schemanamen fest.
table_name Gibt den Namen der Quelltabelle an. Die Quelltabelle kann entweder eine externe Tabelle oder eine Tabelle sein, die über einen gemounteten Katalog bereitgestellt wird.

Beispiel

BEGIN
  DBMS_EXT_TABLE_CACHE.CLEAR (
    owner         => 'SALES',
    table_name    => 'STORE_SALES');
END;
/

Diese Prozedur unterstützt auch Tabellen, die über gemountete Kataloge bereitgestellt werden.

Prozedur CREATE_CACHE

Die Prozedur DBMS_EXT_TABLE_CACHE.CREATE_CACHE erstellt einen Lake Cache in einer autonomen AI-Datenbankinstanz.

Syntax

DBMS_EXT_TABLE_CACHE.CREATE_CACHE (
      owner          IN VARCHAR2,
      table_name     IN VARCHAR2,
      partition_type IN VARCHAR2 DEFAULT NULL,
      col_subset     IN VARCHAR2 DEFAULT NULL);

Parameter

Parameter Beschreibung
owner Legt den Schemanamen fest.
table_name Gibt den Namen der Quelltabelle an. Die Quelltabelle kann entweder eine externe Tabelle oder eine Tabelle sein, die über einen gemounteten Katalog bereitgestellt wird.
partition_type Gibt die Cache-Partitionierungsoption an. Unterstützte Werte sind FILE, das den Lake-Cache mit den unsichtbaren Spalten FILE$PATH und FILE$NAME partitioniert, PATH, das den Lake-Cache mit der unsichtbaren Spalte FILE$PATH partitioniert und FILE_GROUPING, das schnellen Zugriff auf Cachedaten ermöglicht, die mit Dateien im Objektspeicher ausgerichtet sind.

Dieser Parameter ist optional. Wenn keine Angabe gemacht wird, ist FILE_GROUPING der Standard für Caches, die in Tablespaces erstellt werden, die Automatic Segment Space Management (ASSM) verwenden. Geben Sie FILE oder PATH explizit an, um eine dieser Optionen auszuwählen.

FILE$PATH gibt den Dateipfad bis zum Anfang des Objektnamens an. FILE$NAME gibt den Objektnamen an, einschließlich des gesamten Textes nach dem letzten /. Weitere Informationen finden Sie unter Metadatenspalten für externe Tabellen.
col_subset col_subset gibt die zu cachenden Spalten an. Geben Sie einen JSON_ARRAY mit Spaltennamen für externe Tabellen an. Nur diese Spalten werden im Lake Cache gecacht.

col_subset ist optional. Wenn Sie col_subset nicht angeben, enthält der Lake Cache standardmäßig alle Spalten.

Beispiele

Beispiel: Lake Cache mit der Standardpartitionierungsoption erstellen

In diesem Beispiel wird partition_type ausgelassen und alle Quelltabellenspalten enthalten. Bei einem Cache, der in einem ASSM-Tablespace erstellt wird, verwendet die Prozedur FILE_GROUPING.

BEGIN
  DBMS_EXT_TABLE_CACHE.CREATE_CACHE (
    owner      => 'SALES',
    table_name => 'STORE_SALES');
END;
/

Diese Prozedur unterstützt auch Tabellen, die über gemountete Kataloge bereitgestellt werden.

Beispiel: Lake Cache mit einer Teilmenge von Spalten mit der Standardpartitionierungsoption erstellen

In diesem Beispiel werden nur die angegebenen Spalten gecacht, und partition_type wird ausgelassen. Bei einem Cache, der in einem ASSM-Tablespace erstellt wird, verwendet die Prozedur FILE_GROUPING.

BEGIN
  DBMS_EXT_TABLE_CACHE.CREATE_CACHE (
    owner      => 'SALES',
    table_name => 'STORE_SALES',
    col_subset => '["PROD_ID","STORE_ID","SALES_AMT"]');
END;
/

Diese Prozedur unterstützt auch Tabellen, die über gemountete Kataloge bereitgestellt werden.

Beispiel: Erstellen Sie einen Lake Cache explizit mit der FILE-Partitionierung

Um FILE explizit auszuwählen, geben Sie partition_type an:

BEGIN
  DBMS_EXT_TABLE_CACHE.CREATE_CACHE (
    owner          => 'SALES',
    table_name     => 'STORE_SALES',
    partition_type => 'FILE');
END;
/

Diese Prozedur unterstützt auch Tabellen, die über gemountete Kataloge bereitgestellt werden.

Hinweise zur Verwendung

  • DBMS_EXT_TABLE_CACHE.CREATE_CACHE erstellt den Lake-Cache in einer autonomen KI-Datenbankinstanz. Das Erstellen eines Caches ähnelt dem Erstellen einer Tabelle im Datenbankschema.

  • Die Beispiele zeigen alternative Möglichkeiten, einen Cache zu erstellen. Führen Sie sie nicht sequenziell für dieselbe Quelltabelle aus.

Prozedur deaktivieren

Die Prozedur DBMS_EXT_TABLE_CACHE.DISABLE deaktiviert den angegebenen Lake Cache. Der Cache wird als deaktiviert gekennzeichnet. Die Daten im Cache werden jedoch beibehalten.

Syntax

DBMS_EXT_TABLE_CACHE.DISABLE (
      owner        IN VARCHAR2,
      table_name   IN VARCHAR2
);

Parameter

Parameter Beschreibung
owner Legt den Schemanamen fest.
table_name Gibt den Namen der Quelltabelle an. Die Quelltabelle kann entweder eine externe Tabelle oder eine Tabelle sein, die über einen gemounteten Katalog bereitgestellt wird.

Beispiel

BEGIN
    DBMS_EXT_TABLE_CACHE.DISABLE (
      owner          => 'SALES',
      table_name     => 'STORE_SALES');
END;
/

Diese Prozedur unterstützt auch Tabellen, die über gemountete Kataloge bereitgestellt werden.

Hinweis zur Verwendung

  • DBMS_EXT_TABLE_CACHE.DISABLE löscht keine Daten aus dem Lake-Cache. Stattdessen wird der Cache als DISABLED markiert, was bedeutet, dass der Optimizer den Cache nicht für Query Rewrites verwenden kann.

Prozedur DROP_BY_LIKE

Die Prozedur DBMS_EXT_TABLE_CACHE.DROP_BY_LIKE löscht eine oder mehrere Dateien aus dem Lake-Cache. Die Dateien werden basierend auf den angegebenen Filtern gelöscht.

Syntax

DBMS_EXT_TABLE_CACHE.DROP_BY_LIKE (
      owner        IN VARCHAR2,
      table_name   IN VARCHAR2,
      path_filters IN CLOB,
      esc_char     IN VARCHAR2 DEFAULT NULL);

Parameter

Parameter Beschreibung
owner Legt den Schemanamen fest.
table_name Gibt den Namen der Quelltabelle an. Die Quelltabelle kann entweder eine externe Tabelle oder eine Tabelle sein, die über einen gemounteten Katalog bereitgestellt wird.
path_filters PATH_FILTERS ist ein JSON_ARRAY von Pfadfiltern, mit denen nach angegebenen Mustern in Datei-URLs gesucht wird.
esc_char

Gibt das Escapezeichen an, das in den Pfadfiltern verwendet werden soll. Wenn das Escape-Zeichen im Muster vor "%" oder "_" steht, wird das Sonderzeichen wörtlich interpretiert und nicht als besonderes Musterabgleichszeichen.

Dieser Parameter ist optional, und der Standardwert für diesen Parameter ist NULL.

Beispiel

BEGIN
  DBMS_EXT_TABLE_CACHE.DROP_BY_LIKE (
    owner        => 'SALES',
    table_name   => 'STORE_SALES',
    path_filters => '["https://swiftobjectstorage.us-ashburn-1.oraclecloud.com/v1/your_namespace/your_bucket/salesdata1.parquet",
                      "https://swiftobjectstorage.us-ashburn-1.oraclecloud.com/v1/your_namespace/your_bucket/salesdata2.parquet"]'
);
END;
/

Diese Prozedur unterstützt auch Tabellen, die über gemountete Kataloge bereitgestellt werden.

Prozedur DROP_CACHE

Die Prozedur DBMS_EXT_TABLE_CACHE.DROP_CACHE löscht den angegebenen Lake-Cache. Diese Prozedur löscht den Cache und gibt den mit dem Cache verknüpften Speicherplatz frei.

Syntax

DBMS_EXT_TABLE_CACHE.DROP_CACHE (
      owner            IN    VARCHAR2,
      table_name       IN    VARCHAR2
);

Parameter

Parameter Beschreibung
owner Legt den Schemanamen fest.
table_name Gibt den Namen der Quelltabelle an. Die Quelltabelle kann entweder eine externe Tabelle oder eine Tabelle sein, die über einen gemounteten Katalog bereitgestellt wird.

Beispiel

BEGIN
    DBMS_EXT_TABLE_CACHE.DROP_CACHE (
      owner          => 'SALES',
      table_name     => 'STORE_SALES');
END;
/

Diese Prozedur unterstützt auch Tabellen, die über gemountete Kataloge bereitgestellt werden.

Hinweis zur Verwendung

  • Wenn Sie einen Cache löschen, werden seine Metadaten aus dem Data Dictionary entfernt, und alle gecachten Daten werden gelöscht.

Prozedur DROP_FILE

Die Prozedur DBMS_EXT_TABLE_CACHE.DROP_FILE löscht die angegebene Datei aus einem Lake-Cache.

Syntax

DBMS_EXT_TABLE_CACHE.DROP_FILE (
      owner        IN VARCHAR2,
      table_name   IN VARCHAR2,
      file_url     IN VARCHAR2);

Parameter

Parameter Beschreibung
owner Legt den Schemanamen fest.
table_name Gibt den Namen der Quelltabelle an. Die Quelltabelle kann entweder eine externe Tabelle oder eine Tabelle sein, die über einen gemounteten Katalog bereitgestellt wird.
file_url Gibt die Datei-URL an.

Beispiel

BEGIN
  DBMS_EXT_TABLE_CACHE.DROP_FILE (
    owner        => 'SALES',
    table_name   => 'STORE_SALES',
    file_url     => 'https://swiftobjectstorage.us-ashburn-1.oraclecloud.com/v1/your_namespace/your_bucket/salesdata.parquet'
);
END;
/

Diese Prozedur unterstützt auch Tabellen, die über gemountete Kataloge bereitgestellt werden.

Prozedur aktivieren

Die Prozedur DBMS_EXT_TABLE_CACHE.ENABLE aktiviert einen zuvor deaktivierten Lake-Cache. Wenn ein Cache erstellt wird, ist er standardmäßig aktiviert.

Syntax

DBMS_EXT_TABLE_CACHE.ENABLE (
    owner         IN    VARCHAR2,
    table_name    IN    VARCHAR2
);

Parameter

Parameter Beschreibung
owner Legt den Schemanamen fest.
table_name Gibt den Namen der Quelltabelle an. Die Quelltabelle kann entweder eine externe Tabelle oder eine Tabelle sein, die über einen gemounteten Katalog bereitgestellt wird.

Beispiel

BEGIN
  DBMS_EXT_TABLE_CACHE.ENABLE (
    owner        => 'SALES',
    table_name   => 'STORE_SALES'
 );
END;
/

Diese Prozedur unterstützt auch Tabellen, die über gemountete Kataloge bereitgestellt werden.

Funktion GET_AVAILABLE_QUOTA

Mit der Funktion DBMS_EXT_TABLE_CACHE.GET_AVAILABLE_QUOTA können Sie die verbleibende verfügbare Cache-Quota für ein Schema oder einen bestimmten externen Tabellencache abrufen.

Syntax

DBMS_EXT_TABLE_CACHE.GET_AVAILABLE_QUOTA (
    owner       IN   VARCHAR2,
    table_name  IN   VARCHAR2 DEFAULT NULL,
    no_cache    OUT  BOOLEAN,
    total_quota OUT  NUMBER
)
RETURN NUMBER;

Parameter

Parameter Beschreibung
owner Legt den Schemanamen fest.
table_name Gibt den Namen der externen Tabelle an. Wenn table_name NULL ist, gibt die Funktion Quota-Informationen für das Schema zurück.
no_cache Gibt TRUE zurück, wenn keine Cache-Quota verfügbar ist.
total_quota Gibt die gesamte Quota zurück, die für das Schema oder den Cache verfügbar ist.

Rückgabewert

Gibt die verbleibende verfügbare Quota zurück.

Beispiele

Beispiel für die Prüfung der verfügbaren Quota für ein Schema:

SET SERVEROUTPUT ON;
DECLARE
  l_available_quota NUMBER;
  l_total_quota     NUMBER;
  l_no_cache        BOOLEAN;
BEGIN
  l_available_quota := DBMS_EXT_TABLE_CACHE.GET_AVAILABLE_QUOTA(
                         owner       => 'HR',
                         table_name  => NULL,
                         no_cache    => l_no_cache,
                         total_quota => l_total_quota);

  IF l_no_cache THEN
    DBMS_OUTPUT.PUT_LINE('NO_CACHE=TRUE');
  ELSE
    DBMS_OUTPUT.PUT_LINE('NO_CACHE=FALSE');
  END IF;

  DBMS_OUTPUT.PUT_LINE('TOTAL_QUOTA=' || l_total_quota);
  DBMS_OUTPUT.PUT_LINE('AVAILABLE_QUOTA=' || l_available_quota);
END;
/

Beispiel für die Prüfung der verfügbaren Quota für einen bestimmten externen Tabellencache:

SET SERVEROUTPUT ON;
DECLARE
  l_available_quota NUMBER;
  l_total_quota     NUMBER;
  l_no_cache        BOOLEAN;
BEGIN
  l_available_quota := DBMS_EXT_TABLE_CACHE.GET_AVAILABLE_QUOTA(
                         owner       => 'SALES',
                         table_name  => 'STORE_SALES',
                         no_cache    => l_no_cache,
                         total_quota => l_total_quota);

  IF l_no_cache THEN
    DBMS_OUTPUT.PUT_LINE('NO_CACHE=TRUE');
  ELSE
    DBMS_OUTPUT.PUT_LINE('NO_CACHE=FALSE');
  END IF;

  DBMS_OUTPUT.PUT_LINE('TOTAL_QUOTA=' || l_total_quota);
  DBMS_OUTPUT.PUT_LINE('AVAILABLE_QUOTA=' || l_available_quota);
END;
/

Funktion GET_GLOBAL_CACHE_QUOTA

Verwenden Sie die Funktion DBMS_EXT_TABLE_CACHE.GET_GLOBAL_CACHE_QUOTA, um die aufgelöste globale Cache-Quota abzurufen.

Syntax

DBMS_EXT_TABLE_CACHE.GET_GLOBAL_CACHE_QUOTA
RETURN NUMBER;

Rückgabewert

Gibt die aufgelöste globale Cache-Quota basierend auf GLOBAL_CACHE_SIZE und GLOBAL_CACHE_PERCENT zurück.

Hinweise zur Verwendung

  • Wenn sowohl GLOBAL_CACHE_SIZE als auch GLOBAL_CACHE_PERCENT festgelegt sind, wird der größere Wert verwendet.

  • Wenn keine globale Quota-Eigenschaft explizit festgelegt ist, lautet der Standardwert für GLOBAL_CACHE_PERCENT 20.

Beispiel

SET SERVEROUTPUT ON;
DECLARE
  l_global_quota NUMBER;
BEGIN
  l_global_quota := DBMS_EXT_TABLE_CACHE.GET_GLOBAL_CACHE_QUOTA;
  DBMS_OUTPUT.PUT_LINE('GLOBAL_CACHE_QUOTA=' || l_global_quota);
END;
/

Funktion GET_USER_PROPERTY

Die Funktion gibt die Caching-Voreinstellung für das angegebene Schema zurück und gibt eine Number zurück.

MAX_CACHE_SIZE und MAX_CACHE_PERCENT sind Quota-Steuerelemente auf Schemaebene innerhalb des globalen Quota-Modells.

Syntax

DBMS_EXT_TABLE_CACHE.GET_USER_PROPERTY (
    property_name   IN   VARCHAR2,
    owner           IN   VARCHAR2 DEFAULT NULL);

RETURN NUMBER;

Parameter

Parameter Beschreibung
property_name

Gibt den Namen der Eigenschaft an.

Folgende gültige Werte sind für property_name verfügbar:

  • MAX_CACHE_PERCENT

  • MAX_CACHE_SIZE

owner Legt den Schemanamen fest.

Rückgabewerte

Rückgabewert Beschreibung
Der Wert MAX_CACHE_SIZE oder MAX_CACHE_PERCENT in Number. Je nach Parameter property_name gibt die Funktion den Wert MAX_CACHE_SIZE oder MAX_CACHE_PERCENT zurück.

Hinweise zur Verwendung

  • Wenn die globale Cache-Quota bekannt ist, basiert MAX_CACHE_PERCENT auf der aufgelösten globalen Quota. Andernfalls basiert er auf der Schema- oder Cache Tablespace Quota.

  • Wenn sowohl MAX_CACHE_SIZE als auch MAX_CACHE_PERCENT festgelegt sind, wird der größere Wert verwendet.

  • Wenn keine Quota-Eigenschaft auf Schemaebene explizit festgelegt ist, lautet der Standardwert für MAX_CACHE_PERCENT 20.

  • Manuelle Caches und AUTO-Caches belegen denselben Quota-Pool.

Beispiel

SET SERVEROUTPUT ON;
DECLARE
  l_max_cache_sz NUMBER;
BEGIN
  l_max_cache_sz := DBMS_EXT_TABLE_CACHE.GET_USER_PROPERTY(
                      property_name => 'MAX_CACHE_SIZE',
                      owner         => 'SALES');
  DBMS_OUTPUT.PUT_LINE('MAX_CACHE_SIZE=' || l_max_cache_sz);
END;
/

Prozedur REFRESH_TABLE

Die Prozedur DBMS_EXT_TABLE_CACHE.REFRESH_TABLE löscht gecachte Daten für nicht mehr vorhandene Dateien und lädt die neu oder neu geänderten Dateien.

Syntax

DBMS_EXT_TABLE_CACHE.REFRESH_TABLE (
    owner        IN VARCHAR2,
    table_name   IN VARCHAR2);

Parameter

Parameter Beschreibung
owner Legt den Schemanamen fest.
table_name Gibt den Namen der Quelltabelle an. Die Quelltabelle kann entweder eine externe Tabelle oder eine Tabelle sein, die über einen gemounteten Katalog bereitgestellt wird.

Beispiel

In diesem Beispiel werden gecachte Daten für die Tabelle STORE_SALES im Schema SALES aktualisiert.

BEGIN
  DBMS_EXT_TABLE_CACHE.REFRESH_TABLE (
    owner        => 'SALES',
    table_name   => 'STORE_SALES');
END;
/

Diese Prozedur unterstützt auch Tabellen, die über gemountete Kataloge bereitgestellt werden.

Prozedur RETIRE_FILES

Die DBMS_EXT_TABLE_CACHE.RETIRE_FILES löscht Dateien aus dem Cache, die älter als das angegebene Intervall sind. Die Dateien werden basierend auf dem Zeitintervall gelöscht, das mit dem Parameterwert BEFORE berechnet wird.

Syntax

DBMS_EXT_TABLE_CACHE.RETIRE_FILES (
    owner        IN VARCHAR2,
    table_name   IN VARCHAR2,
    before       IN INTERVAL DAY TO SECOND
);

Parameter

Parameter Beschreibung
owner Legt den Schemanamen fest.
table_name Gibt den Namen der Quelltabelle an. Die Quelltabelle kann entweder eine externe Tabelle oder eine Tabelle sein, die über einen gemounteten Katalog bereitgestellt wird.
before Der Parameter before akzeptiert einen INTERVAL DAY TO SECOND-Wert und wird zur Berechnung des Zeitintervalls zwischen dem Wert before und dem aktuellen Zeitstempel verwendet. Das resultierende Zeitintervall wird dann verwendet, um die Dateien aus dem Cache zu löschen.

Beispiel

BEGIN
 DBMS_EXT_TABLE_CACHE.RETIRE_FILES (
    owner        => 'SALES',
    table_name   => 'STORE_SALES',
    before       => INTERVAL '30' DAY);
END;
/

Diese Prozedur unterstützt auch Tabellen, die über gemountete Kataloge bereitgestellt werden.

Prozedur SET_USER_PROPERTY

Die Prozedur DBMS_EXT_TABLE_CACHE.SET_USER_PROPERTY legt die Caching-Voreinstellung für ein Schema fest.

Verwenden Sie MAX_CACHE_SIZE und MAX_CACHE_PERCENT, um Quota-Voreinstellungen auf Schemaebene für Policy-basierte Caches festzulegen.

Syntax

DBMS_EXT_TABLE_CACHE.SET_USER_PROPERTY (
    property_name    IN    VARCHAR2,
    property_value   IN    NUMBER,
    owner            IN    VARCHAR2 DEFAULT NULL);

Parameter

Parameter Beschreibung
property_name

Gibt den Namen der Eigenschaft an.

Folgende gültige Werte sind für property_name verfügbar:

  • MAX_CACHE_PERCENT

  • MAX_CACHE_SIZE

property_value Gibt den Eigenschaftswert an.
owner Legt den Schemanamen fest.

Hinweise zur Verwendung

  • Wenn die globale Cache-Quota bekannt ist, basiert MAX_CACHE_PERCENT auf der aufgelösten globalen Quota. Andernfalls basiert er auf der Schema- oder Cache Tablespace Quota.

  • Wenn sowohl MAX_CACHE_SIZE als auch MAX_CACHE_PERCENT festgelegt sind, wird der größere Wert verwendet.

  • Wenn keine Quota-Eigenschaft auf Schemaebene explizit festgelegt ist, lautet der Standardwert für MAX_CACHE_PERCENT 20.

  • Wenn MAX_CACHE_SIZE größer als GLOBAL_CACHE_SIZE festgelegt ist, löst die Datenbank einen Fehler aus.

  • Manuelle Caches und AUTO-Caches belegen denselben Quota-Pool.

Beispiel

BEGIN
  DBMS_EXT_TABLE_CACHE.SET_USER_PROPERTY(
    property_name  => 'MAX_CACHE_PERCENT',
    property_value => 100,
    owner          => 'SALES');
END;
/

Prozedur VALIDATE

Die Prozedur DBMS_EXT_TABLE_CACHE.VALIDATE validiert den Lake-Cache. Ein Fehler wird gemeldet, wenn die referenzierte Quelltabelle nicht in der Datenbank gefunden wurde.

Syntax

DBMS_EXT_TABLE_CACHE.VALIDATE (
      owner            IN    VARCHAR2,
      table_name       IN    VARCHAR2,
      raise_errors     IN    BOOLEAN DEFAULT TRUE);

Parameter

Parameter Beschreibung
owner Legt den Schemanamen fest.
table_name Gibt den Namen der Quelltabelle an. Die Quelltabelle kann entweder eine externe Tabelle oder eine Tabelle sein, die über einen gemounteten Katalog bereitgestellt wird.
raise_errors Meldet, wenn ein Lake-Cache als ungültig markiert ist.

Beispiel

BEGIN
  DBMS_EXT_TABLE_CACHE.VALIDATE (
    owner         => 'SALES',
    table_name    => 'STORE_SALES',
    raise_errors  => TRUE);
END;
/

Diese Prozedur unterstützt auch Tabellen, die über gemountete Kataloge bereitgestellt werden.