Uso de mensajes persistentes con mensajes almacenados en el almacén de objetos en la nube

Mensajes persistentes en DBMS_PIPE:

• Permite enviar y recuperar mensajes muy grandes.

• Admite el envío de un gran número de mensajes de conducción.

• Soporte para enviar y recibir mensajes en una única base de datos, en varias bases de datos y en distintas regiones.

• Soporta varios pipes con el mismo URI de ubicación de almacenamiento de objetos en la nube.

Los canales de mensajes persistentes se pueden crear en cualquiera de los tipos de DBMS_PIPE soportados:

• Conducto implícito: se crea automáticamente cuando se envía un mensaje con un nombre de conducto desconocido mediante la función DBMS_PIPE.SEND_MESSAGE.
• Conducto explícito: se crea mediante la función DBMS_PIPE.CREATE_PIPE con un nombre de conducto especificado por el usuario.
• Pipa pública: accesible para cualquier usuario con permiso EXECUTE en el paquete DBMS_PIPE.
• Pipa privada: se puede acceder mediante sesiones con el mismo usuario que el creador del pipeline.

A continuación se muestra el flujo de trabajo general para DBMS_PIPE con mensajes persistentes:

Las aplicaciones existentes que utilizan DBMS_PIPE pueden seguir funcionando con cambios mínimos. Puede configurar aplicaciones existentes que utilicen DBMS_PIPE con un URI de ubicación y objeto de credencial mediante un disparador de conexión o mediante alguna otra rutina de inicialización. Después de definir el URI de ubicación y credencial DBMS_PIPE, no se necesitan otros cambios para utilizar mensajes persistentes. El uso posterior del canal almacena los mensajes en el almacén de objetos en la nube en lugar de en la memoria de la base de datos. Esto le permite cambiar el método de almacenamiento para mensajes de Cloud Object Storage en memoria a persistente, con cambios mínimos.

Describe los pasos para crear un conducto persistente con un nombre de conducto especificado (tubo explícito).

1. Almacene las credenciales del almacén de objetos mediante el procedimiento DBMS_CLOUD.CREATE_CREDENTIAL. Por ejemplo:

   BEGIN
     DBMS_CLOUD.CREATE_CREDENTIAL(
       credential_name => 'my_persistent_pipe_cred',
       username => 'adb_user@example.com',
       password => 'password'
     );
   END;
   /

   Esta operación almacena las credenciales en la base de datos en un formato cifrado. Puede utilizar cualquier nombre para el nombre de credencial. Tenga en cuenta que este paso solo es necesario una vez, a menos que cambien las credenciales del almacén de objetos. Después de almacenar las credenciales, puede utilizar el mismo nombre de credencial para acceder al almacén de objetos en la nube y enviar y recibir mensajes con DBMS_PIPE.

   Para obtener información detallada sobre los parámetros, consulte el Procedimiento CREATE_CREDENTIAL. Para Oracle Cloud Infrastructure Object Storage, es necesario que la credencial utilice la autenticación nativa de Oracle Cloud Infrastructure.

   No es necesario crear una credencial para acceder al almacén de objetos de Oracle Cloud Infrastructure si activa las credenciales de entidad de recurso. Consulte Uso de la entidad de recurso para acceder a los Recursos de Oracle Cloud Infrastructure para obtener más información.

   Nota
   
   Algunas herramientas como SQL*Plus y SQL Developer utilizan el carácter de ampersand (&) como carácter especial. Si tiene el carácter ampersand en la contraseña, utilice el comando SET DEFINE OFF en esas herramientas, como se muestra en el ejemplo, para desactivar el carácter especial y obtener la credencial creada correctamente.
2. Cree un conducto explícito para enviar y recuperar mensajes. Por ejemplo, cree un conducto denominado ORDER_PIPE.

   DECLARE
     r_status INTEGER;
   BEGIN
       r_status := DBMS_PIPE.CREATE_PIPE(pipename => 'ORDER_PIPE');
   END;
   /

   Consulte CREATE_PIPE Function para obtener más información.

3. Verifique que se haya creado la conducción.

   SELECT ownerid, name, type FROM v$db_pipes 
          WHERE name = 'ORDER_PIPE';

   OWNERID NAME       TYPE    
   ------- ---------- ------- 
        80 ORDER_PIPE PRIVATE 

4. Utilice los procedimientos DBMS_PIPE para definir el URI de ubicación y la credencial de acceso por defecto para almacenar mensajes persistentes en el almacén de objetos en la nube.

   BEGIN
       DBMS_PIPE.SET_CREDENTIAL_NAME('my_persistent_pipe_cred');
       DBMS_PIPE.SET_LOCATION_URI('https://objectstorage.us-phoenix-1.oraclecloud.com/n/namespace-string/b/bucketname1/'); 
   END;
   /

   Estos procedimientos definen el nombre de credencial por defecto y el URI de ubicación por defecto para su uso con procedimientos DBMS_PIPE.

   Si utiliza Oracle Cloud Infrastructure Object Storage para almacenar mensajes, puede utilizar los URI nativos de Oracle Cloud Infrastructure o los URI de Swift. Sin embargo, el URI de ubicación y la credencial deben coincidir en el tipo de la siguiente manera:

   • Si utiliza un formato de URI nativo para acceder a Oracle Cloud Infrastructure Object Storage, debe utilizar la autenticación de claves de firma nativas de Oracle Cloud Infrastructure en el objeto de credencial.

   • Si utiliza el formato URI de Swift para acceder a Oracle Cloud Infrastructure Object Storage, debe utilizar una autenticación de token de autenticación en el objeto de credencial.

   Consulte Procedimiento SET_CREDENTIAL_NAME y Procedimiento SET_LOCATION_URI para obtener más información.

5. Empaquetar y enviar un mensaje en el conducto.

   DECLARE
     l_result INTEGER;
     l_date   DATE;
   BEGIN
       l_date := sysdate;
       DBMS_PIPE.PACK_MESSAGE(l_date);         -- date of order
       DBMS_PIPE.PACK_MESSAGE('C123');         -- order number
       DBMS_PIPE.PACK_MESSAGE(5);              -- number of items in order
       DBMS_PIPE.PACK_MESSAGE('Printers');     -- type of item in order
   
    
       l_result := DBMS_PIPE.SEND_MESSAGE(
                       pipename => 'ORDER_PIPE',
                       credential_name => DBMS_PIPE.GET_CREDENTIAL_NAME,
                       location_uri => DBMS_PIPE.GET_LOCATION_URI);
        
       IF l_result = 0 THEN
           DBMS_OUTPUT.put_line('DBMS_PIPE sent order successfully');
       END IF;
    
   END;
   /

   Consulte PACK_MESSAGE Procedures y SEND_MESSAGE Function para obtener más información.

Describe los pasos para recuperar un mensaje persistente de un conducto explícito en la misma instancia de Autonomous Database (la instancia a la que se envió el mensaje).

1. Verifique que se haya creado la conducción.

   SELECT ownerid, name, type FROM v$db_pipes 
          WHERE name = 'ORDER_PIPE';
   

   OWNERID NAME       TYPE    
   ------- ---------- ------- 
        80 ORDER_PIPE PRIVATE 

   Cuando se encuentra en la misma instancia de Autonomous Database y existe el conducto, no es necesario que ejecute DBMS_PIPE.CREATE_PIPE antes de recibir un mensaje. Esto se aplica cuando el conducto se creó en la misma instancia, como se muestra en Create an Explicit Persistent Pipe and Send a Message.

2. Recibir un mensaje de la conducción.

   DECLARE
       message1  DATE;
       message2  VARCHAR2(100);
       message3  INTEGER;
       message4  VARCHAR2(100);
       l_result  INTEGER;
   
   BEGIN
   
       DBMS_PIPE.SET_CREDENTIAL_NAME('my_persistent_pipe_cred');
       DBMS_PIPE.SET_LOCATION_URI('https://objectstorage.us-phoenix-1.oraclecloud.com/n/namespace-string/b/bucketname1/'); 
       l_result := DBMS_PIPE.RECEIVE_MESSAGE (
                     pipename => 'ORDER_PIPE',
                     timeout  => DBMS_PIPE.MAXWAIT,
                     credential_name => DBMS_PIPE.GET_CREDENTIAL_NAME,
                     location_uri => DBMS_PIPE.GET_LOCATION_URI);
    
       IF l_result = 0 THEN
           DBMS_PIPE.unpack_message(message1);
           DBMS_PIPE.unpack_message(message2);
           DBMS_PIPE.unpack_message(message3);
           DBMS_PIPE.unpack_message(message4);
    
           DBMS_OUTPUT.put_line('Order Received Successfully On: ' || TO_CHAR(sysdate, 'dd-mm-yyyy hh24:mi:ss'));
           DBMS_OUTPUT.put_line('Date of Order: ' || message1);
           DBMS_OUTPUT.put_line('Order Number: ' || message2);
           DBMS_OUTPUT.put_line('Number of Items In Order: ' || message3);
           DBMS_OUTPUT.put_line('Item Type in Order: ' || message4);
       END IF;
    
   END;
   /

   Cuando está en la misma instancia de Autonomous Database, la credencial ya existe y no necesita ejecutar DBMS_CLOUD.CREATE_CREDENTIAL para recibir un mensaje. Esto se aplica cuando el conducto se creó en la misma instancia, como se muestra en Create an Explicit Persistent Pipe and Send a Message.

Describe los pasos para recuperar un mensaje persistente almacenado en el almacén de objetos en la nube con un conducto explícito en una instancia de Autonomous Database que sea diferente de la instancia que envió el mensaje.

1. Almacene las credenciales del almacén de objetos mediante el procedimiento DBMS_CLOUD.CREATE_CREDENTIAL. Por ejemplo:

   BEGIN
     DBMS_CLOUD.CREATE_CREDENTIAL(
       credential_name => 'my_persistent_pipe_cred',
       username => 'adb_user@example.com',
       password => 'password'
     );
   END;
   /

   Esta operación almacena las credenciales en la base de datos en un formato cifrado. Puede utilizar cualquier nombre para el nombre de credencial. Tenga en cuenta que este paso solo es necesario una vez, a menos que cambien las credenciales del almacén de objetos. Una vez almacenadas las credenciales, puede utilizar el mismo nombre de credencial para acceder al almacén de objetos en la nube y enviar y recibir mensajes con DBMS_PIPE.

   Para obtener información detallada sobre los parámetros, consulte el Procedimiento CREATE_CREDENTIAL.

   No es necesario crear una credencial para acceder al almacén de objetos de Oracle Cloud Infrastructure si activa las credenciales de entidad de recurso. Consulte Uso de la entidad de recurso para acceder a los Recursos de Oracle Cloud Infrastructure para obtener más información.

   Nota
   
   Algunas herramientas como SQL*Plus y SQL Developer utilizan el carácter de ampersand (&) como carácter especial. Si tiene el carácter ampersand en la contraseña, utilice el comando SET DEFINE OFF en esas herramientas, como se muestra en el ejemplo, para desactivar el carácter especial y obtener la credencial creada correctamente.
2. Cree un conducto explícito con el mismo nombre que el conducto que envió el mensaje. Por ejemplo, cree un conducto denominado ORDER_PIPE.

   DECLARE
     r_status INTEGER;
   BEGIN
       r_status := DBMS_PIPE.CREATE_PIPE(pipename => 'ORDER_PIPE');
   END;
   /

   Consulte CREATE_PIPE Function.

3. Verifique que se haya creado la conducción.

   SELECT ownerid, name, type FROM v$db_pipes 
          WHERE name = 'ORDER_PIPE';
   

   OWNERID NAME       TYPE    
   ------- ---------- ------- 
        80 ORDER_PIPE PRIVATE 

4. Utilice los procedimientos DBMS_PIPE para definir la credencial de acceso y el URI de ubicación por defecto para el almacén de objetos, de modo que DBMS_PIPE pueda acceder al mensaje persistente.

   BEGIN
       DBMS_PIPE.SET_CREDENTIAL_NAME('my_persistent_pipe_cred');
       DBMS_PIPE.SET_LOCATION_URI('https://objectstorage.us-phoenix-1.oraclecloud.com/n/namespace-string/b/bucketname1/'); 
   END;
   /

   Estos procedimientos definen el nombre de credencial por defecto y el URI de ubicación por defecto para su uso con procedimientos DBMS_PIPE.

   Si utiliza Oracle Cloud Infrastructure Object Storage para almacenar mensajes, puede utilizar los URI nativos de Oracle Cloud Infrastructure o los URI de Swift. Sin embargo, el URI de ubicación y la credencial deben coincidir en el tipo de la siguiente manera:

   • Si utiliza un formato de URI nativo para acceder a Oracle Cloud Infrastructure Object Storage, debe utilizar la autenticación de claves de firma nativas de Oracle Cloud Infrastructure en el objeto de credencial.

   • Si utiliza el formato URI de Swift para acceder a Oracle Cloud Infrastructure Object Storage, debe utilizar una autenticación de token de autenticación en el objeto de credencial.

   Consulte Procedimiento SET_CREDENTIAL_NAME y Procedimiento SET_LOCATION_URI para obtener más información.

5. Reciba un mensaje del conducto persistente.

   DECLARE
       message1  DATE;
       message2  VARCHAR2(100);
       message3  INTEGER;
       message4  VARCHAR2(100);
       l_result  INTEGER;
   
   BEGIN
   
       DBMS_PIPE.SET_CREDENTIAL_NAME('my_persistent_pipe_cred');
       DBMS_PIPE.SET_LOCATION_URI('https://objectstorage.us-phoenix-1.oraclecloud.com/n/namespace-string/b/bucketname1/'); 
       l_result := DBMS_PIPE.RECEIVE_MESSAGE (
                     pipename => 'ORDER_PIPE',
                     timeout  => DBMS_PIPE.MAXWAIT,
                     credential_name => DBMS_PIPE.GET_CREDENTIAL_NAME,
                     location_uri => DBMS_PIPE.GET_LOCATION_URI);
    
       IF l_result = 0 THEN
           DBMS_PIPE.unpack_message(message1);
           DBMS_PIPE.unpack_message(message2);
           DBMS_PIPE.unpack_message(message3);
           DBMS_PIPE.unpack_message(message4);
    
           DBMS_OUTPUT.put_line('Order Received Successfully On: ' || TO_CHAR(sysdate, 'dd-mm-yyyy hh24:mi:ss'));
           DBMS_OUTPUT.put_line('Date of Order: ' || message1);
           DBMS_OUTPUT.put_line('Order Number: ' || message2);
           DBMS_OUTPUT.put_line('Number of Items In Order: ' || message3);
           DBMS_OUTPUT.put_line('Item Type in Order: ' || message4);
       END IF;
    
   END;
   /

   Consulte RECEIVE_MESSAGE Function para obtener más información.

Describe los pasos para eliminar un conducto persistente.

1. Llame a la función DBMS_PIPE.REMOVE_PIPE para eliminar un conducto.

   DECLARE
      l_result  INTEGER;
   BEGIN
        l_result := DBMS_PIPE.REMOVE_PIPE('ORDER_PIPE');
   END;
   /

   La función REMOVE_PIPE elimina el canal de la instancia de Autonomous Database en la que se ejecuta, pero REMOVE_PIPE no afecta a otras instancias de Autonomous Database con un canal con el mismo nombre que utiliza el mismo URI de ubicación.

2. En la instancia de Autonomous Database, si ha ejecutado DBMS_PIPE.REMOVE_PIPE, verifique que se ha eliminado el conducto.

   SELECT ownerid, name, type FROM v$db_pipes 
          WHERE name = 'ORDER_PIPE';
   

   No rows selected