Oracle Cloud Infrastructureドキュメント

DBMS_CLOUD_NOTIFICATIONパッケージ

DBMS_CLOUD_NOTIFICATIONパッケージを使用すると、メッセージまたはSQL問合せの出力をプロバイダに送信できます。

DBMS_CLOUD_NOTIFICATION概要

DBMS_CLOUD_NOTIFICATIONパッケージについて説明します。

DBMS_CLOUD_NOTIFICATIONでサポートされるプロバイダは、電子メール、Microsoft Teams、OCI通知(ONS)およびSlackです。

DBMS_CLOUD_NOTIFICATIONパッケージでOCI通知サービスを使用する場合、DBMS_CLOUD_NOTIFICATION.SEND_MESSAGEプロシージャのみがサポートされます(DBMS_CLOUD_NOTIFICATION.SEND_DATAプロシージャはサポートされていません)。

DBMS_CLOUD_NOTIFICATIONサブプログラムの要約

この表は、パッケージに含まれるサブプログラムの概要を示しています。

サブプログラム 摘要
SEND_DATAプロシージャ SQL問合せ出力をプロバイダに送信します。
SEND_MESSAGEプロシージャ テキスト・メッセージをプロバイダに送信する。

SEND_DATAプロシージャ

SEND_DATAプロシージャは、指定された問合せの結果をプロバイダに送信します。

構文

DBMS_CLOUD_NOTIFICATION.SEND_DATA(
       provider           IN  VARCHAR2,
       credential_name    IN  VARCHAR2,
       query              IN  CLOB,
       params             IN  CLOB
 );

パラメータ

パラメータ 摘要
provider

プロバイダを指定します。

有効な値は、email、msteamsおよびslackです。

このパラメータは必須です。
credential_name

プロバイダにアクセスする資格証明オブジェクトの名前。

Eメール・プロバイダの場合、資格証明は、ユーザー名およびパスワードを含むSMTP承認済送信者の資格証明の名前です。

msteamsプロバイダの場合、資格証明は資格証明の名前です。

Slackプロバイダの場合、資格証明のユーザー名は"SLACK_TOKEN"で、passwordはSlackボット・トークンである必要があります。

このパラメータは必須です。
query

実行するSQL問合せを指定します。結果がプロバイダに送信されます。

このパラメータは必須です。
params

providerの特定のパラメータをJSON形式で指定します。

プロバイダ・タイプemailの場合、有効なパラメータは次のとおりです。

  • sender. 承認済送信者のEメールIDをString値で指定します。
  • smtp_host. これは、SMTPホスト名をString値で指定します。
  • subject. これは、電子メールの件名をString値で指定します。最大サイズは100文字です。
  • recipient. これは、受信者の電子メールIDをString値で指定します。複数の受信者がいる場合は、電子メールIDの間にコンマを使用します。
  • to_cc. 電子メールのCCを受信する電子メールIDを指定します。String値です。複数のCC受信者がいる場合は、電子メールIDの間にカンマを使用します。
  • to_bcc. EメールのBCCを受信するEメールIDを指定します。String値です。複数のBCC受信者がいる場合は、電子メールIDの間にカンマを使用します。
  • message. これは、メッセージ・テキストをString値で指定します。
  • type. これは、String値の出力形式をCSVまたはJSONとして指定します。
  • title. これは、SQL出力の添付のタイトルをString値で指定します。タイトルには、ファイル名の生成に使用されるため、文字、数字、アンダースコア、ハイフンまたはドットのみを値に含める必要があります。

プロバイダ・タイプmsteamsの場合、有効なパラメータは次のとおりです。

  • tenant. これは、String形式でテナントIDを指定します。
  • team. これは、チームIDをString形式で指定します。
  • channel. これは、チャネルIDをString形式で指定します。
  • title. ファイルのタイトルをString形式で指定します。最大サイズは50文字です。
  • type. これは、出力形式をString値で指定します。有効な値はCSVまたはJSONです。

プロバイダ・タイプslackの場合、有効なパラメータは次のとおりです。

  • channel. これにより、チャネルIDがString値で指定されます。チャネルIDはチャネルの一意のIDであり、チャネル名とは異なります。Slackでは、チャネルの詳細を表示すると、「バージョン情報」タブでチャネルIDを確認できます。
  • type. これは、出力形式をString値で指定します。有効な値はCSVまたはJSONです。

このパラメータは必須です。

使用上のノート

  • 資格証明オブジェクトを作成するには、プロシージャDBMS_CLOUD.CREATE_CREDENTIAL(credential_name、usernameおよびpassword)を使用します。

    詳細は、「CREATE_CREDENTIALプロシージャ」を参照してください。

  • emailプロバイダの場合、次の点に注意してください。

    • ユーザーがsmtp_hostを取得するには、Email DeliveryサーバーのSMTP接続エンドポイントが必要です。ユーザーは、credential_nameを取得するためにEmail Deliveryサーバーで認証するために、SMTP承認済送信者およびその資格証明も必要です。SMTP接続を構成し、SMTP資格証明を生成して承認する必要があります。

    • emailプロバイダでDBMS_CLOUD_NOTIFICATION.SEND_DATAを使用するときにサポートされる最大メッセージ・サイズは32KBです。

    • DBMS_CLOUD_NOTIFICATIONは、Autonomous AI Databaseバージョン19.21以上のメール通知にのみ使用できます。

  • msteamsプロバイダの場合、ユーザーはMicrosoft Teamsアプリケーションとそれで構成されたボットを必要とします。アプリケーションは、管理センターから管理者から承認を取得した後に、組織に公開してインストールする必要があります。また、ユーザーは、Azure PortalからGraph APIのFiles.ReadWrite.AllおよびChannelSettings.Read.All権限にアクセスする必要があります。必要なトークンを生成するには、ユーザー名にbot_id、パスワードにbot_secretが必要です。

    Microsoft TeamsにDBMS_CLOUD_NOTIFICATION.SEND_DATAを使用するときにサポートされる最大ファイル・サイズは4MBです。

  • slackプロバイダの場合、username値は任意の有効な文字列にでき、passwordはSlackボット・トークンです。

例

emailプロバイダを使用してSQL出力を送信します。

BEGIN
    DBMS_CLOUD.CREATE_CREDENTIAL(
    credential_name => 'EMAIL_CRED',
    username        => 'username',
    password        => 'password');
END;
/

BEGIN
   DBMS_CLOUD_NOTIFICATION.SEND_DATA(
        provider        => 'email',
        credential_name => 'EMAIL_CRED',
        query           => 'SELECT tablespace_name FROM dba_tablespaces',
        params          => json_object('recipient' value  'mark@oracle.com, suresh@oracle.com',
                                       'to_cc'  value 'nicole@oracle.com1, jordan@oracle.com',
                                       'to_bcc' value 'manisha@oracle.com',
                                       'subject' value 'Test subject',
                                       'type' value 'json',
                                       'title' value 'mytitle',
                                       'message' value 'This is the message',
                                       'smtp_host' value 'smtp.email.example.com',
                                       'sender'    value  'approver_sender@oracle.com' )
   );
   END;
/

msteamsプロバイダを使用してSQL出力を送信します。

BEGIN
    DBMS_CLOUD.CREATE_CREDENTIAL(credential_name => 'TEAMS_CRED',
        username        => 'bot_id',
        password        => 'bot_secret');
END;
/

BEGIN
     DBMS_CLOUD_NOTIFICATION.SEND_DATA(provider => 'msteams',
        credential_name => 'TEAMS_CRED',
        query           => 'SELECT tablespace_name FROM dba_tablespaces',
        params          => json_object('tenant'value '5b743bc******c0286',
                                       'team'value '0ae401*********5d2bd',
                                       'channel'value '19%3a94be023*****%40thread.tacv2',
                                       'title'value 'today',
                                       'type'value 'csv'));
END;
/

slackプロバイダを使用してSQL出力を送信します。

BEGIN
   DBMS_CLOUD.CREATE_CREDENTIAL(
     credential_name => 'SLACK_CRED',
     username        => 'SLACK_TOKEN',
     password        => 'password');
END;
/
BEGIN
  DBMS_CLOUD_NOTIFICATION.SEND_DATA(
      provider        => 'slack',
      credential_name => 'SLACK_CRED',
      query           => 'SELECT username, account_status, expiry_date FROM USER_USERS WHERE rownum < 5',
      params          => json_object('channel' value 'C0....08','type' value 'csv'));
END;
/

SEND_MESSAGEプロシージャ

プロシージャは、プロバイダにテキスト・メッセージを送信します。

構文

DBMS_CLOUD_NOTIFICATION.SEND_MESSAGE(
       provider           IN  VARCHAR2,
       credential_name    IN  VARCHAR2,
       message            IN  CLOB,
       params             IN  CLOB
 );

パラメータ

パラメータ 摘要
provider

プロバイダを指定します。

有効な値は、email、msteams、slackおよびociです。

このパラメータは必須です。
credential_name

プロバイダにアクセスする資格証明オブジェクトの名前。

  • emailプロバイダ: 資格証明は、ユーザー名およびパスワードを含むSMTP承認済送信者の資格証明の名前です。

  • msteamsプロバイダ: 資格証明には、usernameとpasswordの両方にbot_idおよびbot_secretキーが含まれている必要があります。

  • slackプロバイダ: 資格証明のusernameは"SLACK_TOKEN"で、passwordはSlackボット・トークンである必要があります。

  • ociプロバイダ: 資格証明は、有効なOracle Cloud Infrastructure署名キー・ベースの資格証明またはリソース・プリンシパル資格証明のいずれかです。

このパラメータは必須です。

資格証明オブジェクトを作成するには、プロシージャDBMS_CLOUD.CREATE_CREDENTIALを使用します。詳細は、「CREATE_CREDENTIALプロシージャ」を参照してください。

message

メッセージ・テキストを指定します。

このパラメータは必須です。
params

providerの特定のパラメータをJSON形式で指定します。

プロバイダ・タイプemailの場合、有効なパラメータは次のとおりです。

  • sender: 承認済送信者のEメールIDをString値で指定します。
  • smtp_host: SMTPホスト名をString値で指定します。
  • subject: 電子メールのサブジェクトをString値で指定します。最大サイズは100文字です。
  • recipient: 受信者の電子メールIDをString値で指定します。複数の受信者がいる場合は、電子メールIDの間にコンマを使用します。
  • to_cc: EメールのCCを受信するEメールIDを指定します。複数のCC受信者がいる場合は、電子メールIDの間にカンマを使用します。
  • to_bcc: EメールのBCCを受信するEメールIDを指定します。複数のBCC受信者がいる場合は、電子メールIDの間にカンマを使用します。

プロバイダ・タイプmsteamsの場合、有効なパラメータは次のとおりです。

  • channel: チャネルIDをString値で指定します。

プロバイダ・タイプslackの場合、有効なパラメータは次のとおりです。

  • channel. String値でチャネルIDを指定します。このパラメータは必須です。チャネルIDはチャネルの一意のIDであり、チャネル名とは異なります。Slackでは、チャネルの詳細を表示すると、「バージョン情報」タブでチャネルIDを確認できます。

タイプがociのプロバイダOCI通知の場合、有効なパラメータは次のとおりです:

  • topic_ocid: OCI通知トピックのOCIDを指定します。
  • title: メッセージの件名の行を指定します。

ociプロバイダでは、サブスクリプションに基づいて、メッセージに対して使用可能なエンドポイントが異なります。titleパラメータは、サブスクリプションごとに異なる方法で処理されます。

  • email: titleは、メッセージの件名を指定します。
  • Slack: title値は使用されません。含まれる場合、値は無視されます。

Eメール・プロバイダの使用上のノート

emailプロバイダの場合、smtp_hostを取得するには、Email DeliveryサーバーのSMTP接続エンドポイントが必要です。ユーザーは、credential_nameを取得するためにEmail Deliveryサーバーで認証するために、SMTP承認済送信者およびその資格証明も必要です。SMTP接続を構成し、SMTP資格証明を生成して承認する必要があります。

Msteamsプロバイダの使用上の注意

msteamsプロバイダの場合、ユーザーはMicrosoft Teamsアプリケーションとそれで構成されたボットを必要とします。アプリケーションは、管理センターから管理者から承認を取得した後に、組織に公開してインストールする必要があります。また、ユーザーは、Azure PortalからGraph APIのFiles.ReadWrite.AllおよびChannelSettings.Read.All権限にアクセスする必要があります。必要なトークンを生成するには、ユーザー名にbot_id、パスワードにbot_secretが必要です。

Slackプロバイダの使用上のノート

slackプロバイダの場合、username値は任意の有効な文字列にでき、passwordはSlackボット・トークンです。

OCIプロバイダOCI通知の使用上のノート

DBMS_CLOUD_NOTIFICATIONは、OCI通知プロバイダをサポートしています。OCI通知プロバイダの詳細は、通知の概要を参照してください。

  • OCI通知プロバイダを使用するには、次を実行する必要があります。

    • トピックの作成トピックの作成の詳細は、トピックの作成を参照してください

    • 必要なサブスクリプションを作成します。サブスクリプションの作成の詳細は、サブスクリプションの作成を参照してください

    • サブスクリプションを作成したら、サブスクリプションを確認します。メッセージは、確認済のサブスクリプションにのみ公開されます。サブスクリプションの確認の詳細は、サブスクリプションの確認を参照してください。

  • 自律型AIデータベース・インスタンス、資格証明(ユーザー資格証明を使用している場合)およびサブスクリプション・トピックはすべて同じリージョンに配置する必要があります。

  • 次の制限があるので注意してください。

    • Message Size Limit(メッセージ・サイズ制限): リクエスト当たりのメッセージ・サイズ制限は64KBです。このサイズを超えるメッセージは、単一のリクエスト内で送信または処理できません。

    • Message Delivery Rate Limit(メッセージ配信率制限): 使用するプロトコルに応じて、異なるメッセージ配信率制限があります。

      • emailプロトコル: 制限はエンドポイント当たり10メッセージ/分です。

      この制限は、メッセージの送信および受信速度に影響を与える可能性があります。

    • Transactions Per Minute (TPM) per-Tenancy Limit (テナンシ当たりのトランザクション数制限): この操作には、トピックごとに60のTPM制限があります。この制限は、特定のトピックに対して処理または処理できる1分当たりのメッセージの最大数を表します。この制限を超えると、メッセージの処理または処理速度が遅くなる可能性があります。

例

emailプロバイダを使用してテキスト・メッセージを送信します。

BEGIN
    DBMS_CLOUD.CREATE_CREDENTIAL(
    credential_name => 'EMAIL_CRED',
    username        => 'username',
    password        => 'password');
END;
/

BEGIN
   DBMS_CLOUD_NOTIFICATION.SEND_MESSAGE(
        provider        => 'email',
        credential_name => 'EMAIL_CRED',
        message         => 'Subject content',
        params          => json_object('recipient' value  'mark@oracle.com, suresh@oracle.com',
                                       'to_cc'  value 'nicole@oracle.com, jordan@oracle.com',
                                       'to_bcc' value 'manisha@oracle.com',
                                       'subject' value 'Test subject',
                                       'smtp_host' value 'smtp.email.example.com',
                                       'sender'    value  'approver_sender@oracle.com' )
   );
   END;
/

msteamsプロバイダを使用してテキスト・メッセージを送信します。

BEGIN
    DBMS_CLOUD.CREATE_CREDENTIAL(credential_name => 'TEAMS_CRED',
        username        => 'bot_id',
        password        => 'bot_secret');
END;
/

BEGIN
     DBMS_CLOUD_NOTIFICATION.SEND_MESSAGE(
        provider        => 'msteams',
        credential_name => 'TEAMS_CRED',
        message         => 'text from new teams api',
        params          => json_object('channel'value 'C0....08'),'region'value 'india');
END;
/

slackプロバイダを使用してテキスト・メッセージを送信します。

BEGIN
   DBMS_CLOUD.CREATE_CREDENTIAL(
     credential_name => 'SLACK_CRED',
     username        => 'SLACK_TOKEN',
     password        => 'password');
END;
/
BEGIN
   DBMS_CLOUD_NOTIFICATION.SEND_MESSAGE(
      provider          => 'slack',
      credential_name   => 'SLACK_CRED',
      message           => 'Send text from Autonomous AI Database.',
      params            => json_object('channel' value 'C0....08'));
END;
/

OCI通知を使用してテキスト・メッセージを送信し、ociプロバイダを入力します:

BEGIN
   DBMS_CLOUD_NOTIFICATION.SEND_MESSAGE(
      provider          => 'oci',
      credential_name  => 'OCI_CRED',
      message          => 'Text message for you.',
      params           => json_object('topic_ocid'  value 'oci********pa',
      'title'  value 'Title for message subject' ));
END;
/
BEGIN
   DBMS_CLOUD_NOTIFICATION.SEND_MESSAGE(
      provider          => 'oci',
      credential_name  => 'OCI$RESOURCE_PRINCIPAL',
      message          => 'Text message for you.',
      params           => json_object('topic_ocid'  value 'oci********pa',
      'title'  value 'Title for message subject' ));
END;
/