5 Reading Ticket Templates

When the Enterprise Manager connector creates an incident service request record, a data transformation occurs that maps the attributes of the Alert in Enterprise Manager with the attributes of a Service Request on the HelpDesk system. The trouble ticket template and response files specify this mapping. The logical mapping is summarized in Table 5–1. This table will help you to read the Siebel Ticket Template (SiebelHelpdeskTemplate.xsl).

Table 5-1 Service Request Payload and Enterprise Manager Event Mapping

Service Request Attributes Enterprise Manager Event Attributes Data Type Default Value for Create Default Value for Update

Id

  

DTYPE_ID

  

N/A

SR Number

  

DTYPE_TEXT

  

N/A

Status

(SR_STAT_ID)

  

DTYPE_TEXT

Open/Closed

  • Open if EM's Severity = Clear.

  • Closed if EM's Severity = Clear

SR Type

(SR_CAT_TYPE_CD)

  

DTYPE_TEXT

Internal

N/A

Service Request Type

  

DTYPE_TEXT

Internal

N/A

Severity

(SR_SEV_CD)

Severity

Helpdesk:

  • 1—Critical

  • 2—High

  • 3—Medium

Enterprise Manager:

  • Critical

  • Warning

  • Down

DTYPE_TEXT

    

Abstract

Message. For example, CPU utilization increases from 50% to 95%.

DTYPE_TEXT

  

N/A

Area

(SR_AREA)

  

DTYPE_TEXT

IT

N/A

Description

  • TargetType: Type of target that this event is associated with. For example, host or database.

  • TargetName: Name of the target that this event is associated with. For example, DB1 or stadc40.us.oracle.com.

  • TargetHost: Name of the host of the target that the event/alert was generated by.

  • TargetAgent: Name of the server hosting the agent that monitors the generated event.

  • MetricColumn: Name of the metric column as it appears on Enterprise Manager Grid Control.

  • MetricName: Name of the metric. For example, CPU utilization or memory usage.

  • KeyValues: Values associated with a key value base event.

  • CollectionTime: Time at which the event occurred.

  • NotificationRuleName: Name of the notification rule that generated the notification during auto-ticketing.

  • Event Page URL: URL for event details page.

DTYPE_TEXT

  

N/A

Siebel Ticket Template (SiebelHelpdeskTemplate.xsl)

<?xml version='1.0' encoding='UTF-8'?>
<xsl:transform version="1.0" 
       xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
       xmlns:ns0="http://xmlns.oracle.com/sysman/connector/tt"
       targetNamespace="http://xmlns.oracle.com/sysman/connector/tt"
       xmlns:ser="http://siebel.com/Service/ServiceReqEMHelpDesk" 
       xmlns:data="http://www.siebel.com/xml/ServiceReqIO/Data"
       elementFormDefault="qualified">
 
  <!-- 
  This template creates an incident type ticket with default categorization
  (Category: Default, Type:Default, Item:Default), and high priority. On update,
  the description and message fields are updated. 
  -->
   <xsl:template match="ns0:EventModel">
    <xsl:choose>
      <xsl:when test="normalize-space(ns0:TicketId) = ''">
        <!-- EDIT THE TAG VALUES BELOW TO CHANGE HOW A TICKET IS FILLED
             DURING TICKET CREATION. REFER TO THE MANUAL
             FOR DESCRIPTION OF THESE HELPDESK SUPPORT DATAFIELDS--> 
        <ser:ServiceReqEMHelpDeskInsertAndQuery_Input xmlns:data="http://www.siebel.com/xml/ServiceReqIO/Data">
          <data:ListOfServicereqio>
            <!--Zero or more repetitions:-->
            <data:ServiceRequest operation="?">
              <data:Abstract><xsl:value-of select="ns0:Message"/></data:Abstract>
              <data:Status>Open</data:Status>
              <data:ServiceRequestType>Internal</data:ServiceRequestType>
              <xsl:choose>
                <xsl:when test="normalize-space(ns0:Severity) = 'Critical'">
                  <data:Severity>1-Critical</data:Severity>                  
                </xsl:when>
                <xsl:when test="normalize-space(ns0:Severity) = 'Down'">
                  <data:Severity>2-High</data:Severity>              
                </xsl:when>
                <xsl:when test="normalize-space(ns0:Severity) = 'Warning'">
                  <data:Severity>3-Medium</data:Severity>                 
                </xsl:when>
                <xsl:otherwise>
                  <data:Severity>5-Question</data:Severity>               
                </xsl:otherwise>
              </xsl:choose>         
              <data:Area>IT</data:Area>
              <data:Description>
Ticket created by EM Siebel Connector.
Event Information:
---------------------------------------

Target Type: <xsl:value-of select="ns0:TargetType"/>
Target Name: <xsl:value-of select="ns0:TargetName"/>
Target Host: <xsl:value-of select="ns0:TargetHost"/>
Target Agent: <xsl:value-of select="ns0:TargetAgent"/>
Metric Column: <xsl:value-of select="ns0:MetricColumn"/>
Metric Name: <xsl:value-of select="ns0:MetricName"/>
                <xsl:choose>
                  <xsl:when test="normalize-space(ns0:KeyColumn) != ''">
Key Column: <xsl:value-of select="ns0:KeyColumn"/>
Key Values: <xsl:value-of select="ns0:KeyValues"/>
                  </xsl:when>
                </xsl:choose>
Collection Time: <xsl:value-of select="ns0:CollectionTime"/>
                <xsl:choose>
                  <xsl:when test="normalize-space(ns0:NotificationRuleName) != ''">
Notification Rule: <xsl:value-of select="ns0:NotificationRuleName"/>
                  </xsl:when>
                </xsl:choose>
Event Page URL: <xsl:value-of select="ns0:EventPageURL"/>
--------------------------------------
              </data:Description>
            </data:ServiceRequest>
          </data:ListOfServicereqio>
          <ser:LOVLanguageMode>LIC</ser:LOVLanguageMode>
          <!--Optional:-->
          <ser:ViewMode>All</ser:ViewMode>
        </ser:ServiceReqEMHelpDeskInsertAndQuery_Input>
      </xsl:when>
      <xsl:otherwise>
        <!-- EDIT THE TAG VALUES BELOW TO CHANGE HOW A TICKET IS FILLED
             DURING TICKET UPDATE. REFER TO THE MANUAL
             FOR DESCRIPTION OF THESE HELPDESK SUPPORT DATAFIELDS--> 
        <ser:ServiceReqEMHelpDeskQueryAndUpdate_Input xmlns:data="http://www.siebel.com/xml/ServiceReqIO/Data">
          <data:ListOfServicereqio>
            <!--Zero or more repetitions:-->
            <data:ServiceRequest operation="?">
            <data:SRNumber><xsl:value-of select="ns0:TicketId"/></data:SRNumber>
              <xsl:choose>
                <xsl:when test="normalize-space(ns0:Severity) = 'Critical'">
                  <data:Severity>1-Critical</data:Severity>                  
                  <data:Status>Open</data:Status>
                </xsl:when>
                <xsl:when test="normalize-space(ns0:Severity) = 'Down'">
                  <data:Severity>2-High</data:Severity>              
                  <data:Status>Open</data:Status>
                </xsl:when>
                <xsl:when test="normalize-space(ns0:Severity) = 'Warning'">
                  <data:Severity>3-Medium</data:Severity>                 
                  <data:Status>Open</data:Status>
                </xsl:when>
                <xsl:when test="normalize-space(ns0:Severity) = 'Clear'">
                  <data:Status>Closed</data:Status>
                </xsl:when>
                <xsl:otherwise>
                  <data:Severity>5-Question</data:Severity>               
                  <data:Status>Open</data:Status>
                </xsl:otherwise>
              </xsl:choose>         
            </data:ServiceRequest>
          </data:ListOfServicereqio>
          <ser:LOVLanguageMode>LIC</ser:LOVLanguageMode>
          <!--Optional:-->
          <ser:ViewMode>All</ser:ViewMode>
        </ser:ServiceReqEMHelpDeskQueryAndUpdate_Input>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
</xsl:transform>