サービスの定義


	BEA ホーム \| イベント \| ソリューション \| パートナ \| 製品 \| サービス \| ダウンロード \| ディベロッパ・センタ \| WebSUPPORT
	e-docs \| サイトマップ \| 検索 \| PDF版 \| お問い合わせ \| 用語集

Tuxedo ホーム \| COBOL を使用した BEA Tuxedo アプリケーションのプログラミング \| 先頭へ \| 前へ \| 次へ \| 目次

サービスの定義

サービス・ルーチンをコーディングする場合、最初に TPSVCSTART(3cbl) ルーチンを呼び出す必要があります。このルーチンは、サービスのパラメータとデータを取得します。TPSVCSTART ルーチンの呼び出しには、次の文法を使用します。

01 TPSVCDEF-REC.
   COPY TPSVCDEF.
01 TPTYPE-REC.
   COPY TPTYPE.
01 DATA-REC.
   COPY User Data.
01 TPSTATUS-REC.
   COPY TPSTATUS.
CALL "TPSVCSTART" USING TPSVCDEF-REC TPTYPE-REC DATA-REC TPSTATUS-REC.

サービス情報のデータ構造体は、COBOL の COPY ファイルに TPSVCDEF として定義されます。このデータ構造体のメンバは、次のとおりです。

 05 COMM-HANDLE          PIC S9(9) COMP-5.
 05 TPBLOCK-FLAG         PIC S9(9) COMP-5.
        88 TPBLOCK       VALUE 0.
        88 TPNOBLOCK     VALUE 1.
 05 TPTRAN-FLAG          PIC S9(9) COMP-5.
        88 TPTRAN        VALUE 0.
        88 TPNOTRAN      VALUE 1.
 05 TPREPLY-FLAG          PIC S9(9) COMP-5.
        88 TPREPLY        VALUE 0.
        88 TPNOREPLY      VALUE 1.
 05 TPACK-FLAG   PIC S9(9) COMP-5 REDEFINES TPREPLY-FLAG.
        88 TPNOACK        VALUE 0.
        88 TPACK          VALUE 1.
 05 TPTIME-FLAG           PIC S9(9) COMP-5.
        88 TPTIME         VALUE 0.
        88 TPNOTIME       VALUE 1.
 05 TPSIGRSTRT-FLAG       PIC S9(9) COMP-5.
        88 TPNOSIGRSTRT   VALUE 0.
        88 TPSIGRSTRT     VALUE 1.
 05 TPGETANY-FLAG         PIC S9(9) COMP-5.
        88 TPGETHANDLE    VALUE 0.
        88 TPGETANY       VALUE 1.
 05 TPSENDRECV-FLAG       PIC S9(9) COMP-5.
        88 TPSENDONLY     VALUE 0.
        88 TPRECVONLY     VALUE 1.
 05 TPNOCHANGE-FLAG       PIC S9(9) COMP-5.
        88 TPCHANGE       VALUE 0.
        88 TPNOCHANGE     VALUE 1.
 05 TPSERVICETYPE-FLAG    PIC S9(9) COMP-5.
        88 TPREQRSP       VALUE 0.
        88 TPCONV         VALUE 1.
*
 05 APPKEY                PIC S9(9) COMP-5.
 05 CLIENTID OCCURS 4 TIMES PIC S9(9) COMP-5.
 05 SERVICE-NAME          PIC X(15).

次の表は、TPSVCDEF データ構造体のメンバを示しています。

TPSVCDEF データ構造体

フィールド

説明

COMM-HANDLE

要求元プロセスがサービスの呼び出しに使用した通信ハンドル。この通信ハンドルは、サービス・ルーチンに対して指定されます。

SETTINGS
(TPBLOCK-FLAG
TPTRAN-FLAG など)

サーバの特性を制御するその他の設定。設定値の詳細については、『BEA Tuxedo COBOL リファレンス』を参照してください。

APPKEY

アプリケーションで使用するために予約された値。アプリケーション固有の認証が設計に含まれている場合、認証サーバによって認証の成功または失敗を示す値、およびクライアント認証キーが返される必要があります。認証サーバは、クライアントがアプリケーションに参加するときに呼び出されます。BEA Tuxedo システムは、APPKEY をクライアントのために保持し、このフィールドに格納して以降のサービス要求に渡します。APPKEY がサービスに渡されたときは、クライアントの認証は終了しています。ただし、サービス内で APPKEY フィールドを使用して、サービスを呼び出したユーザ、またはそのユーザに関するそのほかのパラメータを識別できます。

CLIENTID

要求元クライアントの識別子。

SERVICE-NAME

要求元プロセスがサービスの呼び出しに使用したサービス・ルーチンの名前。

フィールド	説明
COMM-HANDLE	要求元プロセスがサービスの呼び出しに使用した通信ハンドル。この通信ハンドルは、サービス・ルーチンに対して指定されます。
SETTINGS (TPBLOCK-FLAG TPTRAN-FLAG など)	サーバの特性を制御するその他の設定。設定値の詳細については、『BEA Tuxedo COBOL リファレンス』を参照してください。
APPKEY	アプリケーションで使用するために予約された値。アプリケーション固有の認証が設計に含まれている場合、認証サーバによって認証の成功または失敗を示す値、およびクライアント認証キーが返される必要があります。認証サーバは、クライアントがアプリケーションに参加するときに呼び出されます。BEA Tuxedo システムは、APPKEY をクライアントのために保持し、このフィールドに格納して以降のサービス要求に渡します。APPKEY がサービスに渡されたときは、クライアントの認証は終了しています。ただし、サービス内で APPKEY フィールドを使用して、サービスを呼び出したユーザ、またはそのユーザに関するそのほかのパラメータを識別できます。
CLIENTID	要求元クライアントの識別子。
SERVICE-NAME	要求元プロセスがサービスの呼び出しに使用したサービス・ルーチンの名前。

TPTYPE-REC データ構造体については、「型付きレコードの定義」を参照してください。

DATA-REC に格納される要求データにサービスがアクセスする場合は、コンフィギュレーション・ファイルでそのサービスに定義されているレコード・タイプにデータが格納されるようにコーディングする必要があります。制御が正常に戻った場合、DATA-REC には受け取ったデータが格納され、LEN には移動した実際のバイト数が格納されます。

次のコード例は、一般的なサービス定義を示しています。

一般的なサービス定義

   IDENTIFICATION DIVISION.
   PROGRAM-ID. BUYSR.
   AUTHOR.TUXEDO DEVELOPMENT.
   ENVIRONMENT DIVISION.
   CONFIGURATION SECTION.
   SOURCE-COMPUTER.USL-486.
   OBJECT-COMPUTER.USL-486.
*
   INPUT-OUTPUT SECTION.
    . . .
******************************************************
* Tuxedo の定義
******************************************************
   01  TPSVCRET-REC.
   COPY TPSVCRET.
*
   01 TPTYPE-REC.
    COPY TPTYPE.
*
   01 TPSTATUS-REC.
   COPY TPSTATUS.
*
   01  TPSVCDEF-REC.
   COPY TPSVCDEF.
******************************************************
* ログ・メッセージの定義
******************************************************
    01 LOGMSG.
            05 LOGMSG-TEXT      PIC X(50).
*
    01 LOGMSG-LEN  PIC S9(9) COMP-5.
******************************************************
* ユーザ定義のデータ・レコード
******************************************************
    01 CUST-REC.
    COPY CUST.
*
    LINKAGE SECTION.
*
    PROCEDURE DIVISION.
*
 START-BUYSR.
    MOVE LENGTH OF LOGMSG TO LOGMSG-LEN.
    OPEN files or DATABASE
******************************************************
* クライアントから送信されたデータの取得
******************************************************
    MOVE "Server Started" TO LOGMSG-TEXT.
    PERFORM DO-USERLOG.
    MOVE LENGTH OF CUST-REC TO LEN IN TPTYPE-REC.
    CALL "TPSVCSTART" USING TPSVCDEF-REC
                      TPTYPE-REC
                      CUST-REC
                      TPSTATUS-REC.
    IF TPTRUNCATE
        MOVE "Input data exceeded CUST-REC length" TO LOGMSG-TEXT
        PERFORM DO-USERLOG
        PERFORM A-999-EXIT.
    IF NOT TPOK
        MOVE "TPSVCSTART Failed" TO LOGMSG-TEXT
        PERFORM DO-USERLOG
        PERFORM A-999-EXIT.
    IF REC-TYPE NOT = "VIEW"
        MOVE "REC-TYPE in not VIEW" TO LOGMSG-TEXT
        PERFORM DO-USERLOG
        PERFORM A-999-EXIT.
    IF SUB-TYPE NOT = "cust"
        MOVE "SUB-TYPE in not cust" TO LOGMSG-TEXT
        PERFORM DO-USERLOG
        PERFORM A-999-EXIT.
     . . .
     set consistency level of the transaction
     . . .
******************************************************
* 終了
******************************************************
 A-999-EXIT.
     MOVE "Exiting" TO LOGMSG-TEXT.
     PERFORM DO-USERLOG.
     SET TPFAIL TO TRUE.
     COPY TPRETURN REPLACING TPSVCRET-REC BY TPSVCRET-REC
                   TPTYPE-REC BY TPTYPE-REC
     DATA-REC BY CUST-REC
     TPSTATUS-REC BY TPSTATUS-REC.
******************************************************
* ユーザ・ログへの書き込み
******************************************************
 DO-USERLOG.
     CALL "USERLOG" USING LOGMSG
               LOGMSG-LEN
               TPSTATUS-REC.

この例では、クライアント側の要求レコードが最初に送られたときに、REC-TYPE に VIEW、SUB-TYPE に cust が設定されています。BUYSR サービスは、VIEW 型レコードを認識するサービスとしてコンフィギュレーション・ファイルに定義されています。BUYSR サービスは、CUST-REC レコードにアクセスしてデータ・レコードを取得します。このレコードが取得された後、データベースへの最初のアクセスを行う前に、トランザクションの整合性レベルが指定されています。トランザクションの整合性レベルの詳細については、「グローバル・トランザクションのコーディング」を参照してください。

注記優先順位を取得する TPGPRIO、および優先順位を設定する TPSPRIO 関数の詳細については、「メッセージの優先順位の設定および取得」を参照してください。

ここで示すコード例は、PRINTER サービスが TPGPRIO ルーチンを使用して、受信したばかりの要求の優先順位を確認する方法を示しています。その優先順位に基づいて、印刷ジョブが適切なプリンタ RNAME に送られます。

その後、INPUT-REC の内容がプリンタに送られます。アプリケーションは TPSVCDEF-REC を照会し、応答が必要かどうかを判定します。応答が必要な場合は、プリンタ名をクライアントに返します。TPRETURN ルーチンの詳細については、「サービス・ルーチンの終了」を参照してください。

受信した要求の優先順位の確認

   IDENTIFICATION DIVISION.
   PROGRAM-ID. PRINTSR.
   AUTHOR.TUXEDO DEVELOPMENT.
   ENVIRONMENT DIVISION.
   CONFIGURATION SECTION.
   SOURCE-COMPUTER.USL-486.
   OBJECT-COMPUTER.USL-486.
*
   INPUT-OUTPUT SECTION.
    . . .
******************************************************
* Tuxedo の定義
******************************************************
   01  TPSVCRET-REC.
   COPY TPSVCRET.
*
   01 TPTYPE-REC.
   COPY TPTYPE.
*
   01 TPSTATUS-REC.
   COPY TPSTATUS.
*
   01  TPSVCDEF-REC.
   COPY TPSVCDEF.
*
   01 TPPRIDEF-REC.
   COPY TPPRIDEF.
******************************************************
* ログ・メッセージの定義
******************************************************
   01 LOGMSG.
           05 FILLER            PIC S9(9) VALUE
                   "TP-STATUS=".
            05 LOG-TP-STATUS    PIC S9(9).
            05 LOGMSG-TEXT      PIC X(50).
*
   01 LOGMSG-LEN  PIC S9(9) COMP-5.
******************************************************
* ユーザ定義のデータ・レコード
******************************************************
    01 INPUT-REC           PIC X(1000).
    01 PRNAME              PIC X(20).
*
    LINKAGE SECTION.
*
    PROCEDURE DIVISION.
*
 START-PRINTSR.
    MOVE LENGTH OF LOGMSG TO LOGMSG-LEN.
    OPEN files or DATABASE
******************************************************
* クライアントから送信されたデータの取得
******************************************************
    MOVE ZERO to TP-STATUS.
    MOVE "Server Started" TO LOGMSG-TEXT.
    PERFORM DO-USERLOG.
    MOVE LENGTH OF INPUT-REC TO LEN.
    CALL "TPSVCSTART" USING TPSVCDEF-REC
                      TPTYPE-REC
                      INPUT-REC
                      TPSTATUS-REC.
    IF NOT TPOK
             MOVE "TPSVCSTART Failed" TO LOGMSG-TEXT
             PERFORM DO-USERLOG
             SET TPFAIL TO TRUE.
             PERFORM A-999-EXIT.
    . . .
    Check other parameters
    CALL "TPGPRIO" USING TPPRIDEF-REC
                   TPSTATUS-REC.
    IF NOT TPOK
             MOVE "TPGPRIO Failed" TO LOGMSG-TEXT
             PERFORM DO-USERLOG
             SET TPFAIL TO TRUE.
             PERFORM A-999-EXIT.
    IF PRIORITY < 20
             MOVE "BIGJOBS" TO RNAME
    ELSE IF PRIORITY < 60
             MOVE "MEDJOBS" TO RNAME
    ELSE
             MOVE "HIGHSPEED" TO RNAME.
    . . .
    Print INPUT-REC on RNAME printer
    . . .
    IF TPNOREPLY
             MOVE SPACES TO REC-TYPE
             MOVE 0 TO LEN
    SET TPSUCCESS TO TRUE
             PERFORM A-999-EXIT
    IF TPREPLY
             MOVE "STRING" TO REC-TYPE
             MOVE LENGTH OF PRNAME TO LEN
    SET TPSUCCESS TO TRUE
             PERFORM A-999-EXIT.
******************************************************
* 終了
******************************************************
 A-999-EXIT.
    MOVE "Exiting" TO LOGMSG-TEXT.
    PERFORM DO-USERLOG.
    SET TPSUCCESS TO TRUE.
    COPY TPRETURN REPLACING TPSVCRET-REC BY TPSVCRET-REC
              TPTYPE-REC buTPTYPE-REC
              DATA-REC BY PRNAME
              TPSTATUS-REC BY TPSTATUS-REC.
******************************************************
* ユーザ・ログへの書き込み
******************************************************
 DO-USERLOG.

     MOVE TP-STATUS TO LOG-TP-STATUS.
     CALL "USERLOG" USING LOGMSG
               LOGMSG-LEN
               TPSTATUS-REC.