Warning: This class is an experimental/preview control that is not final and will change in future releases. If you have any feedback on this control, please post it to the JavaFX JIRA issue tracker.

An implementation of TreeItemBase which provides two possible approaches to building up a tree structure. The first approach is to manually build the structure when the root node is first built. This requires more memory but means that once the data structure is created there is no requirement to do anything else other than placing it in a TreeVew. An example of this approach is shown here:

var simpleTree = TreeItem {
    data: "Root node";
    expanded: true
    children: [
        TreeItem { data: "leaf 1" },
        TreeItem { data: "leaf 2" },
        TreeItem { data: "leaf 3" },
        TreeItem {
            data: "branch 1"
            expanded: true
            children: [
                TreeItem { data: "leaf 4" },
                TreeItem { data: "leaf 5" },
                TreeItem { data: "leaf 6" },
                TreeItem {
                    data: "branch 2"
                    expanded: true
                    children: [
                        TreeItem { data: "leaf 7" },
                        TreeItem { data: "leaf 8" },
                        TreeItem { data: "leaf 9" },
                    ]
                }
            ]
        }
        TreeItem { data: "leaf 10" }
    ]
}

To create a TreeView from this is then achieved by doing the following:

def simpleTreeView = TreeView {
    root: simpleTree;
}

The alternative approach is to recursively build the data structure on-demand by providing functions for createChildren and isLeaf. The example shown below is a Windows-specific filesystem browser built using the TreeView control as well a TreeItem. It is a trivial change to modify this sample to browse alternative file systems (just change the reference to c:/ to suit your file system).

import javafx.stage.Stage;
import javafx.scene.Scene;

import com.javafx.preview.control.TreeItem;
import com.javafx.preview.control.TreeItemBase;
import com.javafx.preview.control.TreeView;

import java.io.File;

var tree = TreeView {
    root: TreeItem {
        data: new File("c:/")
        expanded:true
        isLeaf: isLeaf
        createChildren: createChildren;
    }
}

function createChildren(item:TreeItemBase):TreeItemBase[] {
    def file = item.data as File;
    if (file.isDirectory()) {
        return for (f in file.listFiles()) {
            TreeItem {
                data: f
                createChildren: createChildren;
                isLeaf: isLeaf;
            }
        }
    }

    return [];
}

function isLeaf(item:TreeItemBase):Boolean {
    def file = item.data as File;
    return file.isFile();
}

Stage {
    scene: Scene {
        content: [ tree ]
    }
}

Note how this approach differs from the first one. Both approaches have different positives and negatives, so it is important to test both approaches, if applicable, and select the most appropriate.

See Also:
TreeView, TreeItemBase

Profile: common