Empfehlungen aktivieren und implementieren

EXEC DBMS_AUTO_PARTITION.CONFIGURE('AUTO_PARTITION_MODE','IMPLEMENT');

Empfehlungen aktivieren, ohne sie zu implementieren

EXEC DBMS_AUTO_PARTITION.CONFIGURE('AUTO_PARTITION_MODE','REPORT ONLY');

Neue Empfehlungen und Implementierung dieser neuen Empfehlungen deaktivieren

EXEC DBMS_AUTO_PARTITION.CONFIGURE('AUTO_PARTITION_MODE','OFF');

Schemas und Tabellen für automatische Partitionierung verwalten

• Wenn die Inklusionsliste und die Exklusionsliste leer sind, fügen Sie das Schema HR und die Tabelle SH.SALES zur Exklusionsliste hinzu, sodass nur diese Objekte nicht automatisch partitionierungsanalysen ausführen können.

  BEGIN
      DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_SCHEMA', 
           PARAMETER_VALUE => 'HR',
           ALLOW           => FALSE);
  
      DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_TABLE', 
           PARAMETER_VALUE => 'SH.SALES',
           ALLOW           => FALSE);
  END;
  /

• Nachdem das vorherige Beispiel ausgeführt wurde, entfernen Sie wie folgt das Schema HR aus der Exklusionsliste.

  BEGIN
      DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_SCHEMA', 
           PARAMETER_VALUE => 'HR',
           ALLOW           => NULL);
  END;
  /

• Mit dem folgenden Befehl entfernen Sie alle Schemas aus der Ausschlussliste.

  BEGIN
      DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_SCHEMA', 
           PARAMETER_VALUE => NULL,
           ALLOW           => TRUE);
  END;
  /

• Wenn die Inklusions- und Exklusionslisten leer sind, wird im folgenden Beispiel das Schema HR zur Inklusionsliste hinzugefügt. Sobald die Einschlussliste nicht mehr leer ist, werden nur Schemas in der Einschlussliste berücksichtigt.

  In diesem Beispiel ist nur das Schema HR für die automatische Partitionierung geeignet.

  BEGIN
      DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_SCHEMA', 
           PARAMETER_VALUE => 'HR',
           ALLOW           => TRUE);
  END;
  /

Aufbewahrungszeitraum für automatische Partitionierungsberichte verwalten

Der Aufbewahrungszeitraum für automatische Partitionierungsberichte wird auf 365 Tage festgelegt.

BEGIN
    DBMS_AUTO_PARTITION.CONFIGURE(
         PARAMETER_NAME  => 'AUTO_PARTITION_REPORT_RETENTION', 
         PARAMETER_VALUE => '365');
END;
/

Bericht über automatische Partitionierungsvorgänge für einen bestimmten Zeitraum im einfachen Textformat generieren

In diesem Beispiel wird ein Bericht generiert, der typische Informationen über die automatischen Partitionierungsvorgänge der letzten 24 Stunden enthält. Der Report wird standardmäßig im einfachen Textformat generiert.

DECLARE
  Report clob := NULL
BEGIN
    Report := DBMS_AUTO_PARTITION.REPORT_ACTIVITY();
END;
/

Bericht über automatische Partitionierungsvorgänge im HTML-Format für Mai 2021 generieren

In diesem Beispiel wird ein Bericht generiert, der grundlegende Informationen über die automatischen Partitionierungsvorgänge für den Monat Mai 2021 enthält. Der Report wird im HTML-Format generiert und enthält nur eine Zusammenfassung von automatischen Partitionierungsvorgängen.

DECLARE
  Report clob := NULL
BEGIN
    Report := DBMS_AUTO_PARTITION.REPORT_ACTIVITY(
                       ACTIVITY_START => TO_TIMESTAMP('2021-05-01', 'YYYY-MM-DD'),
                       ACTIVITY_END   => TO_TIMESTAMP('2021-06-01', 'YYYY-MM-DD'),
                       TYPE           => 'HTML',
                       SECTION        => 'SUMMARY',
                       LEVEL          => 'BASIC' );
END;
/

Bericht über den letzten automatischen Partitionierungsvorgang generieren (im Nur-Text-Format)

In diesem Beispiel wird ein Bericht generiert, der typische Informationen über den letzten automatischen Partitionierungsvorgang enthält. Der Report wird standardmäßig im einfachen Textformat generiert.

DECLARE
  Report clob := NULL
BEGIN
    Report := DBMS_AUTO_PARTITION.REPORT_LAST_ACTIVITY();
END;
/

Weitere Informationen finden Sie unter Funktion REPORT_ACTIVITY.

Weitere Informationen finden Sie unter Funktion REPORT_LAST_ACTIVITY.

Empfehlung für eine einzelne Tabelle generieren und Empfehlung manuell anwenden

1. Setzen Sie den Parameter AUTO_PARTITION_MODE auf REPORT ONLY, damit eine automatische Partitionierungsempfehlung abgegeben und verifiziert werden kann. Die Empfehlung wird nicht auf die Tabelle angewendet.

   BEGIN
       DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_MODE', 
           PARAMETER_VALUE => 'REPORT ONLY');
   END;
   /

2. Prüfen Sie, ob die Tabelle TPCH.LINEITEM für die automatische Partitionierung in Frage kommt. Dieser Schritt ist optional und wird empfohlen, wenn Sie selektiv einzelne Tabellen prüfen.

   SELECT DBMS_AUTO_PARTITION.VALIDATE_CANDIDATE_TABLE(
              TABLE_OWNER => 'TPCH',
              TABLE_NAME  => 'LINEITEM')
   FROM DUAL;

   Wenn die Tabelle in Frage kommt, wird beim Aufrufen der automatischen Partitionierung für eine Empfehlungsanalyse VALID zurückgegeben. Andernfalls werden die Verletzungskriterien angezeigt.

   Eine Liste der Kriterien für mögliche Kandidatentabellen finden Sie unter Funktion VALIDATE_CANDIDATE_TABLE.

3. Rufen Sie die DBMS_AUTO_PARTITION-API auf, um eine Empfehlung für die Tabelle TPCH.LINEITEM zu generieren.

   -- DEFINE SQLPLUS BIND VARIABLE FOR RECOMMENDATION ID
   VARIABLE RECOMMENDATION_ID VARCHAR2(32);
   BEGIN
     :RECOMMENDATION_ID := DBMS_AUTO_PARTITION.RECOMMEND_PARTITION_METHOD(
                                TABLE_OWNER => 'TPCH',
                                TABLE_NAME  => 'LINEITEM');
   END;
   /

   Die Empfehlungsanalyse und -verifizierung, die Sie mit DBMS_AUTO_PARTITION.RECOMMEND_PARTITION_METHOD ausführen, kann ein ressourcenintensiver Vorgang mit langer Ausführungszeit sein und viel Zeit dauern. Führen Sie diesen Schritt in einer Datenbank aus, die nicht Ihr primäres Produktionssystem ist. Oracle empfiehlt, dem Verifizierungsvorgang ausreichende Ressourcen bereitzustellen, indem der Service HIGH ausgewählt wird.

4. Prüfen Sie die Empfehlung. Die View DBA_AUTO_PARTITION_RECOMMENDATIONS enthält die Informationen zur Empfehlung. In diesem Beispiel prüfen Sie den empfohlenen Partitionsschlüssel und die empfohlene Partitionsmethode.

   SELECT PARTITION_METHOD, PARTITION_KEY
     FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
     WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID;
   

   Fragen Sie außerdem dieselbe View ab, um den Performanceanalysebericht abzurufen, der für die Workload generiert wurde, nachdem die Tabelle entsprechend der Empfehlung partitioniert wurde.

   SELECT REPORT
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID;
   

5. Wenden Sie die Empfehlung nach der manuellen Validierung der Empfehlung an. Wenn Sie die Empfehlung in der Datenbank anwenden, in der die Empfehlungsanalyse stattgefunden hat, führen Sie dazu die Prozedur APPLY_RECOMMENDATION aus.

   BEGIN
       DBMS_AUTO_PARTITION.APPLY_RECOMMENDATION(
            RECOMMENDATION_ID => :RECOMMENDATION_ID);
   END;
   /

   Wenn Sie die Empfehlung auf eine andere Datenbank anwenden möchten, wie z.B. Ihre Produktionsumgebung, extrahieren Sie die Änderungs-DDL. Führen Sie dann die extrahierte Änderungs-DDL in der Zieldatenbank aus. Die Abfrage zum Exportieren der Änderungs-DDL lautet wie folgt:

   SELECT MODIFY_TABLE_DDL
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID;
   

   Beispielausgabe der Änderungs-DDL:

   BEGIN
       -- DBMS_AUTO_PARTITION RECOMMENDATION_ID C3F7A59E085C2F25E05333885A0A55EA
       --   FOR TABLE "TPCH"."LINEITEM"
       --   GENERATED AT 06/04/2021 20:52:29
       DBMS_AUTO_PARTITION.BEGIN_APPLY(EXPECTED_NUMBER_OF_PARTITIONS => 10);
   
       EXECUTE IMMEDIATE
       'ALTER TABLE "TPCH"."LINEITEM"
       MODIFY PARTITION BYLIST(SYS_OP_INTERVAL_HIGH_BOUND
           ("L_SHIPDATE", INTERVAL ''10'' MONTH, TIMESTAMP ''1992-01-01 00:00:00''))
       AUTOMATIC /* SCORE=23533.11;  */
       (PARTITION P_NULL VALUES(NULL))
       AUTO ONLINE PARALLEL';
   
       DBMS_AUTO_PARTITION.END_APPLY;
   EXCEPTION WHEN OTHERS THEN
       DBMS_AUTO_PARTITION.END_APPLY;
       RAISE;
   END;
   

6. Überprüfen Sie, ob die Tabelle automatisch partitioniert wurde, indem Sie die Katalog-Views abfragen.

   SELECT T.AUTO, T.PARTITIONING_TYPE, C.COLUMN_NAME
       FROM DBA_PART_TABLES T, DBA_PART_KEY_COLUMNS C
       WHERE T.OWNER = 'TPCH' AND T.TABLE_NAME = 'LINEITEM'
           AND T.OWNER = C.OWNER AND T.TABLE_NAME = C.NAME;
   

   Mit dieser Abfrage können Sie ermitteln, ob die automatische Partitionierung auf eine bestimmte Tabelle angewendet wurde.

   SELECT APPLY_TIMESTAMP_START, APPLY_TIMESTAMP_END
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE TABLE_OWNER = 'TPCH' AND TABLE_NAME = 'LINEITEM';
   

Weitere Informationen finden Sie unter Prozedur CONFIGURE.

Informationen dazu finden Sie unter Funktion VALIDATE_CANDIDATE_TABLE.

Informationen dazu finden Sie unter Funktion RECOMMEND_PARTITION_METHOD.

Weitere Informationen finden Sie unter Prozedur APPLY_RECOMMENDATION.

Empfehlung für in Frage kommende Tabellen generieren und Empfehlung manuell anwenden

1. Setzen Sie den Parameter AUTO_PARTITION_MODE auf REPORT ONLY, damit eine automatische Partitionierungsempfehlung abgegeben und verifiziert werden kann. Die Empfehlung wird nicht auf vorhandene Tabellen angewendet.

   BEGIN
       DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_MODE', 
           PARAMETER_VALUE => 'REPORT ONLY');
   END;
   /

2. Rufen Sie die DBMS_AUTO_PARTITION-API auf, um eine Empfehlungstabelle zu generieren.

   -- DEFINE SQLPLUS BIND VARIABLE FOR RECOMMENDATION ID
   VARIABLE RECOMMENDATION_ID VARCHAR2(32);
   BEGIN
     :RECOMMENDATION_ID := DBMS_AUTO_PARTITION.RECOMMEND_PARTITION_METHOD();
   END;
   /

   Die Recommendation-Analyse und -Verifizierung ist ein Vorgang mit Ressourcenintensität und langer Ausführungszeit, der viel Zeit in Anspruch nehmen kann. Bei sekundären Nicht-Produktionsdatenbanken empfiehlt Oracle, ausreichende Ressourcen für die Verifizierung bereitzustellen, indem der Service HIGH gewählt wird.

3. Fragen Sie die View DBA_AUTO_PARTITION_RECOMMENDATIONS ab, um zu sehen, welche Tabellen analysiert wurden.

   SELECT TABLE_OWNER, TABLE_NAME, PARTITION_METHOD, PARTITION_KEY
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID
       ORDER BY RECOMMENDATION_SEQ;
   

4. Mit dieser Abfrage können Sie einen Drilldown im Bericht für eine bestimmte Tabelle durchführen, die bei der Ausführung analysiert wurde. In diesem Beispiel ist dies die Tabelle TPCH.LINEITEM.

   SELECT REPORT
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID
           AND TABLE_OWNER = 'TPCH'
           AND TABLE_NAME  = 'LINEITEM';
   

5. Wenden Sie die Empfehlung an, indem Sie die Prozedur APPLY_RECOMMENDATION ausführen.

   BEGIN
       DBMS_AUTO_PARTITION.APPLY_RECOMMENDATION(
            RECOMMENDATION_ID => :RECOMMENDATION_ID);
   END;
   /

   Alternativ können Sie Empfehlungen für eine bestimmte analysierte Tabelle anwenden, in diesem Beispiel die Tabelle TPCH.LINEITEM.

   BEGIN
       DBMS_AUTO_PARTITION.APPLY_RECOMMENDATION(
           RECOMMENDATION_ID => :RECOMMENDATION_ID,
           TABLE_OWNER       => 'TPCH',
           TABLE_NAME        => 'LINEITEM');
   END;
   /

Weitere Informationen finden Sie unter Prozedur CONFIGURE.

Informationen dazu finden Sie unter Funktion RECOMMEND_PARTITION_METHOD.

Weitere Informationen finden Sie unter Prozedur APPLY_RECOMMENDATION.

Empfehlungen für in Frage kommende Tabellen generieren und automatisch anwenden

1. Setzen Sie den Parameter AUTO_PARTITION_MODE auf REPORT ONLY, damit eine automatische Partitionierungsempfehlung abgegeben und verifiziert werden kann. Die Empfehlung wird nicht auf vorhandene Tabellen angewendet.

   BEGIN
       DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_MODE', 
           PARAMETER_VALUE => 'IMPLEMENT');
   END;
   /

2. Rufen Sie die DBMS_AUTO_PARTITION-API auf, um eine Empfehlungstabelle zu generieren.

   -- DEFINE SQLPLUS BIND VARIABLE FOR RECOMMENDATION ID
   VARIABLE RECOMMENDATION_ID VARCHAR2(32);
   BEGIN
     :RECOMMENDATION_ID := DBMS_AUTO_PARTITION.RECOMMEND_PARTITION_METHOD();
   END;
   /

   Die Recommendation-Analyse und -Verifizierung ist ein Vorgang mit Ressourcenintensität und langer Ausführungszeit, der viel Zeit in Anspruch nehmen kann. Bei sekundären Nicht-Produktionsdatenbanken empfiehlt Oracle, ausreichende Ressourcen für die Verifizierung bereitzustellen, indem der Service HIGH gewählt wird.

3. Fragen Sie die View DBA_AUTO_PARTITION_RECOMMENDATIONS ab, um zu sehen, welche Tabellen analysiert wurden.

   SELECT TABLE_OWNER, TABLE_NAME, PARTITION_METHOD, PARTITION_KEY
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID
       ORDER BY RECOMMENDATION_SEQ;
   

4. Verwenden Sie die Funktion REPORT_LAST_ACTIVITY, um den Bericht über die Aktionen abzurufen, die während der letzten Ausführung ausgeführt wurden.

   SELECT DBMS_AUTO_PARTITION.REPORT_LAST_ACTIVITY() FROM DUAL;
   

Weitere Informationen finden Sie unter Prozedur CONFIGURE.

Informationen dazu finden Sie unter Funktion RECOMMEND_PARTITION_METHOD.

Informationen dazu finden Sie unter Funktion REPORT_LAST_ACTIVITY.