Cluster de VMs Autônomas

locals {
  # IDs of depending resources
  cloud_exadata_infrastructure_id = aws_odb_cloud_exadata_infrastructure.this.id
  db_servers = data.aws_odb_db_servers.this.db_servers[*].id
  odb_network_id = aws_odb_network.this.id
}

# Create an Autonomous VM Cluster in the Exadata Infrastructure
resource "aws_odb_cloud_autonomous_vm_cluster" "this" {
  # Optional explicit dependencies
  depends_on = [aws_odb_cloud_exadata_infrastructure.this, aws_odb_network.this]

  # Required Arguments 
  cloud_exadata_infrastructure_id       = local.cloud_exadata_infrastructure_id
  autonomous_data_storage_size_in_tbs   = 5
  cpu_core_count_per_node               = 40
  db_servers                            = local.db_servers
  display_name                          = "tf-avmc-demo"
  memory_per_oracle_compute_unit_in_gbs = 2
  odb_network_id                        = local.odb_network_id
  scan_listener_port_non_tls            = 1521
  scan_listener_port_tls                = 2484
  total_container_databases             = 2
  maintenance_window {
    preference         = "NO_PREFERENCE"
    lead_time_in_weeks = null
    days_of_week       = null
    hours_of_day       = null
    months             = null
    weeks_of_month     = null
  }

  # Optional Arguments 
  description                = "Autonomous VM Cluster"
  is_mtls_enabled_vm_cluster = true
  license_model              = "BRING_YOUR_OWN_LICENSE"
  time_zone                  = "UTC"
  region                     = "us-west-2"
  tags                       = {
    created_via  = "terraform"
    env          = "demo"
  }
}

# Output OCID of Autonomous VM Cluster for the creation of Autonomous Container Database (Optional)
output "oci_cloud_autonomous_vm_cluster_ocid" {
  value = aws_odb_cloud_autonomous_vm_cluster.this.ocid
}