Exadata Infrastructure

# Create an Exadata Infrastructure
resource "aws_odb_cloud_exadata_infrastructure" "this" {
  # Required Arguments
  display_name                     = "exadb-inf-demo"
  shape                            = "Exadata.X11M"
  compute_count                    = 2
  storage_count                    = 3
  availability_zone_id             = "usw2-az3"
  # Optional Arguments
  customer_contacts_to_send_to_oci = [
	{ email = "demo@example.com" }
  ]
  region                           = "us-west-2"
  availability_zone                = "us-west-2c"
  database_server_type             = "X11M"
  storage_server_type              = "X11M-HC"
  tags                             = {
	"env" = "dev"
  }
  maintenance_window {
    patching_mode                    = "ROLLING"
    preference                       = "NO_PREFERENCE"
    is_custom_action_timeout_enabled = false
    custom_action_timeout_in_mins    = 15
    days_of_week                     = null
    hours_of_day                     = null
    lead_time_in_weeks               = null
    months                           = null
    weeks_of_month                   = null
  }
}

# Get list of DB Servers for provisioning VM Cluster / Autonomous VM Cluster
data "aws_odb_db_servers" "this" {
  cloud_exadata_infrastructure_id = aws_odb_cloud_exadata_infrastructure.this.id
}

# Optional output of OCIDs for configurations using OCI Terraform Provider
output "oci_region" {
   value = regex("(?i:region=)([^?&/]+)", aws_odb_cloud_exadata_infrastructure.this.oci_url)[0]
}

output "oci_compartment_ocid" {
   value = regex("(?i:compartmentId=)([^?&/]+)", aws_odb_cloud_exadata_infrastructure.this.oci_url)[0]
}

output "oci_tenant" {
   value = regex("(?i:tenant=)([^?&/]+)", aws_odb_cloud_exadata_infrastructure.this.oci_url)[0]
}

output "oci_cloud_exadata_infrastructure_ocid" {
   value = aws_odb_cloud_exadata_infrastructure.this.ocid
}