フェデレーテッド・キューブのメンテナンスおよびトラブルシューティング

Essbaseフェデレーテッド・キューブのメンテナンスやトラブルシューティングを実行する場合は、次のガイドラインを使用してください。

このトピックでは、フェデレーテッド・パーティションを作成しており、前のトピックで説明した情報を確認済であることを前提としています。

• フェデレーテッド・キューブのモデリングとテスト

• フェデレーテッド・キューブのメタデータに関する事前注意

• フェデレーテッド・キューブで長時間実行されているSQLの取消し

• データベース接続の詳細が変更された場合の対応

• フェデレーテッド・キューブのバックアップとリストア

フェデレーテッド・キューブのモデリングとテスト

Essbaseフェデレーテッド・キューブを設計する場合は、次の設計およびテストのガイドラインに従って、トラブルシューティングまたはパフォーマンスの監視のための段階的なアプローチを取ります。

• テスト環境でフェデレーテッド・キューブ・プロジェクトを開始します。

• 次の特性を持つEssbase ASOまたはBSOキューブ・モデルで始めます:

  • レベルが多くない

  • 共有メンバーや属性が多くない

1. フェデレーテッド・パーティションを作成するとき、インスタンスに対する問合せが許可されていない場合はオフライン操作をスケジュールします。

2. MaxLのalter application disable commandsまたはdisable connects (新しいユーザー・アクティビティを防止するため)、あるいはその両方を使用し、その後にalter system logout sessionまたはkill request (完了する必要がないアクティブなセッションを終了する必要がある場合)、あるいはその両方を使用して、アクティブなEssbaseユーザー・セッションを徐々に切断します。なお、MaxLによって、Autonomous AI Lakehouseで実行されている可能性があるリクエストを終了することはできません。アプリケーションでコマンドを無効にする場合は、 フェデレーテッド・パーティションの作成後に、必ずコマンドを再度有効にしてください。

   Autonomous AI LakehouseでSQLセッションとして実行されているリクエストを終了するには、追加の手順が必要です。「フェデレーテッド・キューブで長時間実行されているSQLの取消し」を参照してください。

3. タイムアウト・チューニングを実行します:
   • カスタマ・ネットワークのHTTPSプロキシ - カスタマ・ネットワーク・タイムアウトを調整します
   • ロード・バランサ - LoadBalanceタイムアウトを1260秒(21分)に増やします
   • HTTPDタイムアウトを21分に増やします

     /etc/httpd/conf.d/00_base.conf:ProxyTimeout 1260

     /etc/httpd/conf.d/00_base.conf:Timeout 1260

   • APS/JAPIタイムアウト:
     • Essbase Webインタフェースにある「コンソール」ページで、「構成」を選択し、olap.server.netSocketTimeOutの値を書き留めます。値200ミリ秒は、これらのプロパティのカウント5ごとに1秒の待機時間を与えることを意味します。
     • APS/JAPIのタイムアウト制限を30分に設定するには、olap.server.netRetryCountを9000に設定します。
4. フェデレーテッド・パーティションを作成します。
5. ステップ3のタイムアウト調整を元に戻します。
6. alter application enable commandsまたはconnects (あるいはその両方)を使用して(以前にこれらが無効になっていた場合)、ユーザーがシステムに戻れるようにします。
7. フェデレーテッド・キューブに関するレポートの場合、フェデレーテッド・パーティションに対する問合せの実行の予想実行時間より長くするようにQRYGOVEXECTIMEを調整しますなお、QRYGOVEXECTIMEによって、Autonomous AI Lakehouseで実行されている可能性があるリクエストを終了することはできません。
8. 開発環境のテストおよびチューニングが完了したら、前述のステップ1から7を使用して、本番環境を実装します。

ノート:

フェデレーテッド・パーティションの作成時に「アウトラインの保存に失敗しました」というエラーが表示された場合は、セッションが完了するまで待機してから、ブラウザをリフレッシュします。フェデレーテッド・パーティションが作成されている場合は、SQL Developerで検証します。SQL Developerで検証されると、フェデレーテッド・キューブが使用可能になります。それ以外の場合は、モデルを修正する必要があり、前述のステップ3で説明したようにタイムアウト・チューニングが必要です。

フェデレーテッド・キューブのメタデータに関する事前注意

Essbaseで管理されていないフェデレーテッド・キューブのアウトラインを編集するときは注意してください。メンバーを追加または名前変更した場合は、メタデータ変更がAutonomous AI Lakehouseのファクト表にも反映されていることを確認してください。

このトピックは、Essbase管理対象データ・ストレージを使用するフェデレーテッド・キューブには適用されません。

EssbaseアウトラインがAutonomous AI Lakehouse内のファクト表と同期しなくなった場合、フェデレーテッド・キューブは無効になるか正しく機能しません。これを修正するには、フェデレーテッド・パーティションを削除し、アウトラインとファクト表を変更してから、フェデレーテッド・パーティションを再作成する必要があります。

フェデレーテッド・キューブが無効になった場合、Essbaseエラー(1040235): フェデレーテッド・パーティションからのリモート警告で始まるエラーが発生することがあります。

次のタイプのEssbaseアウトライン変更により、(Essbaseで管理されていない)フェデレーテッド・キューブが無効になります:

• ディメンションの追加、名前変更または削除

• ピボット・ディメンションでの保管済メンバーの追加、名前変更または削除

• 保管済から動的へのメンバーの変更

前述以外の他のタイプのEssbaseアウトライン変更の場合は(ピボット・ディメンション以外のメンバーの追加や名前変更など)、それに対応する変更をファクト表内の影響を受けるデータ行に加える必要があります。そうしないと、フェデレーテッド・キューブが正しく機能しない可能性があります。

Essbaseアウトライン・メタデータが変更されることが事前にわかっている場合は、まずフェデレーテッド・パーティションを削除し、アウトライン変更を加え、ファクト表を更新してから、フェデレーテッド・パーティションを再作成することをお薦めします。

しかしながら、Essbaseメタデータが変更されてフェデレーテッド・パーティションが無効になった場合は、次の操作を実行します:

1. 「フェデレーテッド・パーティションの削除」で説明されているとおりに、フェデレーテッド・パーティション、およびそれに関連付けられている接続を削除します(別の方法で使用されていない場合)。

   Autonomous AI Lakehouseのユーザー・スキーマから、Essbaseで生成された表、およびフェデレーテッド・パーティションとともに削除できなかった他のオブジェクトを手動で削除します。

2. Essbaseキューブでアウトライン変更が完了していることを確認します。

3. ファクト表を再度作成します。「ファクト表の作成」を参照してください。

4. Autonomous AI Lakehouseとの接続を再作成します。これは、グローバル接続(Essbase Webインタフェースにあるメインの「ソース」アイコンの下)であるか、そのアプリケーション専用に定義されている「ソース」内にある場合があります。「フェデレーテッド・キューブの接続の作成」の手順に従います。

5. 「フェデレーテッド・パーティションの作成」で説明されているとおりに、フェデレーテッド・パーティションを再作成します。

フェデレーテッド・キューブで長時間実行されているSQLの取消し

Essbaseフェデレーテッド・キューブで実行されているSQLセッションは取り消すことができます。計算に時間がかかりすぎる場合や、フェデレーテッド・キューブでバックアップまたはリカバリが必要な場合、SQLの取消しが必要になることがあります。

フェデレーテッド・キューブで実行されているEssbaseの計算、データ・ロードまたは集計によって長時間実行されるSQL文が生成される場合、Autonomous Data Warehouseで実行されていても、セッションを取り消すことができます。

Essbaseを使用してSQLセッションを取り消す前に、簡単な手順のワークフローを完了してEssbaseでSQLセッション・ガバナーを有効にする必要があります。

次のタイプのアクセス権を持つユーザーは、準備手順に関与します。

ユーザー・タイプ	ワークフロー内のロール
DB管理者	Autonomous AI Lakehouseの管理者スキーマ名およびパスワードを把握しています。Autonomous AI LakehouseでストアドPL/SQLプロシージャを作成し、他のユーザーに権限を付与できます。
DBユーザー フェデレーテッド・パーティション・ユーザーとも呼ばれます	Autonomous AI Lakehouseのスキーマ名およびパスワード(Oracle DatabaseへのEssbase接続の作成に使用するのと同じスキーマおよびパスワード)を把握しています(フェデレーテッド・パーティションの作成前に必要な前提条件)。
Essbaseアプリケーション・マネージャ	フェデレーテッド・キューブに使用されるEssbaseアプリケーションのマネージャ/所有者。

SQLセッション・ガバナーを有効にするには、次の手順のワークフローを完了する必要があります:

1. DB管理者: Autonomous AI Lakehouseに次のPL/SQLストアド・プロシージャを作成し、DBユーザーにEXECUTE権限を付与します:

   ノート:

   ストアド・プロシージャは、データベース・ユーザー・スキーマに作成されます。

   1. ESS_SESSION_SET_MODULE (jagent_id in VARCHAR2,app_name in VARCHAR2, db_name in VARCHAR2, req_id in VARCHAR2)

      次の文を使用してプロシージャを作成します:

      CREATE OR REPLACE NONEDITIONABLE PROCEDURE "ESS_SESSION_SET_MODULE" (jagent_id in VARCHAR2, app_name in VARCHAR2, db_name in VARCHAR2, req_id in VARCHAR2) AS
          ess_jagentid VARCHAR2(256);
          ess_appname VARCHAR2(256);
          ess_dbname VARCHAR2(256);
          ess_reqid VARCHAR2(256);
          hash_str VARCHAR2(100);
      BEGIN
          IF jagent_id is not NULL AND app_name is not NULL AND db_name is not NULL AND req_id is not NULL THEN
              -- add prefixes to identify essbase sessions
              ess_jagentid := CONCAT('ess_jagentid_', jagent_id);
              ess_appname := CONCAT('ess_appname_', app_name);
              ess_dbname := CONCAT('ess_dbname_', db_name);
              ess_reqid := CONCAT('ess_reqid_', req_id);
      
              -- ess_jagentid is stored in client_info
              dbms_application_info.set_client_info(ess_jagentid);
      
              -- create hash out of CONCAT(ess_jagentid, ess_appname, ess_dbname)
              -- the hash identifies the fed partition
              -- store the hash as the module
              -- store the ess_reqid as the action
              SELECT TO_CHAR(ORA_HASH(CONCAT(CONCAT(ess_jagentid, ess_appname), ess_dbname))) INTO hash_str from dual;
              dbms_application_info.set_module(module_name => hash_str, action_name => ess_reqid);
              
          ELSIF jagent_id is NULL AND app_name is NULL AND db_name is NULL AND req_id is NULL THEN
              -- reset session
              dbms_application_info.set_module(null,null);
              dbms_application_info.set_client_info(null);
          END IF;
      END ESS_SESSION_SET_MODULE;
      

   2. ESS_SESSION_CANCEL (jagent_id in VARCHAR2, app_name in VARCHAR2, db_name in VARCHAR2, req_id in VARCHAR2)

      次の文を使用してプロシージャを作成します:

      CREATE OR REPLACE NONEDITIONABLE PROCEDURE "ESS_SESSION_CANCEL" (jagent_id in VARCHAR2, app_name in VARCHAR2, db_name in VARCHAR2, req_id in VARCHAR2) AS
          ess_jagentid VARCHAR2(256);
          ess_appname VARCHAR2(256);
          ess_dbname VARCHAR2(256);
          ess_reqid VARCHAR2(256);
          uname VARCHAR2(100);
          hash_str VARCHAR2(100);
          sessionid VARCHAR2(100);
          killcmd VARCHAR2(1000);
          XCP_MARKED_FOR_TERMINATION exception;
          pragma exception_init (XCP_MARKED_FOR_TERMINATION, -00031);
      BEGIN
          -- add prefixes to identify Essbase sessions
          ess_jagentid := CONCAT('ess_jagentid_', jagent_id);
          ess_appname := CONCAT('ess_appname_', app_name);
          ess_dbname := CONCAT('ess_dbname_', db_name);
          ess_reqid := CONCAT('ess_reqid_', req_id);
      
          -- create hash out of CONCAT(ess_jagentid, ess_appname, ess_dbname)
          -- the hash identifies the federated partition
          SELECT TO_CHAR(ORA_HASH(CONCAT(CONCAT(ess_jagentid, ess_appname), ess_dbname))) INTO hash_str from dual;
          uname := SYS_CONTEXT('USERENV', 'SESSION_USER');
      
          IF jagent_id is not NULL AND app_name is not NULL AND db_name is not NULL AND req_id is not NULL THEN
              -- valid jagent_id, app_name, db_name, req_id
              -- kill sessions associated with the given federated cube and request id
              FOR r IN (select sid,serial# from v$session where username=uname AND module=hash_str AND action=ess_reqid)
              LOOP
                  BEGIN
                      sessionid := DBMS_ASSERT.ENQUOTE_LITERAL(r.sid || ',' || r.serial#);
                      killcmd:='ALTER SYSTEM KILL SESSION ' || sessionid || ' IMMEDIATE';
                      EXECUTE IMMEDIATE killcmd;
                  EXCEPTION
                      WHEN XCP_MARKED_FOR_TERMINATION THEN
                          -- ignore - the session could not be terminated immediately, but is marked for termination.
                          NULL;
                  END;
              END LOOP;
          ELSIF jagent_id is not NULL AND app_name is not NULL AND db_name is not NULL AND req_id is NULL THEN
              -- null req_id
              -- kill all sessions for the given federated cube - invoked at app startup
              FOR r IN (select sid,serial# from v$session where username=uname AND module=hash_str)
              LOOP
                  BEGIN
                      sessionid := DBMS_ASSERT.ENQUOTE_LITERAL(r.sid || ',' || r.serial#);
                      killcmd:='ALTER SYSTEM KILL SESSION ' || sessionid || ' IMMEDIATE';
                      EXECUTE IMMEDIATE killcmd;
                  EXCEPTION
                      WHEN XCP_MARKED_FOR_TERMINATION THEN
                          -- ignore - the session could not be terminated immediately, but is marked for termination.
                          NULL;
                  END;
              END LOOP;
          END IF;
      
          EXCEPTION
              WHEN OTHERS THEN
                  RAISE;
      END ESS_SESSION_CANCEL;
      

   3. 前述のストアド・プロシージャのEXECUTE権限をDBユーザーに付与します。

      GRANT EXECUTE on ESS_SESSION_SET_MODULE TO "DB User";
      GRANT EXECUTE on ESS_SESSION_CANCEL TO "DB User";
      CREATE OR REPLACE SYNONYM "DB User".ESS_SESSION_SET_MODULE FOR ESS_SESSION_SET_MODULE;
      CREATE OR REPLACE SYNONYM "DB User".ESS_SESSION_CANCEL FOR ESS_SESSION_CANCEL;

2. DBユーザー: Autonomous AI Lakehouseスキーマで、シノニムの下にある次のストアド・プロシージャにアクセスできることを確認します:

   • ESS_SESSION_SET_MODULE
   • ESS_SESSION_CANCEL

3. これらの前提条件を満たすと、フェデレーテッド・キューブで長時間実行されているSQLリクエストを、他のEssbaseリクエストと同じ方法で取り消すことができます。Essbase Webインタフェースの「コンソール」の「セッション」領域から、リクエストを取り消すことができます。MaxLを使用している場合は、alter system kill request文を使用してリクエストを取り消すことができます。セッション終了のガイドラインは、「フェデレーテッド・パーティション・キューブのモデルリングとテスト」を参照してください。

データベース接続の詳細が変更された場合の対応

Essbaseでフェデレーテッド・キューブに使用されるAutonomous AI Lakehouse接続詳細を変更した場合は、そのフェデレーテッド・パーティションを削除および再作成し、関連するオブジェクトおよびメタデータ表をデータベース・スキーマからクリーン・アップする必要があります。

このトピックは、Essbase管理対象データ・ストレージを使用するフェデレーテッド・キューブには適用されません。

フェデレーテッド・パーティションの作成時に次のイベントのいずれかが発生した場合は、そのパーティションを削除し、再作成する必要があります:

• Autonomous AI Lakehouseポートの変更

• 接続名の変更

• 接続でウォレットが使用されており、あるサービス名から別のサービス名に切り替える(パフォーマンスまたは同時実行性を変更するため)

• アウトライン更新がファクト表へのメンバー・マッピングを変更し、フェデレーテッド・パーティションが非同期になる。詳細は、「フェデレーテッド・キューブのメタデータに関する事前注意」を参照してください。

接続の詳細が変更されることが事前にわかっている場合は、変更が行われる前にフェデレーテッド・パーティションを削除し、後で再度作成することをお薦めします。ただし、接続が変更され、フェデレーテッド・キューブが無効になった場合は、次の手順に従います。

フェデレーテッド・パーティションの削除

「フェデレーテッド・パーティションの削除」で説明されているとおりに、フェデレーテッド・パーティション、およびそれに関連付けられている接続を削除します(別の方法で使用されていない場合)。

フェデレーテッド・パーティション関連オブジェクトおよびメタデータ表のクリーン・アップ

Autonomous AI Lakehouseのユーザー・スキーマから、Essbaseで生成された表、およびフェデレーテッド・パーティションとともに削除できなかった他のオブジェクトを削除します。

1. opcユーザーとしてEssbaseサーバー・ホストにssh接続します。

   ssh -i MPOCI_KEY.pem [e-mail]

2. oracleユーザーに変更します(およびホーム・ディレクトリに移動します)。

   sudo su - oracle

3. アプリケーション・ディレクトリに移動します。

   cd /u01/data/essbase/app

4. Essbaseアプリケーションおよびキューブ名を使用して、フェデレーテッド・パーティション・オブジェクトおよびメタデータに関連付けられている一意の接頭辞を識別します。

   1. アプリケーション名(AppName)を取得します。名前は大文字と小文字が区別されるため、大文字と小文字を正確に取得します。この例では、AppName = Sampleです。

      ls
      Sample

   2. キューブ・ディレクトリに移動し、キューブ名(DbName)を取得します。名前は大文字と小文字が区別されるため、大文字と小文字を正確に取得します。この例では、DbName = Basicです。

      cd /Sample
      ls
      Basic

   3. SQL Developerまたは他のツールを使用し、フェデレーテッド・キューブが接続されている(または接続されていた)スキーマのユーザーとして、Autonomous AI Databaseに接続します。

   4. SQL Developerで、SELECT文を実行して、OTL_IDおよびOTL_STATUSの値を取得します。

      SELECT文の書式は次のとおりです:

      SELECT OTL_ID, OTL_STATUS, TRC_HOST FROM ESSAV_OTL_MTD_VERSION where APPNAME ='<AppName>';

      例

      Sampleを実際のAppNameに置き換えます。

      SELECT OTL_ID, OTL_STATUS, TRC_HOST FROM ESSAV_OTL_MTD_VERSION WHERE APPNAME='Sample';

      前述の問合せは、OTL_IDの値を返します。たとえば、次のようになります

      987

      ノート:

      OTL_STATUSがACTIVEである行が返された場合は、次のステップに進む前に、TRC_HOSTインスタンスからアプリケーションを削除することを試みる必要があります。

   5. Prefixを次のように作成します:

      ESSAV_<OTL_ID>_

      次に例を示します。

      <Prefix> = ESSAV_987_

5. SELECT文を実行して、フェデレーテッド・キューブに関連付けられたオブジェクトのリストを作成します。これらは、次のステップでクリーン・アップするオブジェクトです。

   SELECT文の書式は次のとおりです:

   SELECT * FROM user_OBJECTS WHERE OBJECT_NAME LIKE '<Prefix>%' ESCAPE '\';

   次に例を示します。

   SELECT * FROM user_OBJECTS WHERE OBJECT_NAME LIKE 'ESSAV_987_%' ESCAPE '\';

6. 接頭辞に関連付けられているすべての分析ビュー、パッケージ、階層、表およびその他のオブジェクトをクリーン・アップするストアドPL/SQLプロシージャを実行します。

   例

   ESSAV_987_を実際の接頭辞に置き換えます。

   SET SERVEROUTPUT ON;
   
   declare
     prefix_str varchar2(70) := 'ESSAV_987_';
   
   BEGIN
   
     FOR c IN ( SELECT ANALYTIC_VIEW_NAME FROM user_analytic_views WHERE ANALYTIC_VIEW_NAME like prefix_str || '%' )
     LOOP
       EXECUTE IMMEDIATE 'DROP ANALYTIC VIEW "' || c.ANALYTIC_VIEW_NAME || '" ';
       DBMS_OUTPUT.PUT_LINE('ANALYTIC VIEW ' || c.ANALYTIC_VIEW_NAME || ' dropped successfully.');
     END LOOP;
   
     FOR c IN ( SELECT distinct OBJECT_NAME FROM USER_PROCEDURES WHERE OBJECT_TYPE='PACKAGE' and OBJECT_NAME like prefix_str || '%' )
     LOOP
       EXECUTE IMMEDIATE 'DROP PACKAGE "' || c.OBJECT_NAME || '" ';
       DBMS_OUTPUT.PUT_LINE('PACKAGE ' || c.OBJECT_NAME || ' dropped successfully.');
     END LOOP;
   
     FOR c IN ( SELECT distinct HIER_NAME FROM USER_HIERARCHIES WHERE HIER_NAME like prefix_str || '%' )
     LOOP
       EXECUTE IMMEDIATE 'DROP HIERARCHY "' || c.HIER_NAME || '" ';
       DBMS_OUTPUT.PUT_LINE('HIERARCHY ' || c.HIER_NAME || ' dropped successfully.');
     END LOOP;
   
     FOR c IN ( SELECT distinct DIMENSION_NAME FROM USER_ATTRIBUTE_DIM_TABLES_AE WHERE DIMENSION_NAME like prefix_str || '%' )
     LOOP
       EXECUTE IMMEDIATE 'DROP ATTRIBUTE DIMENSION "' || c.DIMENSION_NAME || '" ';
       DBMS_OUTPUT.PUT_LINE('ATTRIBUTE DIMENSION ' || c.DIMENSION_NAME || ' dropped successfully.');
     END LOOP;
   
     FOR c IN ( SELECT distinct VIEW_NAME FROM USER_VIEWS WHERE VIEW_NAME like prefix_str || '%' )
     LOOP
       EXECUTE IMMEDIATE 'DROP VIEW "' || c.VIEW_NAME || '" ';
       DBMS_OUTPUT.PUT_LINE('VIEW ' || c.VIEW_NAME || ' dropped successfully.');
     END LOOP;
   
     FOR c IN ( SELECT distinct TABLE_NAME FROM USER_TABLES WHERE TABLE_NAME like prefix_str || '%' )
     LOOP
       EXECUTE IMMEDIATE 'DROP TABLE "' || c.TABLE_NAME || '" purge';
       DBMS_OUTPUT.PUT_LINE('TABLE ' || c.TABLE_NAME || ' dropped successfully.');
     END LOOP;
   
     FOR c IN ( SELECT distinct TYPE_NAME FROM USER_TYPES WHERE TYPE_NAME like prefix_str || '%' )
     LOOP
       EXECUTE IMMEDIATE 'DROP TYPE "' || c.TYPE_NAME || '" FORCE';
       DBMS_OUTPUT.PUT_LINE('TYPE ' || c.TYPE_NAME || ' dropped successfully.');
     END LOOP;
   
   END;
   /
   

7. 関連するメタデータ関連表を削除および更新します。

   1. ストアドPL/SQLプロシージャを実行して、OTL_IDに関連付けられているメタデータ関連表を削除します。

      例

      987をOTL_IDに置き換えます。

      SET SERVEROUTPUT ON;
      BEGIN
        FOR c IN ( SELECT distinct TABLE_NAME FROM USER_TABLES WHERE TABLE_NAME like 'ESSAV_MTD_987_%' )
        LOOP
          EXECUTE IMMEDIATE 'DROP TABLE "' || c.TABLE_NAME || '" purge';
          DBMS_OUTPUT.PUT_LINE('TABLE ' || c.TABLE_NAME || ' dropped successfully.');
        END LOOP;
      END;
      /
      

   2. UPDATE文を実行して、ESSAV_OTL_MTD_VERSION表を非アクティブ・ステータスに設定します。

      例

      Sampleを実際のAppNameに置き換えます。

      UPDATE "ESSAV_OTL_MTD_VERSION" SET  "OTL_STATUS" = 'INACTIVE'  where APPNAME ='Sample';
      commit;

ノート:

Autonomous AI Databaseスキーマを使用するEssbaseインスタンスは1つのみであるため、クリーン・アップ・タスクを実行するときにESSBASE_INSTANCE_UNIQUE_IDを指定する必要はありません。「フェデレーテッド・キューブの制限事項」を参照してください。

接続およびフェデレーテッド・パーティションの再作成

1. Autonomous AI Lakehouseとの接続を再作成します。これは、グローバル接続(Essbase Webインタフェースにあるメインの「ソース」アイコンの下)であるか、そのアプリケーション専用に定義されている「ソース」内にある場合があります。接続の手順に従います。必ず接続をテストし保存してください。

2. 「フェデレーテッド・パーティションの作成」で説明されているとおりに、フェデレーテッド・パーティションを再作成します。

3. 「Essbaseエラー(1350012): OCIに接続しようとして失敗しました」などの接続エラーが引き続き表示される場合は、https://support.oracle.com/rs?type=doc&id=2925030.1を確認してください。

フェデレーテッド・キューブのバックアップとリストア

フェデレーテッド・パーティションはEssbaseアプリケーションで移行されません。フェデレーテッド・キューブの別のサーバーへの移動または別のEssbaseバージョンへの移行を準備するときは、フェデレーテッド・パーティションを削除して新しい環境で再作成する必要があります。

フェデレーテッド・キューブをバックアップするには、

1. データを含めず、他の必要なもの(構成プロパティ、フィルタ、変数、計算スクリプト、その他のアーティファクトなど)をすべて含めて、アプリケーションをバックアップします。これを行うには、LcmExport(またはEssbase Webインタフェースの「LCMのエクスポート」ジョブ)を使用します。

2. ファクト表をバックアップします。Autonomous Databaseのバックアップおよびリストアを参照してください。

3. 「フェデレーテッド・パーティションの削除」の手順に従って、キューブからフェデレーテッド・パーティション定義を削除します。

フェデレーテッド・キューブをバックアップからリストアするには、

1. LcmImport (またはEssbase Webインタフェースにある「LCMのインポート」ジョブ)を使用してアプリケーションを再作成します。

2. 必要に応じて、Autonomous AI Lakehouseでファクト表をリストアします、

3. Autonomous AI Lakehouseとの接続を再作成します。エラーが発生しないようにするために、新しい接続名を使用することをお薦めします。

4. フェデレーテッド・パーティションを再作成します。