Exadata VMクラスタ

locals {
  # IDs of depending resources
  cloud_exadata_infrastructure_id = aws_odb_cloud_exadata_infrastructure.this.id
  db_servers = data.aws_odb_db_servers.this.db_servers[*].id
  odb_network_id = aws_odb_network.this.id
}

# Create a VM Cluster in the Exadata Infrastructure
resource "aws_odb_cloud_vm_cluster" "this" {
  # Optional explicit dependencies
  depends_on = [aws_odb_cloud_exadata_infrastructure.this, aws_odb_network.this]

  # Required Arguments
  cloud_exadata_infrastructure_id = local.cloud_exadata_infrastructure_id
  cpu_core_count                  = 16
  db_servers                      = local.db_servers
  display_name                    = "tf-vmc-demo"
  gi_version                      = "23.0.0.0"
  hostname_prefix                 = "vm"
  odb_network_id                  = local.odb_network_id
  ssh_public_keys                 = [
    file("~/.ssh/demo-ssh-key.pub")
  ]
  data_collection_options {
    is_diagnostics_events_enabled = true
    is_health_monitoring_enabled  = true
    is_incident_logs_enabled      = true
  }
  
  # Optional Arguments
  cluster_name                    = "gic-demo"
  data_storage_size_in_tbs        = 2
  db_node_storage_size_in_gbs     = 120
  is_local_backup_enabled         = false
  is_sparse_diskgroup_enabled     = false
  license_model                   = "BRING_YOUR_OWN_LICENSE"
  memory_size_in_gbs              = 60
  scan_listener_port_tcp          = 1521
  timezone                        = "UTC"
  region                          = "us-west-2"
  tags                            = {
    created_via  = "terraform"
    env          = "demo"
  }

  # timeouts for long running operations
  timeouts {
    create = "24h"
    update = "2h"
    delete = "8h"
  }

  # gi_version will be updated with minor version, e.g. "23.8.0.25.04" 
  lifecycle {
    ignore_changes = [
      gi_version
    ]    
  }
}

# Output OCID of Exadata VM Cluster for Database Home creation (Optional)
output "oci_cloud_vm_cluster_ocid" {
  value = aws_odb_cloud_vm_cluster.this.ocid
}