Download de Logs de Acesso a Partir de um Ambiente

Use o script nesta seção para automatizar o processo de download dos logs de acesso de um ambiente para um computador local.

1. Crie um arquivo de lote (.BAT) chamado syncAccessLog.bat contendo o script a seguir e salve-o em um local conveniente, como, por exemplo, C:\automate_scripts.

   Nota:

   Se sua senha contiver caracteres especiais, consulte Caracteres Especiais.

   @echo off
   title APR
   setlocal DisableDelayedExpansion
   
   REM To hardcode the values in the script replace %1, %2, %3, and %4 with the actual values.
   REM Example:
   REM set apr_dir="C:\Oracle\apr"
   REM set username="serviceAdmin"
   REM set password="C:\mySecuredir\password.epw"
   REM set url="https://test-cloudpln.pbcs.us1.oraclecloud.com"
   set apr_dir=%1
   set username=%2
   set password=%3
   set url=%4
   
   setlocal EnableDelayedExpansion
   set epmautomate_dir=%cd%
   set lastfile=
   REM if [%1]==[] goto :usage
   REM if [%2]==[] goto :usage
   REM if [%3]==[] goto :usage
   
   set argC=0
   for %%x in (%*) do Set /A argC+=1
   if %argC% neq 0 (
     if %argC% neq 3 (
       if %argC% neq 4 (
         goto :usage
         )
     )
   )
   goto :login
   
   :usage
   echo.
   echo Invalid syntax. Please check the parameters.
   echo Syntax:
   echo 1) syncAccessLog.bat APR_FolderPath_on_client username password url
   echo     or 
   echo 2) set the parameters in the file and use below syntax
   echo syncAccessLog.bat
   goto :end
   
   :login
   setlocal DisableDelayedExpansion
   REM for /f "delims=" %%i in ('epmautomate login %2 %3 %4') do set result=%%i
   for /f "delims=" %%i in ('epmautomate login %username% %password% %url%') do set result=%%i
   
   if not exist %apr_dir% (
   echo.
   echo apr folder does not exist 
   GOTO :end
   )
   cd /D %apr_dir%
   for /f "delims=" %%D in ('dir /a:d /b /o:-n') do ( 
   REM AFTER: for /f "delims=" %%D in ('dir /a-d /b /s /o:-n') do (
     set "lastFile=%%~nD"
     goto :next
   )
   
   :next
   setlocal EnableDelayedExpansion
   echo.
   echo Most Recent Access Log on client is %lastFile%
   
   set "output_cnt=0"
   cd /D %epmautomate_dir%
   for /F "delims=" %%f in ('epmautomate listfiles') do (
   
     cd /D !apr_dir!
     set "line=%%f"
     for /f "tokens=* delims= " %%a in ("!line!") do set line=%%a
     if "!line:~0,3!" equ "apr" (
       if "!line:~-4!" equ ".zip" (
         if "%lastFile%" lss "!line:~4,19!" (
             if "!line:~4,19!" neq "!dirname!" (
               set apr_dir=!apr_dir:"=!
               set /a output_cnt+=1
               set "output[!output_cnt!]=!apr_dir!\!line:~4,19!"
               set "dirname=!line:~4,19!"
               
               REM start downloading
               mkdir "!dirname!"
               cd /D !dirname!
               echo downloading !line!
               set "downloadDir=!apr_dir!\!dirname!"
               cd /D %epmautomate_dir%
               for /f "delims=" %%i in ('epmautomate downloadfile "!line!"') do set result1=%%i
               move "!line:~24!" "!downloadDir!" > nul
               echo !result1!
               REM end downloading
               
             ) else (
               REM start downloading
               cd /D !dirname!
               echo downloading !line!
               set apr_dir=!apr_dir:"=!
               set "downloadDir=!apr_dir!\!dirname!"
               cd /D %epmautomate_dir%
               for /f "delims=" %%i in ('epmautomate downloadfile "!line!"') do set result1=%%i
               move "!line:~24!" "!downloadDir!" > nul
               echo !result1!
               REM end downloading
             )
         ) else (
           REM TO-DO
         )
       )
     )
   )
   
   echo.
   echo %output_cnt% access logs downloaded
   for /L %%n in (1 1 !output_cnt!) DO echo !output[%%n]!
   goto :end
   
   :end
   cd /D %epmautomate_dir%
   endlocal
   

2. Modifique syncAccessLog.bat para definir os valores dos parâmetros na tabela a seguir. Esses valores são usados para acessar o ambiente com o objetivo de fazer o download de logs de acesso.

   Tabela 3-4 Valores de Variáveis a Incluir no syncAccessLog.bat

   Variável	Valor Esperado
   set apr_dir=%1	Especifique o diretório no qual será feito o download de logs de acesso. Exemplo: set apr_dir="C:\Oracle\apr"
   set username=%2	Um nome de usuário do Oracle Enterprise Performance Management Cloud que é usado para conexão com o ambiente e fazer o download de logs de acesso. Exemplo: set username="ServiceAdmin"
   set password=%3	O nome e a localização do arquivo que armazena a senha criptografada do usuário especificado pela variável username. Você também pode especificar a senha do usuário em texto simples (não recomendado). Consulte o comando encrypt para obter informações sobre a criação de um arquivo de senha criptografada. Exemplos: set password="C:\mySecuredir\password.epw" set password="P@ssword1"
   set url=%4	O URL do ambiente. Exemplo: set url="https://test-cloudpln.pbcs.us1.oraclecloud.com"

3. Utilizando o Agendador do Windows, agende syncAccessLog.bat. Consulte Automação da Execução de Scripts para obter as etapas detalhadas.