Gestire il partizionamento automatico su Autonomous Database

Abilita e implementa suggerimenti

EXEC DBMS_AUTO_PARTITION.CONFIGURE('AUTO_PARTITION_MODE','IMPLEMENT');

Abilita i suggerimenti, ma non implementarli

EXEC DBMS_AUTO_PARTITION.CONFIGURE('AUTO_PARTITION_MODE','REPORT ONLY');

Disabilitare le nuove raccomandazioni e l'attuazione di tali nuove raccomandazioni

EXEC DBMS_AUTO_PARTITION.CONFIGURE('AUTO_PARTITION_MODE','OFF');

Gestire schemi e tabelle per il partizionamento automatico

• Se la lista di inclusione e la lista di esclusione sono vuote, aggiungere lo schema HR e la tabella SH.SALES alla lista di esclusione, impedendo solo a tali oggetti di eseguire l'analisi automatica del partizionamento.

  BEGIN
      DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_SCHEMA', 
           PARAMETER_VALUE => 'HR',
           ALLOW           => FALSE);
  
      DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_TABLE', 
           PARAMETER_VALUE => 'SH.SALES',
           ALLOW           => FALSE);
  END;
  /

• Dopo l'esecuzione dell'esempio precedente, utilizzare quanto segue per rimuovere lo schema HR dalla lista di esclusione.

  BEGIN
      DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_SCHEMA', 
           PARAMETER_VALUE => 'HR',
           ALLOW           => NULL);
  END;
  /

• Utilizzare il comando seguente per rimuovere tutti gli schemi dalla lista di esclusione.

  BEGIN
      DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_SCHEMA', 
           PARAMETER_VALUE => NULL,
           ALLOW           => TRUE);
  END;
  /

• Se le liste di inclusione ed esclusione sono vuote, l'esempio seguente aggiunge lo schema HR alla lista di inclusione. Non appena la lista di inclusione non è più vuota, vengono considerati solo gli schemi nella lista di inclusione.

  In questo esempio, solo lo schema HR è un candidato per il partizionamento automatico.

  BEGIN
      DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_SCHEMA', 
           PARAMETER_VALUE => 'HR',
           ALLOW           => TRUE);
  END;
  /

Gestisci periodo di conservazione report partizionamento automatico

Impostare il periodo di conservazione per i report di partizionamento automatico su 365 giorni.

BEGIN
    DBMS_AUTO_PARTITION.CONFIGURE(
         PARAMETER_NAME  => 'AUTO_PARTITION_REPORT_RETENTION', 
         PARAMETER_VALUE => '365');
END;
/

Generare un report, in formato testo normale, delle operazioni di partizionamento automatico per un periodo specifico

Questo esempio genera un report contenente informazioni tipiche sulle operazioni di partizionamento automatico nelle ultime 24 ore. Per impostazione predefinita, il report viene generato in formato testo normale.

DECLARE
  Report clob := NULL
BEGIN
    Report := DBMS_AUTO_PARTITION.REPORT_ACTIVITY();
END;
/

Generare un report, in formato HTML, delle operazioni di partizionamento automatico per MAGGIO 2021

Questo esempio genera un report contenente informazioni di base sulle operazioni di partizionamento automatico per il mese di MAGGIO 2021. Il report viene generato in formato HTML e include solo un riepilogo delle operazioni di partizionamento automatico.

DECLARE
  Report clob := NULL
BEGIN
    Report := DBMS_AUTO_PARTITION.REPORT_ACTIVITY(
                       ACTIVITY_START => TO_TIMESTAMP('2021-05-01', 'YYYY-MM-DD'),
                       ACTIVITY_END   => TO_TIMESTAMP('2021-06-01', 'YYYY-MM-DD'),
                       TYPE           => 'HTML',
                       SECTION        => 'SUMMARY',
                       LEVEL          => 'BASIC' );
END;
/

Generare un report, in formato testo normale, dell'ultima operazione di partizionamento automatico

Questo esempio genera un report contenente informazioni tipiche sull'ultima operazione di partizionamento automatico. Per impostazione predefinita, il report viene generato in formato testo normale.

DECLARE
  Report clob := NULL
BEGIN
    Report := DBMS_AUTO_PARTITION.REPORT_LAST_ACTIVITY();
END;
/

Per ulteriori informazioni, vedere REPORT_ACTIVITY Function.

Per ulteriori informazioni, vedere REPORT_LAST_ACTIVITY Function.

Generare un suggerimento per una singola tabella e applicare manualmente il suggerimento

1. Impostare il parametro AUTO_PARTITION_MODE su REPORT ONLY per abilitare l'esecuzione e la verifica di un suggerimento di partizionamento automatico. Il suggerimento non viene applicato alla tabella.

   BEGIN
       DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_MODE', 
           PARAMETER_VALUE => 'REPORT ONLY');
   END;
   /

2. Verificare che la tabella TPCH.LINEITEM sia idonea per il partizionamento automatico. Questa operazione è facoltativa e consigliata quando si mirano in modo selettivo a singole tabelle.

   SELECT DBMS_AUTO_PARTITION.VALIDATE_CANDIDATE_TABLE(
              TABLE_OWNER => 'TPCH',
              TABLE_NAME  => 'LINEITEM')
   FROM DUAL;

   Se la tabella è un candidato valido, quando si richiama il partizionamento automatico per un'analisi dei suggerimenti, viene restituito come VALID. In caso contrario, vengono visualizzati i criteri di violazione.

   Per un elenco dei criteri per le tabelle dei candidati idonei, vedere VALIDATE_CANDIDATE_TABLE Function.

3. Richiamare l'API DBMS_AUTO_PARTITION per generare un suggerimento per la tabella TPCH.LINEITEM.

   -- DEFINE SQLPLUS BIND VARIABLE FOR RECOMMENDATION ID
   VARIABLE RECOMMENDATION_ID VARCHAR2(32);
   BEGIN
     :RECOMMENDATION_ID := DBMS_AUTO_PARTITION.RECOMMEND_PARTITION_METHOD(
                                TABLE_OWNER => 'TPCH',
                                TABLE_NAME  => 'LINEITEM');
   END;
   /

   L'analisi e la verifica dei suggerimenti eseguite con DBMS_AUTO_PARTITION.RECOMMEND_PARTITION_METHOD possono essere operazioni a uso intensivo di risorse e con tempi di esecuzione lunghi e richiedere molto tempo. Eseguire questa operazione su un database che non è il sistema di produzione principale. Oracle consiglia di fornire all'operazione di verifica risorse sufficienti scegliendo il servizio HIGH.

4. Controllare il suggerimento. La vista DBA_AUTO_PARTITION_RECOMMENDATIONS contiene le informazioni sul suggerimento. In questo esempio, controllare la chiave di partizione e il metodo di partizione consigliati.

   SELECT PARTITION_METHOD, PARTITION_KEY
     FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
     WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID;
   

   Inoltre, eseguire una query sulla stessa vista per ottenere il report di analisi delle prestazioni generato per il carico di lavoro dopo che la tabella è stata partizionata in base ai suggerimenti.

   SELECT REPORT
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID;
   

5. Dopo la convalida manuale del suggerimento, applicare il suggerimento. Se si applica il suggerimento nel database in cui è stata eseguita l'analisi dei suggerimenti, applicare il suggerimento eseguendo la procedura APPLY_RECOMMENDATION.

   BEGIN
       DBMS_AUTO_PARTITION.APPLY_RECOMMENDATION(
            RECOMMENDATION_ID => :RECOMMENDATION_ID);
   END;
   /

   Se si desidera applicare il suggerimento a un database diverso, ad esempio l'ambiente di produzione, estrarre il DDL di modifica. Quindi, eseguire il DDL di modifica estratto nel database di destinazione. La query per estrarre la DDL di modifica è la seguente:

   SELECT MODIFY_TABLE_DDL
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID;
   

   Esempio di output di modifica DDL:

   BEGIN
       -- DBMS_AUTO_PARTITION RECOMMENDATION_ID C3F7A59E085C2F25E05333885A0A55EA
       --   FOR TABLE "TPCH"."LINEITEM"
       --   GENERATED AT 06/04/2021 20:52:29
       DBMS_AUTO_PARTITION.BEGIN_APPLY(EXPECTED_NUMBER_OF_PARTITIONS => 10);
   
       EXECUTE IMMEDIATE
       'ALTER TABLE "TPCH"."LINEITEM"
       MODIFY PARTITION BYLIST(SYS_OP_INTERVAL_HIGH_BOUND
           ("L_SHIPDATE", INTERVAL ''10'' MONTH, TIMESTAMP ''1992-01-01 00:00:00''))
       AUTOMATIC /* SCORE=23533.11;  */
       (PARTITION P_NULL VALUES(NULL))
       AUTO ONLINE PARALLEL';
   
       DBMS_AUTO_PARTITION.END_APPLY;
   EXCEPTION WHEN OTHERS THEN
       DBMS_AUTO_PARTITION.END_APPLY;
       RAISE;
   END;
   

6. Verificare che la tabella sia stata partizionata automaticamente, eseguire una query sulle viste catalogo.

   SELECT T.AUTO, T.PARTITIONING_TYPE, C.COLUMN_NAME
       FROM DBA_PART_TABLES T, DBA_PART_KEY_COLUMNS C
       WHERE T.OWNER = 'TPCH' AND T.TABLE_NAME = 'LINEITEM'
           AND T.OWNER = C.OWNER AND T.TABLE_NAME = C.NAME;
   

   Utilizzare questa query per identificare quando il partizionamento automatico è stato applicato a una determinata tabella.

   SELECT APPLY_TIMESTAMP_START, APPLY_TIMESTAMP_END
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE TABLE_OWNER = 'TPCH' AND TABLE_NAME = 'LINEITEM';
   

Per informazioni, vedere Procedura CONFIGURA.

Per informazioni, vedere VALIDATE_CANDIDATE_TABLE Function.

Per informazioni, vedere RECOMMEND_PARTITION_METHOD Function.

Per informazioni, vedere APPLY_RECOMMENDATION Procedure.

Generare un suggerimento per le tabelle idonee e applicare manualmente il suggerimento

1. Impostare il parametro AUTO_PARTITION_MODE su REPORT ONLY per abilitare l'esecuzione e la verifica di un suggerimento di partizionamento automatico. Il suggerimento non viene applicato alle tabelle esistenti.

   BEGIN
       DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_MODE', 
           PARAMETER_VALUE => 'REPORT ONLY');
   END;
   /

2. Richiamare l'API DBMS_AUTO_PARTITION per generare una tabella di suggerimenti.

   -- DEFINE SQLPLUS BIND VARIABLE FOR RECOMMENDATION ID
   VARIABLE RECOMMENDATION_ID VARCHAR2(32);
   BEGIN
     :RECOMMENDATION_ID := DBMS_AUTO_PARTITION.RECOMMEND_PARTITION_METHOD();
   END;
   /

   L'analisi e la verifica dei suggerimenti sono operazioni ad alta intensità di risorse e a lungo termine e potrebbero richiedere molto tempo. Nei database secondari non di produzione, Oracle consiglia di fornire alla verifica risorse sufficienti scegliendo il servizio HIGH.

3. Eseguire una query sulla vista DBA_AUTO_PARTITION_RECOMMENDATIONS per vedere quali tabelle sono state analizzate.

   SELECT TABLE_OWNER, TABLE_NAME, PARTITION_METHOD, PARTITION_KEY
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID
       ORDER BY RECOMMENDATION_SEQ;
   

4. Utilizzare questa query per eseguire il drill-down nel report di una tabella specifica analizzata nell'esecuzione, ovvero la tabella TPCH.LINEITEM in questo esempio.

   SELECT REPORT
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID
           AND TABLE_OWNER = 'TPCH'
           AND TABLE_NAME  = 'LINEITEM';
   

5. Applicare il suggerimento eseguendo la procedura APPLY_RECOMMENDATION.

   BEGIN
       DBMS_AUTO_PARTITION.APPLY_RECOMMENDATION(
            RECOMMENDATION_ID => :RECOMMENDATION_ID);
   END;
   /

   In alternativa, applicare i suggerimenti per una tabella specifica analizzata, la tabella TPCH.LINEITEM in questo esempio.

   BEGIN
       DBMS_AUTO_PARTITION.APPLY_RECOMMENDATION(
           RECOMMENDATION_ID => :RECOMMENDATION_ID,
           TABLE_OWNER       => 'TPCH',
           TABLE_NAME        => 'LINEITEM');
   END;
   /

Per informazioni, vedere Procedura CONFIGURA.

Per informazioni, vedere RECOMMEND_PARTITION_METHOD Function.

Per informazioni, vedere APPLY_RECOMMENDATION Procedure.

Genera e applica automaticamente i suggerimenti per le tabelle idonee

1. Impostare il parametro AUTO_PARTITION_MODE su REPORT ONLY per abilitare l'esecuzione e la verifica di un suggerimento di partizionamento automatico. Il suggerimento non viene applicato alle tabelle esistenti.

   BEGIN
       DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_MODE', 
           PARAMETER_VALUE => 'IMPLEMENT');
   END;
   /

2. Richiamare l'API DBMS_AUTO_PARTITION per generare una tabella di suggerimenti.

   -- DEFINE SQLPLUS BIND VARIABLE FOR RECOMMENDATION ID
   VARIABLE RECOMMENDATION_ID VARCHAR2(32);
   BEGIN
     :RECOMMENDATION_ID := DBMS_AUTO_PARTITION.RECOMMEND_PARTITION_METHOD();
   END;
   /

   L'analisi e la verifica dei suggerimenti sono operazioni ad alta intensità di risorse e a lungo termine e potrebbero richiedere molto tempo. Nei database secondari non di produzione, Oracle consiglia di fornire alla verifica risorse sufficienti scegliendo il servizio HIGH.

3. Eseguire una query sulla vista DBA_AUTO_PARTITION_RECOMMENDATIONS per vedere quali tabelle sono state analizzate.

   SELECT TABLE_OWNER, TABLE_NAME, PARTITION_METHOD, PARTITION_KEY
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID
       ORDER BY RECOMMENDATION_SEQ;
   

4. Utilizzare la funzione REPORT_LAST_ACTIVITY per recuperare il report sulle azioni eseguite durante l'ultima esecuzione.

   SELECT DBMS_AUTO_PARTITION.REPORT_LAST_ACTIVITY() FROM DUAL;
   

Per informazioni, vedere Procedura CONFIGURA.

Per informazioni, vedere RECOMMEND_PARTITION_METHOD Function.

Per informazioni, vedere REPORT_LAST_ACTIVITY Function.